{Change Comments ***********************************************************}

{8/11/93
Copied & modified: Fanuc 6M M001.81.2
For: Braden Eng / Allen Bradley
Control: Allen Bradley Series 8600MC
Machine: Shizouka vertical 3 Axis mill
Created new Processor per manual.
G27 = Continuous sequence operation with automatic speed reduction at corners.
G70 = Programming in inches.
Arcs use I & J for arc center regardless of plane selection.
WFO's output by request only, MP or NewWFO.
CRCOff on LastFeat.
Subprograms do not repeat, set another repeat call to repeat subprogram call.
Using Var#1 for current WFO and Var#2 for incremented MultipleParts WFO.
Jim Radcliffe}

{10/2/93
Modified: AB 8600 Shiz [AB] M597.81.2
For: Braden Eng / Allen Bradley
Control: Allen Bradley Series 8600MC
Machine: Shizouka vertical 3 Axis mill
Corrected UGS block, added coma between last X anf first Y, deleted Z.
Added comas between codes in RQO blocks.
Commented out the EndSub command, for some reason the customer does not want it.
Jim Radcliffe}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(XStockMin#,4)
FORMAT(XStockMax#,4)
FORMAT(YStockMin#,4)
FORMAT(YStockMax#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(HelixPitch#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(Dwell#,4)
FORMAT(Peck#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnshiftPX#,4)
FORMAT(OriginUnshiftPY#,4)
FORMAT(OriginUnshiftPZ#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(OriginUnshiftRX#,4)
FORMAT(OriginUnshiftRY#,4)
FORMAT(OriginUnshiftRZ#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5)
FORMAT(ToolOffset#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqC '(DIS,"SUB NUMBER ' Program# '")' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
EOR EOL
DoSubComment
RETURN

SubEnd:
{SeqC EndSub EOL}
EOR EOL
CloseSub
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC '(RPT,' RepCycs ')' EOL {repeat call}
SeqC '(CLS,P' Program# ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

CurrentWFO#:
Recall# Num#('1')
RETURN

FinishSubG92: {part 2}
SubEnd
SeqC '(RQO,' CurrentWFO# ',X' RepeatX# ',Y' RepeatY# ',Z' RepeatZ# ')' EOL
SeqC '(ERP)' EOL {end repeat}
SeqC '(RQO,' CurrentWFO# ',X' OriginUnshiftRX#('0') ',Y' OriginUnshiftRY#('0') ',Z' OriginUnshiftRZ#('0') ')' EOL
RETURN

GetWFO: {output current register 1 WFO}
'(UAO,' CurrentWFO# ')'
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO Save# Num#('2') CurrentWFO# {store register 1 WFO to register 2}
EachWFO
SeqC '(UAO,' Recall# Num#('2') ')' EOL {output current register 2 WFO}
SeqC '(CLS,P' Program# ')' EOL
IncWFO
Save# Num#('2') ADD# Recall# Num#('2') Num#('1') {increment register 2 WFO}
NextWFO
ELSE
SeqC '(RPT,' Parts# ')' EOL {repeat call}
SeqC '(CLS,P' Program# ')' EOL
END
StartSub
RETURN

CloseMP:
SubEnd
IF WorkFixtureOffsets?
SeqC GetWFO EOL
ELSE
SeqC '(RQO,' CurrentWFO# ',X' PartShiftX# ',Y' PartShiftY# ',Z' PartShiftZ# ')' EOL
SeqC '(ERP)' EOL {end repeat}
SeqC '(RQO,' CurrentWFO# ',X' OriginUnshiftPX#('0') ',Y' OriginUnshiftPY#('0') ',Z' OriginUnshiftPZ#('0') ')' EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveXYZC ArcIJ 'K' HelixPitch#
ELSE
MoveXYZC ArcIJ
END
ELSE
IF XZPlane?
IF YMove?
MoveXYZC 'I' ArcI# 'J' ArcJ# 'K' HelixPitch#
ELSE
MoveXYZC 'I' ArcI# 'J' ArcJ#
END
ELSE {YZPlane}
IF XMove?
MoveXYZC 'I' ArcI# 'J' ArcJ# 'K' HelixPitch#
ELSE
MoveXYZC 'I' ArcI# 'J' ArcJ#
END
END
END
RETURN

CheckCRC:
IF LastFeat?
CRCOffC
ELSE
CRCOnC
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC '(CLS,P' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC CheckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? AND ZMove? AND NOT LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CheckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CheckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CheckCRC FeedC MoveXYZC FeedRateC EOL
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CheckCRC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC CheckCRC FormatArc DecelFeed EOL
ELSE
SeqC CheckCRC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND SameTool?
'*** WARNING ***' EOL
'NewWFO PostScript command was used on a SameTool operation,' EOL
'and then processed with MultipleParts, this cannot be done.' EOL
ELSE
Save# Num#('1') NewWFO# {store NewWFO to register 1}
SeqC GetWFO EOL
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SubEnd
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(CLS,P' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SubEnd
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC '(CLS,P' Program# ')' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SubEnd
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
Save# Num#('1') Num#('0') {store WFO1 to register 1}
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' It will be output in the form: (UAO,n), n being the Work Fixture Offset # you specify.' EOL
' Do not use on a same tool operation and then ncPost process with the multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
OpenSub
EOR EOL
SeqC '(DIS,"Program Number ' Program# '")' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'; PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE' EOL
END
END
RestoreScale
SeqC '(UGS,1,X' XStockMin# 'X' XStockMax# ',Y' YStockMin# 'Y' YStockMax# ')' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq 'G27' CRCOff 'G70' EOL
SeqC Plane EOL
SeqC DrillOff EOL
SeqC '(DIS,"Insert Tool Number ' Tool# '")' EOL
SeqC OpToolID '.' ToolOffset# ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC Rapid OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrInc Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq 'G27' CRCOff 'G70' EOL
SeqC Plane EOL
SeqC DrillOff EOL
SeqC '(DIS,"Insert Tool Number ' Tool# '")' EOL
SeqC OpToolID '.' ToolOffset# ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC Rapid OfstOff EOL
SeqC SpinOff EOL
SeqC 'M0' EOL

{Start new Operation}

SeqC PlaneC EOL
SeqC OpToolID '.' ToolOffset# EOL
GetStartOfSameTool
SeqC SpeedC SpinOn EOL
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid OfstOff EOL

{Start new Operation}

SeqC PlaneC EOL
SeqC OpToolID '.' ToolOffset# EOL
GetStartOfSameTool
SeqC SpeedC EOL
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
ELSE

{Start new Operation}

SeqC PlaneC EOL
GetStartOfSameTool
SeqC SpeedC EOL
SeqC AbsOrInc Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
GetCycle

{ set dwell time before cycle is called }
IF FIRO? OR FIFO? OR PeckChipBreaker?
IF Dwell?
SeqC 'UDW=' Dwell# EOL
END
END

{ call drill cycle }
SeqC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
RLevel
IF RetractToCP1?
'R' ClearancePlane1#
END
ZDepth Peck
IF PeckFullRetract?
'K1.' 'J' Peck#
END
FeedEnt EOL

{ cycle is executed on first point after the cycle call }
SeqC StrtPos EOL

TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC Rapid OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
EOR EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END