{Change Comments ***********************************************************}

{6/1/90
Copied & modified: AB Sheldon [BRL+] L142.69.4
For: Rollason
Machine: Allen Bradley 7300
Control: J&L TNC-A 2 Axis Lathe
Updated to Version 3.2 per Fanuc 10T MS [-] L001.69.3 format.
End turret consists of tool stations 1 thru 8.
Rear turret consists of tool stations 11 thru 16.
DWB}

{7/9/90
Modified: AB 7300 J & L [-] L163.69.4
For: Rollason
Added logic to determine ReverseXYArcs/StandardXYArcs depending on Turret selection.
Added MaxRPM to Preset line of each operation.
DWB}

{9/20/90
Modified: AB 7300 J & L [-] L163.70
For: Rollason
Removed logic for switching G02/G03 per turret, G02 is same for both.
Added 'K' to thread lead address is form.
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.2 format.
DWB}

{10/25/90
Modified: AB 7300 J & L [-] L163.71.2
For: Rollason
Added FORMAT for CalcEPRPM#.
Force Feed and FeedRate on last line of Approach.
Deleted FirstFeed sub.
Deleted NewToolOffset output.
Deleted extra END in CheckOffset sub.
Added PSComments.
Added ReverseXZArcs IF ToolOver?('8').
Added StandardXZArcs IF NOT ToolOver?('8').
Added MoveType$.
Added StockOff in FirstOperation.
Added CalcEPRPM# at end of prog.
DWB}

{4/9/91
Modified: AB 7300 J & L [-] L163.71.3
For: Rollason
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are Threading and Tapping.
Added Formula to calculate start of Tapered Thread for AutoFinish Pass.
DWB}

{5/13/91
Modified: AB 7300 J & L [-] L163.80
For: Rollason
Added NewToolOffset to CheckOffset sub.
Added logic to turn SpinOff when NewGear? = TRUE.
Added XTapAtZ to ThreadFeat in ToolPath and to AutoFinish line in CannedCycle.
Simplified IndexTool sub using MATH.
Combined and simplified CheckRapid subs.
DWB}

{7/24/91
Modified: AB 7300 J & L [-] L163.80
For: Rollason
Modifications made per memo dated 7/12/91 from Tom Walls at Rollason.
Modified ArcIJC to ArcIJ in FormatArc sub.
I and K values must appear on all Arc moves.
Added SETLASTOP to XCPC and ZCPC at NewTool, to output correct moves to clearance.
Because we are using SetAddTools, NewTool modifies XCPC and ZCPC using the CadCam document's
Stock values and the CURRENT Tool's offsets. We actually want to use the PREVIOUS Tool's offsets.
DWB}

{8/6/97
Initial: AB 7300 J & L [-] L163.80.1
Created: AB 7300 J&L 4515B Lxxx.85
ForUser: Muse Metal
Control: Allen-Bradley 7300
Machine: Jones and Lamson 4515B dual turret
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: New processor per fax from Tom Muse.
Jim Radcliffe}

