{Change Comments ***********************************************************}

{11/26/90
Copied & modified: Fanuc 6M M001.76.1
For: Ashland Inc.
Add SeqLabC to comment lines except for footer comments.
Modify WFOStuff sub to output WFO1 in first operation only, unless NewWFO is used.
Machine has manual speed control, change SpinOn to a comment line & delete SpeedC.
Change colons to ". " (period space) in comments.
Added ESC character, ASCII('27'), to end of prog after EOR.
Jim Radcliffe}

{4/03/91
Modified: Fagor Nasa M360.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{5/17/95
Initial: Fagor Nasa M360.79
ForUser: Hendrickson
Control: Fagor 8025
Machine: MTS Mega II
Comment: New Processor. Modifications per marked up readout and instructions.
Jim Radcliffe}

{6/1/95
Initial: Fagor 8025 MTS Mega II M792.79
Created: Fagor 8025 MTS Mega II M792.80
Comment: Modified sub calls and identificaton per Ricardo at Fagor.
Using G20 to call, G22 to identify and G24 to end.
Subroutines placed at enf of main program.
Changed to use Retag for consecutive sequnce numbers thru the subroutines.
Jim Radcliffe}

{12/1/95
Initial: Fagor 8025 MTS Mega II M792.80
Created: Fagor 8025 MTS Mega II M792.85
ForUser: Hendrickson Enterprises
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: Modified per marked up readout from Marc at Hendrickson.
Updated to .85 format
Added helical interpolation.
Can only loop a sub 99 times:
Created checks for loops over 99
Created CallSubCall that calls sub looped 99 times
Var#1 = desired number of loops
Var#2 = number of times to loop 99 times
Var#3 = number of remaining loops
Jim Radcliffe}

{1/12/96
Initial: Fagor 8025 MTS Mega II M792.80
Created: Fagor 8025 MTS Mega II M792.85.1
ForUser: Hendrickson Enterprises
Comment: Modified per marked up readout from Marc at Hendrickson.
Modified Fform for no negitive K values in
JM}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}
{3/30/96,
Initial: Fagor 8025 MTS Mega II M792.89
Created: Fagor 8025 MTS Mega II M792.89.1
Added Num Format #8, Changed Helix pitch to Format #8 in order to always output positive K value,
undid change to form that Jeff M. made on 1/12/96, MPK}

