{Change Comments ***********************************************************}

{10/31/89
Copied & modified: Fan 6M MS MV35 [¨] M051.55
For: Accutool
Machine: Matsura RA2
Control: Yasnac MX3
Modified per customer requests.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/26/91,
Modified: Yasnac MX3 Mat [AM] M267.62
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{2/25/93
Copied & modified: Yasnac MX3 Mat [AM] M267.79
For: Majic Mfg
Updated to Version 4.1 per Fanuc 6M M001.81 Format.
Changed OfstOff in MachSpec to output G49.
Changed FORMAT for Dwell to 3 place, Trailing Zeros.
250 = 1/4 second.
Changed Comments back to M001 standard.
Moved CRCOff back to M001 standard.
Added FIRST TOOL NOT IN SPINDLE.
Added ASCII('13') at FirstOperation and NewTool.
Moved Speed SpinOn to StrPos block at FirstOperation and NewTool.
Changed IncValue to WFOOff at OfstOff block at NewTool, SameTool and end of Prog.
This is a one shot G53 code to return to Machine Reference Coordinates, i.e. Fanuc G28.
Added Rigid Tapping Mode at Drilling.
Added G89 Bore Cycle with Dwell at Drilling.
JR}

{8/17/93
Updated: Yasnac MX3 Mat [MM] M553.81
For: Gibbs & Associates/Matsurra
Updated per Fanuc 6M M001.81.2 Format.
Needed for creation of Yas MX3 Mat [AbsZAC] M.81.2 for Makato Uemura at Matsurra.
DWB}

{2/16/95
Modified: Yasnac MX3 Mat [MM] M553.81.2
For: Murtaugh Represents / Aero Precision
Control: Yasnac i80
First Tool In Spindle. PreTool. Block delete CoolOn.
Changed output of OfstOff.
Jim Radcliffe}

{3/16/95
Modified: Yasnac i80 M00A.81.2
For: Murtaugh Represents / Aero Precision
Control: Fanuc 0M
Modified sub repetitions calls.
Modified Rigid Tapping cycle.
Jim Radcliffe}

{8/19/95, Updated Fanuc 0M [AP] M788.81.2 to .85 format per Fanuc 6M M001.85.01.02, JR}

{1/9/96
Initial: Fanuc 0M [AP] M788.85
Created: Fanuc 16M [AP] C000.10.02
ForUser: Murtaugh Represents / Aero Precision
Control: Fanuc 16M
Machine: Mori Seiki SH-50
Develop: ComPost 4.21.33, Catalyst68K v2.30.22C
Comment: New Processor per marked up readout and conversation with Pete Lonero
Converted to C Style Advanced Mill Processor
Separate multiple parts sub call and WFO to separate lines.
ToolChangeAtHome Position is not supported. Hardcoded G91G30X0Y0Z0!
48 Work Offsets G54P1 thru G54P48.
MachSpec is P1 thru P48!
Added literal G54 to Prog before WFO calls!
Jim Radcliffe}

{1/19/96
Initial: Fanuc 16M [AP] C000.10.02
Created: Fanuc 16M [AP] C000.10.03
ForUser: Murtaugh Represents / Aero Precision
Develop: ComPost 4.21.33, Catalyst68K v2.30.26C
Comment: additional request per Peter Lonero
Added G91G28B0 to the beginning of the program.
Machine must be at B home before shuttling!
Added G8P1 to milling operations
Added G8P0 to drilling operations
Corrected bug of literal 2 being output when doing multiple parts
reversed the oder of the boolaen statment from:
IF WFOCS? OR Flag?('2')
to:
IF Flag?('2') OR WFOCS?
Jim Radcliffe}

{1/24/96
Initial: Fanuc 16M [AP] C000.10.03
Created: Fanuc 16M [AP] C000.10.04
ForUser: Murtaugh Represents / Aero Precision
Develop: ComPost 4.21.33, Catalyst68K v2.30.27C
Comment: Per Pete Lonero, B move before XY positioning move.
Jim Radcliffe}

{7/10/96,
Initial: Fanuc 16M [AP] C789.10.04
Created: Fanuc 16M [AP] C789.13
Added redundant StrtPos to BeginTool2 that only outputs when multiple part OTAP, customer wants
to have Start Pos in the main program. Updated to .13 format, MPK}

{7/15/96,
Initial: Fanuc 16M [AP] C789.13
Created: Fanuc 16M [AP] C789.13.1
Put the redundant output of StartPos along with Offset on into OpenMP and CloseMP when OTAP so that
XY positioning always comes before Z move, MPK}
{7/17/96,
Initial: Fanuc 16M [AP] C789.13.1
Created: Fanuc 16M [AP] C789.13.2
Made output of Length offset in OpenMP and CloseMP conditional upon being the first part cut with each tool, used
Flag('7') to keep track since I could not use if FirstPart? because of the toogling of increasing/decreasing WFOs, MPK}

{7/17/96,
Initial: Fanuc 16M [AP] C789.13.2
Created: Fanuc 16M [AP] C789.13.3
Modified output of CoolOn to output insode the MP subroutine when OTAP, MPK}

{9/30/96,
Initial: Fanuc 16M [AP] C789.13.3
Created: Fanuc 16M [AP] C789.13.4
deleted tool change, offset cancel, rotacaion reset and m60 from InitOp,
added AbsOrInc and ProgStop to InitOp,
changed Seq in BeginTool1 to 'N' Tool# (control does not have a problem with duplicate sequence numbers,
added CSAngle moves to saftey start block in BeginTool1,
Move tool changes from EndTool2 to BeginTool1,
made CSangle moves in BeginTool3 conditional upon being MP, OTAP (this was to avoid possible
problems with the rotation being outside of the MP sub.)
deleted tool change at program end,
MPK}

{11/19/96
Initial: Fanuc 16M [AP] C789.13.4
Created: Fanuc 16M [AP] C789.13.5
ForUser: Aero Precision
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Modified per marked up readout from Peter Lonero
Moved CoolOn to wherever we call OfstOn.
Moved CoolOff to wherever we call OfstOff.
Added redundant Speed output for Multiple Parts subs as Speed may get changed with next SameTool.
Jim Radcliffe}

{10/02/97, Converted to metric. CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(FeedTapIPR#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(TCZ#,4)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Parts#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6) {.72}
FORMAT(Program#,7)
FORMAT(CSSubID#,7)
FORMAT(CallMasterNum#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )'
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
'G54P' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'G54P' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
'A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
RETURN

DoCSG52Comment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
ASCII('13') SubID DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLabB RepCycs Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
SetFlag('7')
IF Flag?('2') OR WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC 'G54' SetWFO EOL
IF OneToolAllParts?
SeqC StrtPos EOL
IF Flag?('7')
SeqC OfstOn '/' CoolOn EOL
SetFlagF('7')
END
END
SeqC SubCall CallLabB OnePart Program# EOL
IncWFO
NextWFO
ELSE
IF OneToolAllParts?
SeqC StrtPos EOL
IF Flag?('7')
SeqC OfstOn '/' CoolOn EOL
SetFlagF('7')
END
END
SeqC SubCall CallLabB Parts Program# EOL
END
StartSub
END
RETURN

CloseMP:
IF Flag?('2') OR WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
IF Flag?('2')
SeqC 'G54' SetWFO EOL
EachCSOp
DoCSG52Comment
ClearCSOffset
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
IF OneToolAllParts?
SeqC StrtPos EOL
IF Flag?('7')
SeqC OfstOn '/' CoolOn EOL
SetFlagF('7')
END
END
SeqC SubCall CallLabB OnePart CSSubID# EOL
NextCSOp
ELSE
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
IF OneToolAllParts?
SeqC StrtPos EOL
IF Flag?('7')
SeqC OfstOn '/' CoolOn EOL
SetFlagF('7')
END
END
SeqC SubCall CallLabB OnePart CSSubID# EOL
NextCSOp
END
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
IF Flag?('2')
SeqC 'G54' SetWFO EOL
EachCSOp
DoCSG52Comment
ClearCSOffset
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
IF OneToolAllParts?
SeqC StrtPos EOL
IF Flag?('7')
SeqC OfstOn '/' CoolOn EOL
SetFlagF('7')
END
END
SeqC SubCall CallLabB OnePart CSSubID# EOL
NextCSOp
ELSE
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
IF OneToolAllParts?
SeqC StrtPos EOL
IF Flag?('7')
SeqC OfstOn '/' CoolOn EOL
SetFlagF('7')
END
END
SeqC SubCall CallLabB OnePart CSSubID# EOL
NextCSOp
END
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF Flag?('2') OR WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
SetFlag('5')
END
END
RETURN

FormatLine:
DoAbsOrInc CkCRC FeedC MoveXYZC
RETURN

CkCRCNum:
IF Flag?('5')
SetFlagF('5')
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLabB OnePart Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC CRCOffsetC MoveXYZC EOL
END
END
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC CkCRCNum EOL
DecelMove2
END
SeqC FormatLine DecelFeed CkCRCNum EOL
ELSE
SeqC FormatLine FeedRateC CkCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLabB OnePart Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLabB OnePart Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlagF('2') {not using G52's for multiple parts }
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') {True = need CRCOffset }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
IF Metric?
SetMaxRPM('12000')
ELSE
SetMaxFeed('500')
END
SetTCZ('7')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('48')
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('2')
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('48') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC 'G8P1' EOL
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
SeqC 'G8P0' EOL
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC Rapid StrtPos EOL
END
GetCycle
IF Tap? AND OptCyc1? {Rigid Tapping Mode}
SeqC 'M29' Speed EOL
END
SeqC FromCP
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB OnePart CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLabB OnePart Program# EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC DrillOff ZCP3 EOL
IF Repeats?
FinishSubG92
SeqC ZCP3C EOL
END
END
END
RETURN

DefaultWFO:
IF NOT SameTool?
IF NeedWFO1?
SeqC 'G54' WFO1 EOL
END
END
RETURN

DoCSG52:
DoCSG52Comment
DefaultWFO
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

DefaultCSG52:
IF NOT SameTool?
DoCSG52
END
RETURN

DefaultCSWFO:
IF NOT SameTool?
SeqC CSWFO EOL
END
RETURN

WFOStuff:
IF MultipleParts?
IF NOT WorkFixtureOffsets?
DefaultWFO
END
ELSE
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqC CSWFO EOL
ELSE
DefaultCSWFO
END
ELSE
IF ChangeCS?
DoCSG52
ELSE
DefaultCSG52
END
END
ClearCSOffset
END
RETURN

InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqC AbsOrInc EOL
SeqC ProgStop EOL
RETURN

BeginTool1:
'N' Tool# Rapid Plane CRCOff DrillOff AbsOrInc CSAngleA CSAngleB EOL
SeqC OpToolID EOL
SeqC ToolChng EOL
DoOpComments
DoPostScript
RETURN

BeginTool2:
SeqC Speed SpinOn PreTool EOL
RETURN

BeginTool3:
CheckPass
SeqC AbsOrInc Rapid
IF MultipleParts? AND OneToolAllParts?
CSAngleA CSAngleB
END
EOL
SeqC StrtPos EOL
RETURN

BeginTool4:
IF NOT MultipleParts?
SeqC OfstOn '/' CoolOn EOL
ELSE
IF NOT OneToolAllParts?
SeqC OfstOn '/' CoolOn EOL
END
END
RETURN

EndTool1:
SeqC Rapid 'Z' TCZ# EOL {OfstOff-Full Up}
RETURN

EndTool2:
IF AbsoluteMoves?
SeqC IncValue 'G30X0Y0Z0' CoolOff EOL
SeqC AbsValue SpinOff EOL
ELSE
SeqC 'G30X0Y0Z0' CoolOff EOL
SeqC SpinOff EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
ASCII('13')
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC Rapid 'Z' TCZ# CoolOff EOL
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
SeqC
IF NewToolOffset? or ChangeCS?
Rapid 'Z' TCZ#
END
IF CoolOff? AND LAST NOT CoolOff?
CoolOff
END
EOL
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC AbsOrInc Rapid CSAngleA CSAngleB EOL
SeqC PlaneC StrtPos SpeedC SpinOn EOL
SeqC OfstOn '/' CoolOn EOL
ELSE
SeqC AbsOrInc Rapid CSAngleA CSAngleB EOL
SeqC PlaneC StrtPos SpeedC EOL
SeqC
IF NewToolOffset? OR ChangeCS?
OfstOn
END
IF NOT CoolOff? AND LAST CoolOff?
'/' CoolOn
END
EOL
END
RETURN

EndProgram2:
IF AbsoluteMoves?
SeqC IncValue 'G30X0Y0Z0' CoolOff EOL
SeqC AbsValue SpinOff EOL
ELSE
SeqC 'G30X0Y0Z0' CoolOff EOL
SeqC SpinOff EOL
END
DoEndOpPS

IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

EndProgram3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
BeginTool1
WFOStuff
BeginTool2
BeginTool3
BeginTool4
ELSE
IF NewTool?
EndTool1
EndTool2 {to tool change, CS problem}
SubCSMP
BeginTool1
WFOStuff
BeginTool2
BeginTool3
BeginTool4
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
EndTool1 {End of program}
EndProgram2
CloseMP
EndProgram3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
BeginTool1
WFOStuff
BeginTool2
OpenMP
SeqC Speed EOL
BeginTool3
BeginTool4
ELSE
IF NewTool?
EndTool1
CloseMP
EndTool2 {to tool change, CS problem}
BeginTool1
WFOStuff
BeginTool2
OpenMP
SeqC Speed EOL
BeginTool3
BeginTool4
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
EndTool1 {End of program}
CloseMP
EndProgram2
EndProgram3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
BeginTool1
WFOStuff
BeginTool2
BeginTool4
OpenMP
SeqC Speed EOL
BeginTool3 {can't XY position before WFO}
ELSE
IF NewTool?
CloseMP
EndTool1
EndTool2 {to tool change, CS problem}
BeginTool1
WFOStuff
BeginTool2
BeginTool4
OpenMP
SeqC Speed EOL
BeginTool3 {can't XY position before WFO}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
EndTool1
EndProgram2
EndProgram3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
BeginTool1
WFOStuff
BeginTool2
BeginTool3
BeginTool4
ELSE
IF NewTool?
EndTool1
EndTool2
BeginTool1
WFOStuff
BeginTool2
BeginTool3
BeginTool4
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
EndTool1 {End of program}
EndProgram2
EndProgram3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END