{Change Comments ***********************************************************}

{9/14/89, Modified from Fanuc 10T-MS [-] L001.60, DWB}

{9/19/89
The current 'SimpleRough' command is not outputting correctly for this control. Currently it
outputs the correct format for the first pass, but each additional pass only outputs the 'X'
value. Each line requires the following output:
SeqC 'G84' MoveX FinZ FeedRate EOL
The post will output a message to the user that we will fix the format in the near future, and
how to handle the problem for the time being.
NOTE: Currently ncCam is not allowing me to deselect PreferredCanned when I want to do a simple
threading cycle, so I cannot test for same.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/29/92
Updated: Compact 5 Emco [TP] L118.56
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Program#,2) {.72}
FORMAT(Operation#,2) {.72}
FORMAT(Tool#,2) {.72}

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSP EOL
SeqC StockOff XOpCD EOL
SeqC Feed StockOnNoCan XSP FeedRate EOL
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSP EOL
IF SameTool? AND NOT FirstOperation?
IF LAST ApproachID?
SeqC StockOff XOpCD EOL
END
END
SeqC Feed StockOnNoCan XSP FeedRate EOL
RETURN

FaceApproachSP:
IF SameTool? AND NOT FirstOperation?
SeqC StockOnNoCan XSP EOL
END
SeqC StockOff ZOpCP EOL
SeqC Feed StockOnNoCan ZSP FeedRate EOL
RETURN

AppMove:
ZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Rapid XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Rapid XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Rapid StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveX MoveZ
RETURN

ToolPath:
EACHFeat
GetToolTip
IF PointFeat?
SeqC MoveSX MoveSY EOL
ELSE
IF RapidFeat?
IF NOT FirstFeat? AND LAST ThreadFeat?
SeqC Rapid MoveX EOL
SeqC Rapid MoveZ EOL
ELSE
SeqC Rapid MoveX MoveZ EOL
END
ELSE
IF LineFeat?
SeqC Feed MoveX MoveZ FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC Rapid MoveX EOL
SeqC 'G33' MoveZ ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
ReverseXZArcs
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane CSSOff
Seq Preset Home EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
IF LAST ApproachOD?
SeqC Rapid XCPC EOL
ELSE
IF LAST ApproachID?
SeqC Rapid LAST XOpECDC EOL
END
END
SeqC Rapid ZCPC EOL
DoEndOpPS
SeqC Rapid NewHome EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Plane
Seq Preset Home EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
SeqC Rapid StockOnNoCan XSP ZSP EOL
ELSE
IF ApproachOD?
IF LAST ApproachOD?
SeqC Rapid LAST XOpECD EOL
ELSE {around}
IF LAST ApproachID?
SeqC Rapid LAST XOpECD EOL
END
SeqC Rapid ZCP EOL
SeqC Rapid XCP EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC Rapid LAST XOpECD EOL
ELSE
IF LAST ApproachOD? {around}
SeqC Rapid XCP EOL
END
SeqC Rapid ZCP EOL
SeqC Rapid XOpCD EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC Rapid LAST ZOpECP EOL
ELSE
IF LAST ApproachOD? {around}
SeqC Rapid XCP EOL
ELSE {LAST ApproachID}
SeqC Rapid LAST XOpECD EOL
END
SeqC Rapid ZCP EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
IF NOT ApproachFace?
StockOn
SetPass1
SeqC 'G84' XatFinZ FinZ FeedRate EOL
END
' ' EOL
' NOTE: THIS POST DOES NOT OUTPUT CORRECT LATHE TURNING CYCLE YET' EOL
' SELECT THE LINE, COPY AND PASTE FOR THE NUMBER OF PASSES YOU WANT' EOL
' THEN EDIT THE X VALUES THAT YOU NEED' EOL
' WE WILL IMPLEMENT THE CORRECT FORMAT IN THE NEAR FUTURE' EOL
' ' EOL
{SimpleRough}
END
ELSE
IF Threading?
SeqC 'G78' XatFinZ FinZ ThrdLead EOL
IF AutoFinish?
SeqC Rapid XatFinZ EOL
SeqC 'G33' FinZ ThrdLead EOL
SeqC Rapid XCSP EOL
SeqC Rapid ZCSP EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC Rapid StrtPos EOL
ToolPath
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF ApproachOD?
SeqC Rapid XCPC EOL
ELSE
IF ApproachID?
SeqC Rapid XOpECDC EOL
END
END
SeqC Rapid ZCPC EOL
DoEndOpPS
SeqC Rapid FirstHome EOL
IF ProgStop?
SeqC 'M0' EOL
END
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END