{Change Comments ***********************************************************}

{6/14/95, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}
{8/26/95, L001.85.01.01, Changed ToolAngle to 'A' InFeedAngle#, JR}
{6/18/96, rewrote CheckOffset to clean up and correct Speed bug, JR}
{8/20/96, fixed output of Rapid after ThreadFeat, JR}

{9/25/96
Initial: Fanuc 10T MS [-] L001.85.01.02
Created: AB 8600 J&S Grinder Lxxx.85m
ForUser: US Can
Control: Allen Bradley 8600
Machine: Jones & Shipman ID/OD Grinder
Develop: ComPost2 68k v1.0b3, ncCAD 4.33.02, ncCAM 4.33, ncPost 4.33.09
Comment: New Processor per manual and conversations with Jones & Shipman and Steve Garten.
This processor will only output basic moves.
It intended to be used for the finish profile path or diamond dressing only.
Absolute Arc Centers. I for Z and J*2 for X.
G01 and RapidF for Rapid movement.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.###;0'
#3 = '#######0'
#4 = '###^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(XStockMin#,2)
FORMAT(XStockMax#,2)
FORMAT(ZStockMin#,2)
FORMAT(ZStockMax#,2)
FORMAT(RapidF#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in Metric, tools and tool path}
SetScale('25.4') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Feed ThisOpEntryXCP AppMove RapidF EOL
ELSE
IF ApproachID?
SeqC Feed XOpCD AppMove RapidF EOL
ELSE {ApproachFace}
SeqC Feed StockOnNoCan XSP AppMove RapidF EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
END
DoOpComments
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G4P2000' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G4P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Feed
ELSE
FeedC
END
MoveXC MoveZC RapidF EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
';ISO' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
'[UCG,1,Z' ZStockMin# 'Z' ZStockMax# ',X0.' 'X' XStockMax# ']' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
IF LAST ApproachOD?
SeqC FeedC CRCOffC LAST OpExitXCPC RapidFC EOL
ELSE
IF LAST ApproachID?
SeqC FeedC CRCOffC LAST XOpECDC RapidFC EOL
END
END
SeqC FeedC CRCOffC LAST OpExitZCPC RapidFC EOL
DoEndOpPS
SeqC NewHome EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
SeqC FeedC CRCOffC StockOnNoCan XSPC ZSPC RapidFC EOL
ELSE
IF ApproachOD?
IF LAST ApproachOD?
SeqC FeedC CRCOffC LAST XOpECDC RapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC FeedC CRCOffC LAST XOpECDC RapidFC EOL
END
SeqC FeedC CRCOffC LAST OpExitZCPC RapidFC EOL
SeqC FeedC CRCOffC LAST OpExitXCPC RapidFC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC FeedC CRCOffC LAST XOpECDC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC FeedC CRCOffC LAST OpExitXCPC RapidFC EOL
END
SeqC FeedC CRCOffC LAST OpExitZCPC RapidFC EOL
SeqC FeedC CRCOffC XOpCDC RapidFC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC FeedC CRCOffC LAST ZOpECPC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC FeedC CRCOffC LAST OpExitXCPC RapidFC EOL
ELSE {LAST ApproachID}
SeqC FeedC CRCOffC LAST XOpECDC RapidFC EOL
END
SeqC FeedC CRCOffC LAST OpExitZCPC RapidFC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC FeedC CRCOffC ZOpECPC RapidFC EOL
ELSE
SeqC FeedC CRCOffC XOpECDC RapidFC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC FeedC CRCOffC XSPC ZSPC RapidFC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqC Feed XSP RapidF EOL
SeqC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G4P2000' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF ApproachOD?
SeqC FeedC CRCOffC OpExitXCPC RapidFC EOL
ELSE
IF ApproachID?
SeqC FeedC CRCOffC XOpECDC RapidFC EOL
END
END
SeqC FeedC CRCOffC OpExitZCPC RapidFC EOL
DoEndOpPS
SeqC FirstHome EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END