{10/16/97
Initial: AB 7300 J&L 4515B L625.85
Created: AB 7300 J&L 4515B L625.85.1
Develop: ComPost2 1.1b2. Virtual Gibbs 4.21
Comment: Deleted EOR from beginning of program per conversation with Tom Muse.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '##.#####;0'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2)
FORMAT(TurretX#,2)
FORMAT(TurretZ#,2)
FORMAT(HomeX#,2)
FORMAT(CycleStartX#,2)
FORMAT(CycleStartZ#,2)
FORMAT(FinishXRadius#,2)
FORMAT(FinishZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(ADD#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Special Command Subroutines ***********************************************}

IncTurret:
IF Flag?('1')
' M37'
ELSE
' M27'
END
RETURN

IndexTool:
' M' ADD# Tool# Num#('20')
RETURN

IPM:
' G94'
SetFlag('2')
RETURN

IPMC:
IF NOT Flag?('2')
IPM
END
RETURN

IPR:
' G95'
SetFlagF('2')
RETURN

IPRC:
IF Flag?('2')
IPR
END
RETURN

SpeedMode:
IF ConstantSurfaceFeed?
CSSOn ' G96 R' HomeX#
ELSE
CSSOff ' G97'
END
RETURN

DoCoolOn:
IF NOT CoolOff?
IF Flag?('1')
' M6'
ELSE
' M8'
END
END
RETURN

DoCoolOff:
IF Flag?('1')
' M7'
ELSE
' M9'
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

IPRNoCan:
IF NOT CannedCycle?
IPRC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC IPRNoCan EOL
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC IPRNoCan EOL
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
SeqC IPM EOL
Rapid RapidF
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF CoolOff? AND LAST NOT CoolOff?
SeqC DoCoolOff EOL
END
IF NewGear?
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC ' M0' EOL
END
DoOpComments
DoPostScript
SeqC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
Preset MaxRPM
END
ELSE
Preset MaxRPM
END
END
IF NewGear?
GearRange
END
EOL
SeqC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff ' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF LAST ProgStop?
SpinOn
ELSE
IF NewGear?
SpinOn
END
END
EOL
SeqC
IF NewToolOffset?
ToolOfst
END
IF LAST ProgStop?
DoCoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
DoCoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJ
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC IPMC EOL
SeqC ' G4 F2.' EOL
SeqC IPRC Speed InverseSpinOn EOL
Feed
ELSE
IF Dwell?
SeqC IPMC EOL
SeqC ' G4 F' Dwell# EOL
SeqC IPRC EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC IPMC EOL
SeqC
IF LAST ThreadFeat?
Rapid RapidF
ELSE
RapidC RapidFC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC IPRC EOL
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC
IF Taper?
XTapAtZ
END
ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
SeqC IPMC EOL
IF LAST CannedCycle?
Rapid RapidF
ELSE
IF LAST Threading?
Rapid RapidF
ELSE
RapidC RapidFC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('2000')
SetMaxFeed('500')
SetFlagF('1') { ID Turret }
SetFlagF('1') { IPM Rapid Mode }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
IF ToolOver?('10')
{ ID Turret }
NegSideLathe
ReverseXZArcs
SetFlag('1')
ELSE
{ OD Turret }
PosSideLathe
StandardXZArcs
SetFlagF('1')
END
'N' Tool# '00' EOL
DoOpComments
DoPostScript
SeqC SpinOff EOL
SeqC AbsOrInc IncTurret EOL
SeqC ' G0' EOL
SeqC IPM IndexTool EOL
SeqC Preset MaxRPM GearRange EOL
SeqC Preset Home EOL
SeqC SpeedMode Speed SpinOn EOL
SeqC ToolOfst DoCoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
SeqC NewHome ' T0' DoCoolOff EOL
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

IF ToolOver?('10')
{ ID Turret }
NegSideLathe
ReverseXZArcs
SetFlag('1')
ELSE
{ OD Turret }
PosSideLathe
StandardXZArcs
SetFlagF('1')
END
'N' Tool# '00' EOL
DoOpComments
DoPostScript
IF NewGear?
SeqC SpinOff EOL
END
SeqC AbsOrInc IncTurret EOL
SeqC ' G0' EOL
SeqC IPM IndexTool EOL
SeqC Preset MaxRPM GearRange EOL
SeqC Preset Home EOL
SeqC SpeedMode Speed SpinOn EOL
SeqC ToolOfst DoCoolOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Drilling?
IF Tap?
SeqC LCycle ' Z' FinishZ# ' K' FeedIPR# EOL
SeqC SpinOff EOL
SeqC IPMC EOL
SeqC ' G4 F2.' EOL
SeqC IPRC Speed InverseSpinOn EOL
SeqC LCycle ZSP ' K' FeedIPR# EOL
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' MUL# Num#('1') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC IPMC EOL
SeqC ' G4 F2.' EOL
SeqC IPRC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC IPMC EOL
IF CannedCycle?
Rapid RapidF
ELSE
IF Threading?
Rapid RapidF
ELSE
RapidC RapidFC
END
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC FirstHome ' T0' DoCoolOff EOL
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END