{Change Comments ***********************************************************}

{8/29/95
Modified: Heid TNC 155 Hkrt-Y M613.81.3
Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format.
Changed all literal ' M09' to CoolOff Command 4 places at FirstOperation, NewTool, SameTool, end of
IF Milling and end of IF Drilling.
Changed literal ' M05' to SpinOff Command at NewTool.
DWB}

{5/24/96, Updated to .89 format, MPK}

{02/12/99, Changed to Metric. CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = 'ą####0.000'
#5 = '#######0'
#6 = '####0.000'
#7 = '###^0'
#8 = '+####0.000'
#9 = 'ą####0.000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ABS#,2)
FORMAT(DIV#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(ZDepth#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnShiftPX#,4)
FORMAT(OriginUnShiftPY#,4)
FORMAT(OriginUnShiftPZ#,4)
FORMAT(OriginUnShiftRX#,4)
FORMAT(OriginUnShiftRY#,4)
FORMAT(OriginUnShiftRZ#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(TLLength#,4)
FORMAT(TLDia#,4)
FORMAT(TLNum#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Program2#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(FeedEntry#,7)
FORMAT(ClearancePlane2#,8)
FORMAT(ZDepthInc#,8)
FORMAT(Peck#,8)
FORMAT(ClearancePlane1#,9)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in Enlgish, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
ELSE
SetScale('1')
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoL:
' L'
Return

DoM:
' M'
Return

DoR0:
' R0'
Return

RF: { RapidF }
' F1500'
Return

EntryMove:
SeqLab DoL
IF AutoCycle? {implies incremental}
' IY' SPZ#
ELSE
ZIn
END
DoR0
IF FeedEntry?
FeedEnt
ELSE
RF
END
DoM EOL
RETURN

StartSub:
OpenSub
DoSubComment
SeqLab ' LBL ' Program# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Y CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# ' REP ' Repeats# '/ ' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoL ZCP3 DoR0
IF AutoCycle?
RF
ELSE
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
END
DoM EOL
END
RETURN

FinishSubG92: {part 2}
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' RepeatX# EOL
SeqLab ' CYCL DEF 7.2 IY' RepeatZ# EOL
SeqLab ' CYCL DEF 7.3 IZ' RepeatY# EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftRX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftRZ#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftRY#('0') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# ' REP ' Parts# ' / ' Parts# EOL
StartSub
ELSE
'( NOTE: This post processor does not support work fixture offsets!!! )' EOL
'( Reprocess using Equally Spaced Offsets!!! )' EOL
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftZ# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftY# EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPZ#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPY#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

DoCRC:
IF CRCleft?
' RL'
ELSE
' RR'
END
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF ArcFeat?
DoCRC
ELSE
IF LastFeat?
DoR0
ELSE
IF NotEqual? SPX# EPX# { XMove }
DoCRC
ELSE
IF NotEqual? SPY# EPY# { YMove }
DoCRC
ELSE
IF NotEqual? SPZ# EPZ# { ZMove }
DoR0
END
END
END
END
END
ELSE
DoR0
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

DoHelix:
SetAbs
'P IPA'
IF ArcCW?
'+'
ELSE
'-'
END
IF Equal? EPMoveAngle# SPMoveAngle# { Full Circle }
'360.000'
ELSE
ABS# SUB# EPMoveAngle# SPMoveAngle#
END
SetInc
IF XYPlane?
' IY' EPZ#
ELSE
IF XZPlane?
' IZ' EPY#
ELSE { YZPlane }
' IX' EPX#
END
END
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF AutoCycle?
SetInc
ELSE
SetAbsOrInc
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XYPlane?
IF ArcFeat? OR XMove? OR YMove?
' IX' EPX# ' IZ' EPY#
END
IF ZMove?
' IY' EPZ#
END
ELSE
IF XZPlane?
IF ArcFeat? OR XMove? OR ZMove?
' IX' EPX#
IF YMove?
' IZ' EPY#
END
' IY' EPZ#
ELSE
IF YMove?
' IZ' EPY#
END
END
ELSE { YZPlane }
IF ArcFeat? OR YMove? OR ZMove?
IF XMove?
' IX' EPX#
END
' IZ' EPY# ' IY' EPZ#
ELSE
IF XMove?
' IX' EPX#
END
END
END
END
ELSE
IF XYPlane?
MoveX MoveY MoveZC
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE { YZPlane }
MoveXC MoveY MoveZ
END
END
END
RETURN

FormatArc:
DoAbsOrInc
IF AutoCycle? {implies incremental}
' CC IX' ArcI# ' IZ' ArcJ# EOL
ELSE
' CC' ArcIJ EOL
END
SeqLab ' C'
IF XYPlane? AND ZMove?
DoHelix
ELSE
IF XZPlane? AND YMove?
DoHelix
ELSE
IF YZPlane? AND XMove?
DoHelix
ELSE
CheckMove
END
END
END
IF ArcCW?
' DR+'
ELSE
' DR-'
END
CkCRC
RETURN

FormatLine:
DoAbsOrInc DoL CheckMove CkCRC
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab DoL MoveSX MoveSY DoR0 RF DoM EOL
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoL DoDrillAbsOrInc
IF NOT AbsValue?
IF XMove? OR YMove?
' IX' SPX# ' IZ' SPY#
END
IF ZMove?
' IY' SPZ#
END
ELSE
MoveSX MoveSY
END
DoR0 RF ' M99' EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc DoL CheckMove ckCRC RF DoM EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRate DoM EOL
DecelMove2
END
SeqLab FormatLine DecelFeed DoM EOL
ELSE
SeqLab FormatLine FeedRate DoM EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeed DoM EOL
DecelMove2
END
SeqLab FormatArc DecelFeed DoM EOL
ELSE
SeqLab FormatArc ArcFeed DoM EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLab DoL ZCP2 DoR0
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
SeqLab DoL StrtPos DoR0
IF FeedConnect?
FeedEnt
ELSE
RF
END
DoM EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# DoR0 FeedRate DoM EOL
AbsOrInc
END
END
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# DoR0 RF DoM EOL
AbsOrInc
IF FeedEntry?
SeqLab DoL ZCP2PlusInc DoR0 RF DoM EOL
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoL ZInPlusInc DoR0 RF DoM EOL
END
ELSE
IF FeedEntry?
SeqLab DoL ZCP2PlusInc DoR0 RF DoM EOL
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoL ZInPlusInc DoR0 RF DoM EOL
END
END
ELSE
IF FeedEntry?
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoL ZInPlusInc DoR0 RF DoM EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLab DoL ZCP2 DoR0
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
DoM EOL {.69}
END {.69}
SeqLab ' LBL 0' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos DoR0
IF FeedConnect?
FeedEnt
ELSE
RF
END
DoM EOL
END
IF FeedConnect?
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab DoL ZCP2PlusIncC DoR0 RF DoM EOL
END
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoL ZInPlusInc DoR0 RF DoM EOL
END
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SaveProgNum2
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
SeqLab ' BEGIN PGM ' Program# ' INCH' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
EachTool
SetScale('1')
SeqLab ' TOOL DEF ' TLNum#
RestoreScale
DoL TLLength#
' R' DIV# TLDia# Num#('2') { TLRadius# }
EOL
NextTool
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SetAbs
Plane {no output}
IF NOT LastTool?
SeqLab DoL Home DoR0 RF DoM EOL
SeqLab ' STOP' SpinOff EOL
END
SeqLab DoL Home DoR0 RF DoM EOL
SeqLab ' TOOL CALL ' Tool# ' Y' TABLE(2,SpeedRPM#,1) EOL
SeqLab DoL Home DoR0 RF DoM EOL
SeqLab DoL ZCP1 DoR0 RF DoM EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
END
CheckPass
SeqLab DoL StrtPos DoR0 RF SpinOn EOL
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab DoL Home DoR0 RF CoolOff EOL
SeqLab ' STOP M00' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SetAbs
Plane {no output}
SeqLab DoL Home DoR0 RF DoM EOL
SeqLab ' STOP' SpinOff EOL
SeqLab ' TOOL CALL ' Tool# ' Y' TABLE(2,SpeedRPM#,1) EOL
SeqLab DoL ' Y' ClearancePlane1# DoR0 RF DoM EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
END
CheckPass
SeqLab DoL StrtPos DoR0 RF SpinOn EOL
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab DoL Home DoR0 RF CoolOff EOL
SeqLab ' STOP M00' EOL
END

{Start new Operation}

GetStartOfSameTool
SetAbs
Plane {no output}
SeqLab DoL StrtPos DoR0 RF SpinOn EOL
END
END
END {common point for all operations}
IF Milling?
SeqLab DoL ZCP2 DoR0 RF DoM EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLab DoL ZCP3 DoR0
IF AutoCycle?
RF
ELSE
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
END
CoolOff EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab DoL StrtPos DoR0 RF DoM EOL
END
IF NOT RetractToCP1?
SeqLab DoL ZCP2 DoR0 RF DoM EOL
END
GetCycle
IF Tap?
SeqLab ' CYCL DEF 2.0 TAPPING' EOL
SeqLab ' CYCL DEF 2.1 SETUP -' ClearancePlane2# EOL
SeqLab ' CYCL DEF 2.2 DEPTH ' ZDepth# EOL
SeqLab ' CYCL DEF 2.3 DWELL 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SETUP -' ClearancePlane2# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' ZDepth# EOL
SeqLab ' CYCL DEF 1.3 PECKG -'
IF Peck?
Peck#
ELSE
ZDepthInc#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
IF CallMasterOp?
SeqLab ' CALL LBL ' CallMasterNum# ' REP' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab ' CALL LBL ' Program# ' REP' EOL
StartSub
ToolPath
SeqLab ' LBL 0' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
{SetDrillEndOpZ}
IF Repeats?
FinishSubG92
END
SeqLab DoL ZCP3 DoR0 RF CoolOff EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
SeqLab DoL Home DoR0 RF SpinOff EOL
SeqLab ' STOP M30' EOL
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Reopen
SeqLab ' END PGM ' Program2# ' INCH' EOL
ASCII('3') EOL
Close
Retag