{Change Comments ***********}
{1Sep97
Original: Fanuc 16M Makino A55 C948.13.2
Created: Fanuc 16M Makino A55 Cxxx.13
For: Master Machine
Changes made per: Ron
Added formats for ClearancePlane1#, FeedEntIPR# and ToolOffset#
Added FORMAT#8 and Formatted TLDia# at Prog Numeric Format Definitions
Moved IF NOT SameTool Boolean in DoOpComments, so that Tool Comments will output first.
Added blank Lines at DoOpComments, ProgStart, ToolList and after each OptionalStop
Added code to prevent Output of Negative Angles for the Indexer at CSAngleA and CSAngleB
Deleted references to DoCSWFOComment at CloseMP and WFOStuff
Deleted old version Numbers and Literals e.g. {.81}, {comments} etc.
Added Subs CSdata and DoTheListOfCS
Note: These Subs produce a list of Co-Ordinate Machining Systems used in the Part.
Using an EachOp NextOp loop, Virtual will only provide a list of CSs in the order in which they are
used, however the customer wanted a list placed in the program header
of each Unique occurance in NUMERICAL order. This is acheived by creating an Array of Data ( in the CSdata sub )
using Composts NUM# commands. The maximum number that can be listed is 49 CSs, as there are only
50 variables available and NUM#('50') is used as a Loop counter.
Changed SetMaxRPM from 30000 to 14000 in ProgStart
Added a Program header, initialised the CS List and Added a ToolList in ProgStart
Amended RigidTap cycle per customers requirements.
Deleted WFOStuff from MPallTools1P, MP1ToollAllPfu, MP1ToollAllPXcp and NoMPs
Moved WFOStuff to FirstOp3, NewToolOp5 and SameToolOp3
Added doToolChange Sub in FirstOp1 and replaced the ToolChng command in NewToolOp2
Added doOffsetOn Sub and replaced OffsetOn commands in FirstOp4, NewToolOp6 and SameToolOp3
This Sub prevents the output of the ToolOffset if ClearancePlane1# is Negative and insteads outputs a Literal 'G43Z10H'
Replaced 'IncValue OfstOff' with a Literal 'M98P8885' at SameToolOp1
Added a Boolean to supress the SpinOn command in SameTool, if the RPM has not changed
Deleted CoolOff and SpinOff at End1
Replaced IncValue OfstOff at End1 with a Literal 'M98P8886'
Deleted Literal 'G30X0Y0' and AbsValue at End3
Charles Winston}

{11/23/98,
Initial: Fanuc 16M Makino [MM] CX91.13
Created: Fanuc 16M Makino [M&L] Cxxx.13
For: M&L Industries
Removed tool call macro,
Changed pretool to be output on last op,
added SeqC 'G28' AbsValue 'Z0.M19' EOL to NewTool2
added SeqC 'G28' AbsValue 'Y0.Z0.M19' EOL to End1,
Moved ToolChng up one bloock
MPK}

{11/30/98,
Initial: Fanuc 16M Makino [M&L] Cxxx.13
Created: Fanuc 16M Makino [M&L] Cxxx.13.1
For: M&L Industries
'P000' at program start,
removed tool list,
MPK}

{12/2/98
Initial: Fanuc 16M Makino [M&L] Cxxx.13.1
Created: Fanuc 16M Makino [M&L] Cxxx.13.2
For: M&L Industries
Changed AbsValue to IncValue in tool offset cancel block in NewTool,
modified tool offset cancel block in SameTool to match others,
removed macro call in SameToolOp1 that was mistakenly left,
MPK
}

{
Created: Fanuc 16M LM [M&L] Cxxx.13.3
For: M&L Industries
Added Plane to first op and PlaneC to NewTool to get I's and J's to output
MPK
}

{1/12/99
Initial: Fanuc 16 LM [M&L] CT52.13.3
Created: Fanuc 16 LM [M&L] CT52.13.4
Change Comments:
Form:
None
Prog:
Added Rapid to G80 line after drill cycles,
added ResestCRCNum beginning of Toolpath and Toolpath2,
removed spinoff in End3 when doing Fullup,
added ToolChng to End3 sub,
MPK}


