{Change Comments ***********************************************************}

{6/14/95, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}
{8/26/95, L001.85.01.01, Changed ToolAngle to 'A' InFeedAngle#, JR}
{6/18/96, rewrote CheckOffset to clean up and correct Speed bug, JR}
{8/20/96, fixed output of Rapid after ThreadFeat, JR}

{8/19/97
Initial: Fanuc 10T MS [-] L001.85.01.02
Created: AB 8600 W&S 2SCL L627.85
ForUser: Braden Engineering / Ramsey Winch
Control: Allen-Bradley 8600T
Machine: Warner & Swasey 2-SCL
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: New processor per sample programs and manual.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###.##;0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '##0^'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(MaxRPM#,6)
FORMAT(RapidF#,7)

{Special Command Subroutines ***********************************************}

IPM:
'G94'
SetFlag('1')
RETURN

IPMC:
IF NOT Flag?('1')
IPM
END
RETURN

IPR:
'G95'
SetFlagF('1')
RETURN

IPRC:
IF Flag?('1')
IPR
IF ConstantSurfaceFeed?
CSSOn 'G96' Speed
END
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC IPRC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC FeedC IPMC StockOnNoCan XSPC RapidFC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC FeedC IPMC StockOnNoCan ZSPC RapidFC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Feed IPMC ThisOpEntryXCP AppMove RapidF EOL
ELSE
IF ApproachID?
SeqC Feed IPMC XOpCD AppMove RapidF EOL
ELSE {ApproachFace}
SeqC Feed IPMC StockOnNoCan XSP AppMove RapidF EOL
END
END
ApproachSP
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewGear?
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
END
DoOpComments
DoPostScript
SeqC
IF ConstantSurfaceFeed?
IF NewGear?
GearRange
END
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
'(SSL,' MaxRPM# ')'
END
ELSE
'(SSL,' MaxRPM# ')'
END
END
EOL
SeqC
IF NOT ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
IF NewGear?
GearRange
END
END
IF LAST ProgStop?
SpinOn
ELSE
IF NewGear?
SpinOn
END
END
EOL
IF NewToolOffset?
SeqC OpToolID LatheOffset ToolChng
END
SeqC
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
RETURN

FormatArc:
IPRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G4' IPMC 'F2.' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G4' IPMC 'F' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Feed
ELSE
FeedC
END
IPMC MoveXC MoveZC
IF LAST ThreadFeat?
RapidF
ELSE
RapidFC
END
EOL
ELSE
IF LineFeat?
SeqC FeedC IPRC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Feed IPM
ELSE
IF LAST Threading?
Feed IPM
ELSE
FeedC IPMC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
SetFlagF('1') { inches per minute / inches per revolution }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
DoOpComments
DoPostScript
Seq
IF ConstantSurfaceFeed?
SeqC IPR GearRange EOL
SeqC '(SSL,' MaxRPM# ')' EOL
END
SeqC IPM CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1 SpinOn
ELSE
Speed GearRange SpinOn
END
EOL
SeqC Preset Home EOL
SeqC OpToolID LatheOffset ToolChng EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC RapidFC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
END
END
SeqC LAST OpExitZCPC RapidFC EOL
DoEndOpPS
SeqC 'T0' ToolChng EOL
SeqC NewHome CoolOff EOL
IF NewGear?
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' ASCII('13') EOL
ELSE
SeqC ProgStop ASCII('13') EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq
IF ConstantSurfaceFeed?
SeqC IPR GearRange EOL
SeqC '(SSL,' MaxRPM# ')' EOL
END
SeqC IPM CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1 SpinOn
ELSE
Speed GearRange SpinOn
END
EOL
SeqC Preset Home EOL
SeqC OpToolID LatheOffset ToolChng EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC RapidFC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC RapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
END
SeqC LAST OpExitZCPC RapidFC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC RapidFC EOL
END
SeqC LAST OpExitZCPC RapidFC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC RapidFC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC RapidFC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
IF Drilling?
IF Tap?
SeqC LCycle IPRC ZDepth 'K' FeedIPR# EOL
SeqC SpinOff EOL
SeqC 'G4' IPMC 'F2.' EOL
SeqC Speed InverseSpinOn EOL
SeqC IPRC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqC LCycle IPRC ZDepth Peck FeedRate EOL
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqC StrtPos EOL
ToolPath
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC FeedC IPMC ZOpECPC RapidFC EOL
ELSE
SeqC FeedC IPMC XOpECDC RapidFC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC FeedC IPMC XSPC ZSPC RapidFC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' MUL# Num#('1') ADD# FinishXRadius# Taper# EOL
SeqC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqC Feed XSP RapidF EOL
SeqC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G4' IPMC 'F2.' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Feed IPM
ELSE
IF Threading?
Feed IPM
ELSE
FeedC IPMC
END
END
IF ApproachOD?
SeqC OpExitXCPC RapidFC EOL
ELSE
IF ApproachID?
SeqC XOpECDC RapidFC EOL
END
END
SeqC OpExitZCPC RapidFC EOL
DoEndOpPS
SeqC 'T0' ToolChng EOL
SeqC FirstHome CoolOff EOL
SeqC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END