{Change Comments ***********************************************************}

{5/24/93
Created: Fanuc 6M NoSubs M001.81 per Fanuc 6M M001.81 Format
Added Following Variables:
Var(1) = FirstOperation Tools
Var(2) = LastOp Tools
Var(3) = Last ncCAM Operation
NOTE: This Processor does not support FIFO.
JR}

{7/29/93
Modified: Fanuc 6M NoSubs M001.81
Added FIFO support.
JR}

{8/3/93
Modified: Fanuc 6M NoSubs M001.81.1
Added SameTool WFOStuff.
Added RapidF.
Updated FIFO support.
JR}

{10/4/93
Copied & modified: Fanuc 6M NoSubs M001.81.2
Created: Fanuc 6M NoSubs 4A M001.81.4 per Yasnac MX3 4A Mat A001.81.4
For: Moehrle
Control: Allen Bradley 7320
Machine: Burgmaster VTC 330
JR}

{1/31/94
Modified: AB 7320 Burg VTC 330 A013.81.4
For: Moehrle
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.2/Compost 4.21.19
Updated to Version 4.2 per Fanuc 6M A001.81.2c Format.
Major modifications per LongHand M001.81.3 Format.
Changes made per Fred Moehrle.
Added Spaces to all Addresses in Form and Prog.
Added Format #9, "*##.####;0" for Peck Address K at Prog Numeric Format Definitions.
Changed Peck Command to 'K' Peck# at Drill Stuff.
Added literal 'P.1' for Dwell to G84 Tapping Cycle at Drill Stuff.
Added NoIJKSigns at setup and initializations.
DWB}