{4/18/96,
Initial: Fagor 8025 MTS Mega II M792.89
Created: Fagor 8025 [ETS] Mxxx.89
Added DoEOL sub to reset sequence numbering to 1 when N# reaches 10000, MPK}

{4/25/96,
Initial: Fagor 8025 [ETS] MY79.89
Created: Fagor 8025 [ETS] MY79.89.1
deleted Recall# Num#('5') accidentally left in DoEOL sub, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '##.##;0'
#7 = '00000'
#8 = '+####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(CalcCP2FmSurf#,4)
FORMAT(Retract#,4)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(ToolOffset#,5)
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(SpeedRPM#,5)
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Repeats#,5)
FORMAT(Recall#,5)
FORMAT(Dwell#,6) {.72}
FORMAT(Program#,7)
FORMAT(HelixPitch#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoEOL:
IF NOT EmptyLine?
IF GreaterThan? Recall# Num#('5') Num#('9999')
'Ś1'
Save# Num#('5') Num#('0')
END
Save# Num#('5') ADD# Recall# Num#('5') Num#('1') EOL
END
EOL
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLabC '( SUB NUMBER. ' Tag# ' )' DoEOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '( OPERATION ' Operation# '. ' OperationType$ ' )' DoEOL
END
IF OperationComment?
SeqLabC '( ' OperationComment$ ' )' DoEOL
END
IF WorkGroupComment?
SeqLabC '( ' WorkGroupComment$ ' )' DoEOL
END
IF ToolTypeComment?
SeqLabC '( TOOL ' Tool# '. ' ToolDiameter# ' ' ToolType$ ' )' DoEOL
END
IF ToolComment?
SeqLabC '( ' ToolComment$ ' )' DoEOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# DoEOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# DoEOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# DoEOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# DoEOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript DoEOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS DoEOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt DoEOL
ELSE
SeqLabC RapidC ZIn DoEOL
END
RETURN

StartSub:
OpenSub
SeqLabC 'G22N' Tag# DoEOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' DoEOL
SeqLabC '( WARNING Z CLEARANCE WILL CHANGE )' DoEOL
SeqLabC '( WITH EACH CYCLE OF SUB REPEAT )' DoEOL
' ' DoEOL
END
END
RETURN

CallSubCall:
{ integer portion of the desired number of loops devided by 99 }
SAVE# NUM#('2') TRUNC# DIV# Recall# Num#('1') Num#('99')
{ remainder decimal portion multiplied by 99 }
SAVE# NUM#('3') MUL# SUB# DIV# Recall# Num#('1') Num#('99') Recall# NUM#('2') Num#('99')
{ call new sub integer portion number of times }
SeqLabC 'G20N' Tag# '.' Recall# NUM#('2') DoEOL
{ create new sub that loops desired sub 99 times }
StartSub
TagInc
SeqLabC 'G20N' Tag# '.99' DoEOL
SeqLabC EndSub DoEOL
CloseSub
{ call & loop desired sub remainder number of times }
SeqLabC 'G20N' Tag# '.' Recall# NUM#('3') DoEOL
RETURN

StdSub:
IF GreaterThan? Repeats# Num#('99')
Save# Num#('1') Repeats#
CallSubCall
ELSE
SeqLabC 'G20N' Tag# '.' Repeats# DoEOL
END
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
DoEOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC DoEOL
SeqLabC EndSub DoEOL
CloseSub
SeqLabC Preset UnshftRC DoEOL
RETURN

OpenMP:
TagInc
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLabC SetWFO DoEOL
SeqLabC 'G20N' Tag# '.1' DoEOL
IncWFO
NextWFO
ELSE
IF GreaterThan? Parts# Num#('99')
Save# Num#('1') Parts#
CallSubCall
ELSE
SeqLabC 'G20N' Tag# '.' Parts# DoEOL
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC EndSub DoEOL
CloseSub
SeqLabC WFO1 DoEOL
ELSE
SeqLabC Preset ShiftPC DoEOL
SeqLabC EndSub DoEOL
CloseSub
SeqLabC Preset UnshftPC DoEOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue DoEOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
IF XYPlane?
IF ZMove?
MoveX MoveY ArcIJ MoveZ 'K' HelixPitch#
ELSE
MoveX MoveY ArcIJ
END
ELSE
IF XZPlane?
IF YMove?
MoveX MoveZ ArcIJ MoveY 'J' HelixPitch#
ELSE
MoveX MoveZ ArcIJ
END
ELSE
IF XMove?
MoveY MoveZ ArcIJ MoveX 'I' HelixPitch#
ELSE
MoveY MoveZ ArcIJ
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CRCOnC FeedC MoveXYZC FeedRateC DoEOL
DecelMove2
END
SeqLabC CRCOnC FeedC MoveXYZC DecelFeed DoEOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CRCOnC FeedC MoveXYZC FeedRateC DoEOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC DoEOL
SeqLabC 'G20N' Tag# '.1' DoEOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC DoEOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC RapidC MoveXYZC DoEOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc RapidC MoveXYZC DoEOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC RapidC MoveXYZC DoEOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC DoEOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC DoEOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC DoEOL
DecelMove2
END
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed DoEOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC DoEOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC DoEOL
DecelMove2
END
SeqLabC FormatArc DecelFeed DoEOL
ELSE
SeqLabC FormatArc ArcFeedC DoEOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' DoEOL
ELSE
SeqLabC 'G' NewWFO# DoEOL
END
ELSE
IF FirstOperation?
IF NeedWFO1?
SeqLabC 'G' NewWFO# DoEOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue DoEOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
DoEOL
SeqLabC EndSub DoEOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos DoEOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC DoEOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt DoEOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC DoEOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc DoEOL
SeqLabC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqLabC AbsOrInc ZInPlusInc DoEOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc DoEOL
SeqLabC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqLabC Rapid ZInPlusInc DoEOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqLabC Rapid ZInPlusInc DoEOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC 'G20N' Tag# '.1' DoEOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt DoEOL {.69}
ELSE
SeqLabC Rapid ZCP2 DoEOL {.69}
END
END {.69}
SeqLabC EndSub DoEOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos DoEOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt DoEOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC DoEOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqLabC RapidC ZInPlusInc DoEOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC 'G20N' Tag# '.1' DoEOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub DoEOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

GetCoolant:
IF SameTool?
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
ELSE
CoolOn
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
TagInit
Save# Num#('5') Num#('1')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' DoEOL
' Literals : put between single or double quotes.' DoEOL
' Separate commands and literals with at least one space.' DoEOL
' A CR ( RETURN key ) will start a new line.' DoEOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' DoEOL
' EndOP -' DoEOL
' all literals and commands before an ENDOP command' DoEOL
' will appear at the beginning of the operation. All ' DoEOL
' literals and commands after an ENDOP command will appear' DoEOL
' at the end of the operation. ' DoEOL
' NewWFO(56), NWFO(56) -' DoEOL
' The Work Fixture Offset # you specify will be used for all following operations.' DoEOL
' Do not use with the ncPost multiple part option.' DoEOL
' 4thAxisCW(12.5), 4ACW(12.5) -' DoEOL
' generates a + A move of the value you specify' DoEOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' DoEOL
' generates a - A move of the value you specify' DoEOL
' 5thAxisCW(30), 5ACW(30) -' DoEOL
' generates a + B move of the value you specify' DoEOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' DoEOL
' generates a - B move of the value you specify' DoEOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR Program# DoEOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLabC '( ' ProgramName$ ' )' DoEOL
END
IF ProgramComment?
SeqLabC '( ' ProgramComment$ ' )' DoEOL
END
IF FormatNameComment?
SeqLabC '( FORMAT. ' FormatName$ ' )' DoEOL
END
IF TimeComment?
SeqLabC '( ' Date$ ' AT ' Time$ ' )' DoEOL
END
IF MovesComment?
SeqLabC '( OUTPUT IN ' MoveType$ ' INCHES )' DoEOL
END
IF PartsComment?
SeqLabC '( PARTS PROGRAMMED. ' Parts# ' )' DoEOL
END
IF StartToolComment?
SeqLabC '( FIRST TOOL IN SPINDLE )' DoEOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab 'T' Tool# '.' ToolOffset# SpinOn DoEOL
DoOpComments
SeqLabC Plane CRCOff 'G70' DrillOff 'G94' DoEOL
DoPostScript
WFOStuff
SeqLabC '( SPEED ' SpeedRPM# ' )' DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos DoEOL
SeqLabC 'G43' ZCP1 DoEOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos DoEOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff DoEOL
SeqLabC OfstOff DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home SpinOff DoEOL
ELSE
SeqLabC SpinOff DoEOL
END
SeqLabC ToolChng DoEOL

{Start new Operation}

SeqLab 'T' Tool# '.' ToolOffset# SpinOn DoEOL
DoOpComments
SeqLabC Plane CRCOff 'G70' DrillOff 'G94' DoEOL
DoPostScript
WFOStuff
SeqLabC '( SPEED ' SpeedRPM# ' )' DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos DoEOL
SeqLabC 'G43' ZCP1 DoEOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos DoEOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff DoEOL
SeqLabC OfstOff DoEOL
SeqLabC SpinOff DoEOL
SeqLabC 'M00' DoEOL

{Start new Operation}

SeqLabC 'T' Tool# '.' ToolOffset# SpinOn DoEOL
GetStartOfSameTool
SeqLabC '( SPEED ' SpeedRPM# ' )' DoEOL
SeqLabC PlaneC AbsOrInc Rapid StrtPos DoEOL
SeqLabC 'G43' ZCP1 DoEOL
SeqLabC CoolOn DoEOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff DoEOL
END
IF NewToolOffset?
SeqLabC OfstOff DoEOL

{Start new Operation}

SeqLabC 'T' Tool# '.' ToolOffset# DoEOL
GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos DoEOL
SeqLabC 'G43' ZCP1 DoEOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos DoEOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C DoEOL
SeqLabC GetCoolant DoEOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C DoEOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC CRCOffC ZCP3C FeedEntC DoEOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C DoEOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos DoEOL
SeqLabC ZCP1 DoEOL
END
SeqLabC GetCoolant DoEOL
GetCycle
SeqLabC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
FromCP StrtPos RLevel ZDepth Peck
IF Peck?
'C' Retract#
'D' CalcCP2FmSurf#
IF PeckChipBreaker?
'H' Retract#
END
END
Dwell FeedEnt DoEOL
IF CallMasterOp?
SeqLabC 'G20N' CallMasterNum# '.1' DoEOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterTag
SeqLabC 'G20N' Tag# '.1' DoEOL
StartSub
ToolPath
SeqLabC EndSub DoEOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC DrillOff ZCP3 DoEOL
IF Repeats?
FinishSubG92
END
SeqLabC RapidC ZCP3C DoEOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff DoEOL
SeqLabC OfstOff DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC AbsOrInc Rapid FirstHome SpinOff DoEOL
ELSE
SeqLabC SpinOff DoEOL
END
IF ProgStop?
SeqLabC 'M00' DoEOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC EOP DoEOL
CloseSub
Post2 {organize Subs into one program}
ASCII('27') DoEOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH. ' FileBytes# ' CHARACTERS )' DoEOL
END
IF FileFeetComment?
'( FILE LENGTH. ' FileFeet# ' FEET )' DoEOL
END
IF FileMetersComment?
'( FILE LENGTH. ' FileMeters# ' METERS )' DoEOL
END
Close
END