{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#;'
#8 = '####0.0###;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(FeedEntIPR#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(ToolOffset#,5)
FORMAT(NewWFO#,5)
FORMAT(ADD#,5)
FORMAT(SUB#,5)
FORMAT(Recall#,5)
FORMAT(CS#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)
FORMAT(TLDia#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoRepComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF NOT SameTool?
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF SameTool?
' ' EOL
END
RestoreScale
END
RETURN

CalcCSWFO#: {(iPart-1)*NumOfCS#)}
ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSWFO:
'G'
IF GreaterThan? CalcCSWFO# Num#('59')
'54.1P' SUB# CalcCSWFO# Num#('59')
ELSE
CalcCSWFO#
END
RETURN

CSAngleA:
IF AAxisAvail?
FORMAT(SUB#,2)
IF SameTool?
IF AChange?
'A'
IF GreaterThan? CSOffsetA# Num#('0')
SUB# Num#('360.0') CSOffsetA#
ELSE
CSOffsetA#
END
END
ELSE
'A'
IF GreaterThan? CSOffsetA# Num#('0')
SUB# Num#('360.0') CSOffsetA#
ELSE
CSOffsetA#
END
END
FORMAT(SUB#,5)
END
RETURN

CSAngleB:
IF BAxisAvail?
FORMAT(SUB#,2)
IF SameTool?
IF BChange?
'B'
IF GreaterThan? CSOffsetB# Num#('0')
SUB# Num#('360.0') CSOffsetB#
ELSE
CSOffsetB#
END
END
ELSE
'B'
IF GreaterThan? CSOffsetB# Num#('0')
SUB# Num#('360.0') CSOffsetB#
ELSE
CSOffsetB#
END
END
FORMAT(SUB#,5)
END
RETURN

DoCSWFOComment:
IF AAxisAvail? OR BAxisAvail?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
END
RETURN

DoCSG52Comment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

PSInit:
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF Flag?('2') OR WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqC SetWFO SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
END
RETURN

CloseMP:
IF FullUp? AND NOT LastTool?
SeqC IncValue OfstOff EOL {Does not cancel offset in NewToolOp1}
END
IF Flag?('2') OR WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
IF Flag?('2')
SeqC SetWFO EOL
EachCSOp
DoCSG52Comment
ClearCSOffset
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ELSE
EachCSOp
{ DoCSWFOComment }
ClearCSOffset
SeqC CSWFO SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
END
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
IF Flag?('2')
SeqC SetWFO EOL
EachCSOp
DoCSG52Comment
ClearCSOffset
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ELSE
EachCSOp
{ DoCSWFOComment }
ClearCSOffset
SeqC CSWFO SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
END
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF Flag?('2') OR WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
ResetCRCNum
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC ExitType PRIME ZCP2 ExitFeed EOL
END
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC AbsOrInc ExitType ZCP2 ExitFeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
SeqC MoveSXYZC EOL
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

CSdata:
IF LTEqual? Recall# NUM#('50') NumOFCS#
Save# NUM#('50') ADD# Recall# NUM#('50') NUM#('1') {counter}
IF GreaterThan? Recall# Recall# NUM#('50') NUM#('0')
EachOp
IF Equal? Operation# Recall# Recall# NUM#('50')
DoCSWFOComment
END
NextOp
END
END
RETURN

DoTheListOfCS:
Save# Num#('50') NUM#('0') { Setup the Op Number to be examined, (Initialized to zero) }
CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata
CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata
CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata
CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata
CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata CSdata { Limit of 49 CSs }
RETURN

doOffsetOn:
IF LessThan? ClearancePlane1# Num#('0')
'G43Z10H' ToolOffset#
ELSE
SeqC OfstOn
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlagF('2') {not using G52's for multiple parts }
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
SetFlag('7') {True = in rigid tapping Mode }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('14000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('54')
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('2')
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('54')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END

EOR EOL
ProgID1
IF ProgramComment?
'( ' ProgramComment$ ' )'
END
EOL
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF UseComments? AND FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
' ' EOL
EachOp
IF Equal? Recall# CS# NUM#('0')
Save# CS# Operation# { Save the NUMBER of the First Operation in which each Co-Ordinate Machining System is used }
END
NextOp
DoTheListOfCS
RETURN

OpGuts:
IF NOT SameTool?
RapidF# {forces the output of a conditional feedrate}
END
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoRepComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC CRCOffC
IF NOT FeedConnect?
ExitType PRIME ZCP3C
END
ExitFeed EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C
IF LastTool? OR NEXT NOT SameTool?
CoolOff
END
EOL
ELSE
SeqC CRCOffC ExitType ZCP3C ExitFeed
IF LastTool? OR NEXT NOT SameTool?
CoolOff
END
EOL
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
IF RigidTap?
SeqC Speed EOL
SeqC 'G95' EOL
SeqC 'M135S800' EOL
SeqC Cycle FromCP ZDepth RLevel 'F' FeedEntIPR# EOL
ELSE
SeqC Cycle FromCP ZDepth RLevel Dwell Peck Retract FeedEntC EOL
END
TrackZNO# ZDepth#
ToolPath
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC Rapid DrillOff ZCP3
IF LastTool? OR NEXT NOT SameTool?
CoolOff
END
EOL
IF RigidTap?
'G94' EOL
END
SeqC ZCP3C EOL
END
END
RETURN

DefaultWFO:
IF NOT SameTool?
IF NeedWFO1?
SeqC WFO1 EOL
END
END
RETURN

DoCSG52:
DoCSG52Comment
DefaultWFO
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

DefaultCSG52:
IF NOT SameTool?
DoCSG52
END
RETURN

DefaultCSWFO:
IF NOT SameTool?
SeqC CSWFO
END
RETURN

WFOStuff:
IF MultipleParts?
IF NOT WorkFixtureOffsets?
DefaultWFO
END
ELSE
IF WFOCS?
IF ChangeCS?
{ DoCSWFOComment }
SeqC CSWFO
ELSE
DefaultCSWFO
END
ELSE
IF ChangeCS?
DoCSG52
ELSE
DefaultCSG52
END
END
ClearCSOffset
END
RETURN

InitOp:
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE AND ' Plane ' Plane )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
' ' EOL
Seq
IF ToolComment?
'( ' ToolComment$ ' )'
END
EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
GetCycle
IF Drilling? AND RigidTap?
SeqC 'G8P0' EOL
SetFlag('7')
ELSE
SetFlagF('7')
END
RETURN

FirstOp3:
CheckPass
IF AAxisAvail? OR BAxisAvail?
SeqC 'M11' EOL {Unclamp rotary table}
END
SeqC WFOStuff Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB
IF Drilling?
IF NOT RigidTap?
SpeedC SpinOn
END
ELSE
SpeedC SpinOn
END
EOL
IF AAxisAvail? OR BAxisAvail?
SeqC 'M10' EOL {Clamp rotary table}
END
RETURN

FirstOp4:
SeqC doOffsetOn CoolOn
IF NOT LastTool?
PreTool
END
EOL
RETURN

NewToolOp1:
RETURN

NewToolOp2:
IF Flag?('7')
SeqC 'G8P1' EOL
END
DoEndOpPS
SeqC 'G28' IncValue 'Z0.M19' EOL
IF LAST ProgStop?
SeqC 'M0'
IF OperationComment?
'( ' OperationComment$ ' )'
END
EOL
ELSE
SeqC ProgStop EOL
END
SeqC ToolChng EOL
SeqC ' ' EOL
RETURN

NewToolOp3: {Start new Operation}
Seq
IF ToolComment?
'( ' ToolComment$ ' )'
END
EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
GetCycle
IF Drilling? AND RigidTap?
SeqC 'G8P0' EOL
SetFlag('7')
ELSE
SetFlagF('7')
END
RETURN

NewToolOp5:
CheckPass
IF AAxisAvail? OR BAxisAvail?
SeqC 'M11' EOL {Unclamp rotary table}
END
SeqC WFOStuff PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB
IF Drilling?
IF NOT RigidTap?
Speed SpinOn
END
ELSE
Speed SpinOn
END
EOL
IF AAxisAvail? OR BAxisAvail?
SeqC 'M10' EOL {Clamp rotary table}
END
RETURN

NewToolOp6:
SeqC doOffsetOn CoolOn PreTool EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC 'G28' IncValue 'Z0.M19' EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
SeqC SpinOff EOL
SeqC 'M0'
IF OperationComment?
'( ' OperationComment$ ' )'
END
EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
IF AAxisAvail? OR BAxisAvail?
IF SameTool?
IF AChange? OR BChange?
SeqC 'M11' EOL {Unclamp rotary table}
END
END
END
SeqC PlaneC WFOStuff AbsOrInc Rapid StrtPos CSAngleA CSAngleB
IF Drilling?
IF NOT RigidTap?
SpeedC
END
ELSE
SpeedC
END
EOL
IF AAxisAvail? OR BAxisAvail?
IF SameTool?
IF AChange? OR BChange?
SeqC 'M10' EOL {clamp rotary table}
END
END
END
SeqC doOffsetOn CoolOn EOL
ELSE
IF AAxisAvail? OR BAxisAvail?
IF SameTool?
IF AChange? OR BChange?
SeqC 'M11' EOL {Unclamp rotary table}
END
END
END
SeqC PlaneC WFOStuff RapidC StrtPos CSAngleA CSAngleB
IF Drilling?
IF NOT RigidTap?
SpeedC
END
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed SpinOn
END
END
EOL
IF AAxisAvail? OR BAxisAvail?
IF SameTool?
IF AChange? OR BChange?
SeqC 'M10' EOL {clamp rotary table}
END
END
END
SeqC
IF NewToolOffset? OR ChangeCS?
doOffsetOn
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
RETURN

End1:
IF Flag?('7')
SeqC 'G8P1' EOL {Used For rigid Tapping}
END
SeqC 'G28' IncValue 'Y0.Z0.M19' EOL
IF OptionalStops?
'M1' EOL
END
' ' EOL
RETURN

End2:
DoEndOpPS
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp4
OpenMP
FirstOp3 {can't XY position before WFO}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp6
OpenMP
NewToolOp5 {can't XY position before WFO}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END