{1/31/94
Copied & Modified: AB 7320 Burg VTC 330 A013.81.5
For: Moehrle
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.2/Compost 4.21.19
Created: AB 7320 Burg VTC 330 Mxxx.81.5.
DWB}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '#.##;0'
#7 = '0'
#8 = '00'
#9 = '*##.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(TrackZ#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Tag#,5)
FORMAT(Recall#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(NewWFO#,8) {.72}
FORMAT(Peck#,9)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' B' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' B' FourthDegree# EOL
FourthCCWF {reset flag}
END
{ FifthCW and FifthCCW not supported 1/27/94 DWB }
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC RapidFC EOL
END
RETURN

GetConnect:
IF FeedConnect?
FeedC
ELSE
RapidC
END
RETURN

GetConnectF:
IF FeedConnect?
FeedEntC
ELSE
RapidFC
END
RETURN

ExitMove:
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
SeqC FeedC ZInC FeedEntC EOL
END
END
ELSE
SeqC CRCOffC
IF FIFO? { .81 }
FeedC
ELSE
RapidC
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
ELSE
RapidFC
END
EOL
END
RETURN

ExitMove2:
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C RapidFC
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
{ Not supported because CRCOffC is always output after LastFeat }
RETURN

StdLine: {enables CRC on first call, .70}
SeqC CRCOnC EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

DrillStuff:
SeqC
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
ZDepth RLevel
IF Tap?
' P.1' { Tap Dwell }
ELSE
Dwell
END
IF Peck?
' K' Peck#
END
FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

DoLastPeck: { OldZ - Peck# ² Depth }
SeqLabC Feed ' Z' TrackZ# SPZ# FeedEntC EOL { Move to Depth }
IF LastFeat?
SeqLabC Rapid ZCP3 RapidF EOL { Move to CP3 }
ELSE
IF RetractToCP1?
SeqLabC Rapid ZCP1 RapidF EOL { Move to CP1 }
ELSE
SeqLabC Rapid ZCP2 RapidF EOL { Move to CP2 }
END
END
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('1') Peck# SPZ# { IF OldZ - Peck# > Depth }
Save# Num#('1') SUB# Recall# Num#('1') Peck# { OldZ - Peck# = NewZ }
SeqLabC Feed ' Z' TrackZ# Recall# Num#('1') FeedEntC EOL { Move to NewZ }
SeqLabC Rapid ' Z' TrackZ# ADD# Recall# Num#('1') Retract# RapidF EOL { Move to RetractZ }
END
RETURN

DrillCycle:
GetCycle
IF PeckChipBreaker?
SeqC ZCP2C EOL
Save# Num#('1') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoLastPeck
ELSE
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
DrillStuff
IF LastFeat?
SeqC DrillOff ZCP3 RapidF EOL
ELSE
SeqC DrillOff ZCP1 RapidF EOL
END
ELSE
IF FirstFeat?
DrillStuff
END
IF LastFeat?
SeqC DrillOff ZCP3 RapidF EOL
END
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYC EOL {.80.01}
DrillCycle
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC RapidC MoveXYZC RapidFC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC RapidFC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('6') SUB# EPX# CurOriginPosX#
Save# Num#('7') SUB# EPY# CurOriginPosY#
SetInc
END
IF LastFeat?
SeqC CRCOffC EOL
END
END
NEXTFeat
RETURN

WFOStuff: { Only supports NewWFO PostScript command. Why? I do not know! 1/27/94 DWB }
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC ' H' NewWFO# EOL
END
ELSE
{ No NewWFO PostScript Command }
END
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqC AbsOrInc RapidC ZCP2 RapidFC EOL
END
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF NOT FirstCycle?
SeqC CRCOffC GetConnect StrtPos GetConnectF EOL
END
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
IF ZshiftOnly?
EntryMove
END
ELSE
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
DoCycleComment
IF NOT FirstFeat?
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC RapidFC EOL
END
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
DoCycleComment
IF FirstFeat? AND FirstCycle?
ELSE
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC GetConnectF EOL
END
END
SetAbs
Save# Num#('4') SPX#
Save# Num#('5') SPY#
SetInc
AutoCycCutSub1
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('4') Recall# Num#('6')
TrackYNO# ADD# Recall# Num#('5') Recall# Num#('7')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF NOT FirstFeat?
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC GetConnectF EOL
END
END
AutoCycCutSub1
EachRep
IF FirstCycle?
EntryMove
ELSE
IF NOT FeedConnect?
ExitMove
END
DoCycleComment
IF FirstFeat? AND FirstCycle?
ELSE
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC GetConnectF EOL
END
END
IF NOT FeedConnect?
EntryMove
END
END
ToolPath
NextRep
AutoCycCutSub2
ReSetPass2 {restore for positioning moves}
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoPartCycleComment
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

GoToZ0:
' Z0'
RETURN

ToolOfstOff:
' T00'
RETURN

CheckOfstOn:
IF NotEqual? Tool# ToolOffset#
ToolOfst
END
RETURN

CheckOfstOnSameTool:
IF NotEqual? ToolOffset# LAST ToolOffset#
ToolOfst
END
RETURN

GoHome:
IF ToolChangeAtHome?
SetAbs
LoadFeat
SUB# HomeX# CurOriginPosX#
SUB# HomeY# CurOriginPosY#
Num#('0') { Dummy Z }
SetAbsOrInc
MoveXY
END
RETURN

CheckCRCOffset:
IF CutterRadiusCompensation?
CRCOffsetC
END
RETURN

MasterSub:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE
IF ToolChangeAtHome?
SetHome
END
Seq Plane CRCOff DrillOff ToolOfstOff EOL
SeqC Rapid GoToZ0 RapidF EOL
SeqC GoHome EOL
SeqC OpToolID ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
WFOStuff
SeqC Speed SpinOn CheckCRCOffset EOL
CheckPass
SeqC Rapid StrtPos RapidF CoolOn EOL
SeqC CheckOfstOn EOL
SeqC ZCP1 EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE

{Finish off last Operation}

SeqC ToolOfstOff CoolOff EOL
SeqC RapidC GoToZ0 RapidFC EOL
DoEndOpPS
SeqC GoHome
IF LAST ProgStop?
' M00'
ELSE
ProgStop
END
ASCII('13') EOL

{Start new Operation}

Seq Plane CRCOff DrillOff ToolOfstOff EOL
SeqC Rapid GoToZ0 RapidF EOL
SeqC GoHome EOL
SeqC OpToolID ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
WFOStuff
SeqC Speed SpinOn CheckCRCOffset EOL
CheckPass
SeqC Rapid StrtPos RapidF CoolOn EOL
SeqC CheckOfstOn EOL
SeqC ZCP1 EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC ToolOfstOff CoolOff EOL
SeqC RapidC GoToZ0 RapidFC EOL
SeqC ' M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Speed SpinOn CheckCRCOffset CheckOfstOnSameTool EOL
SeqC PlaneC Rapid StrtPos RapidF CoolOn EOL
SeqC ZCP1 EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC ToolOfstOff EOL
SeqC RapidC GoToZ0 RapidFC EOL

{Start new Operation}

GetStartOfSameTool
SeqC CheckCRCOffset CheckOfstOnSameTool EOL
SeqC PlaneC Rapid StrtPos SpeedC RapidF EOL
SeqC ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC CheckCRCOffset EOL
SeqC PlaneC Rapid StrtPos SpeedC RapidF EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZshiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
ToolPath
NextRep
ELSE
ToolPath
END
SeqC RapidC ZCP3C RapidFC EOL
END
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
SeqC ToolOfstOff CoolOff EOL
SeqC RapidC GoToZ0 RapidFC EOL
DoEndOpPS
SeqC
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SetAbs
LoadFeat
SUB# FIRST HomeX# CurOriginPosX#
SUB# FIRST HomeY# CurOriginPosY#
Num#('0') { Dummy Z }
SetAbsOrInc
MoveXY
END
IF ProgStop?
' M00'
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
ProgStop
END
END
EOL
RETURN

MPLoop:
TagInit
IF AllToolsOnePart?
EachPart
TagInc
EachOp
MasterSub
NextOp
EndPartSub
NextPart
ELSE { OneToolAllParts }
Save# Num#('2') Recall# Num#('1')
IF LTEqual? Recall# Num#('1') Recall# Num#('3')
EachOp
IF Equal? Operation# Recall# Num#('2')
Save# Num#('2') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('1') Recall# Num#('3')
Save# Num#('2') Operation#
ELSE
IF NotEqual? Recall# Num#('1') SUB# Recall# Num#('2') Num#('1')
Save# Num#('2') SUB# Operation# Num#('1')
END
END
END
END
NextOp
EachPart
TagInc
EachOp
IF GTEqual? Operation# Recall# Num#('1')
IF LTEqual? Operation# Recall# Num#('2')
IF Equal? Operation# Recall# Num#('1')
IF NOT FirstPart?

{Finish off last Operation}

IF FullUp?
SeqC ToolOfstOff CoolOff EOL
SeqC RapidC GoToZ0 RapidFC EOL
END
{DoEndOpPS}

{Start new Operation}

GetStartOfSameTool
SeqC CheckCRCOffset EOL
SeqC PlaneC Rapid StrtPos SpeedC RapidF EOL
IF FullUp?
SeqC CheckOfstOn ToolOfst EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
END
END
END
MasterSub
END
END
NextOp
NextPart
Save# Num#('1') ADD# Recall# Num#('2') Num#('1')
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
NoIJKSigns
InitWFONum
SetFlood
SetMaxRPM('3000')
SetMaxFeed('300')
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
SetFlagF('1') { End of MultipleParts }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EOR EOL
SeqC Rapid CRCOff ' G70' DrillOff AbsOrInc ' G94 T00 D00 H00 P0 M48' EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts?
Save# Num#('1') Num#('1')
EachOp
IF LastOp?
Save# Num#('3') Operation#
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
SeqC EOP EOL
EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END