{Change Comments ***********************************************************}

{6/1/95
Copied: Fanuc 6M M001.81.2f
Created: D&M 4s/6s M798.81.2
For: Mid West Tech
Machine: D&M 4s/6s CNC Mill
Control: D&M Level 3s Software
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Changes made per conversations with Jeff Cooper of D&M Computer, Inc. and training manual.
Numerous modifications made per manual.
DWB}

{9/26/95
Updated and Modified: D&M 4s/6s M798.81.2
For: Mid West Tech
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.22/Compost 4.21.32/1.0a
Changes made per Wyman of Mid West Tech.
Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format.
Changed all occurances of literal M07 to G94 for Mac FeedRates.
Commented out FormatNameComment at FirstOperation.
Commented out StartToolComment at FirstOperation.
Deleted literal '?' at FirstOperation and NewTool.
Moved 'G70' block from before DoOpComments to after at FirstOperation and NewTool.
Deleted 'G80' block at FirstOperation and NewTool.
Deleted ToolChng OpToolID block at FirstOperation and NewTool.
Added call to GetFeedEnt prior to StrtPos block at FirstOperation, NewTool and SameTool.
Moved ZCP1 from StrtPos block to block by itself following StrtPos block at FirstOperation,
NewTool and SameTool.
Deleted CoolOn at FirstOperation, NewTool and SameTool.
Deleted CoolOff at NewTool, SameTool and end of Prog.
Deleted SpinOff at NewTool, SameTool and end of Prog.
Deleted call to GetFeedEnt at IF Drilling.
Added ReTag at end of Prog.
Commented out File Length Comments as end of Prog.
DWB}

{9/26/95
Copied: D&M 4s/6s M798.85
Created: D&M 4s/6s [DOS] M863.85
For: Mid West Tech
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.22/Compost 4.21.32/1.0a
Changes made per Wyman of Mid West Tech.
Changed all Speed blocks to SpinOn ' ' SpeedRPM# at FirstOperation, NewTool and SameTool.
Changed all occurances of literal G94 to M07 for IBM FeedRates.
Added GetAbsOrInc sub to keep track of AbsValue/IncValue mode status.
Added RapidG90 sub to output literal RAPID G90 on all Absolute Rapid Moves.
Added RapidG90 sub to output literal RAPID G91 on all Incremental Rapid Moves.
Added FeedG90 sub to output literal FEED G90 on all Absolute Feed Moves.
Added FeedG90 sub to output literal FEED G91 on all Absolute Feed Moves.
DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{11/26/96
Copied: D&M 4s/6s [IBM] M863.85
Created: D&M 4s/6s [IBM] M863.85.01
For: D & M Technologies
modified form by changing Spindle Forward from M03 to M04.
modified form by disabling the Arc Stop on Quadrant feature.
WS}

{9/30/97
Updated & Modified: D&M 4s/6s [IBM] M863.89.01
Created: D&M 4s/6s [IBM] M863.89.2
For: D & M Technologies
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Jeff Bakke of D & M Technologies and phone conversations.
Updated for Catalyst v3.35C per Fanuc 6M M001.89b Format.
Customer requested that Rapid or Feed be output following any M-Code output, at start of all subs
and in Main Program following return from sub.
Rewrote Prog to conform.
Customer requested ToolChng ' ' Tool# at all ToolChanges.
Added ToolChng ' ' Tool# EOL block prior to call to DoOpComments at FirstOperation and NewTool.
Customer requested ZDepth value output on all ToolPath blocks of all Drilling Cycles.
Added condition at ToolPath PointFeat.
Customer agrees that post will not support MasterOp/CallMasterOp situations.
DWB}

{5/28/98
Initial: D&M 4s/6s [IBM] M863.89.2
Created: D&M 4s/6s [IBM] MY62.89.3
ForUser: Lab-Volt Systems
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: Modified per fax from Jeff Bakke
Problem Jeff wrote:
When creating contours with large data point sets in Virtual Gibbs, the post
processor creates something similar to:
G01
X1.0 Y1.0 FEED ABS
Y2.0 Z-.5 FEED ABS
X1.2 Y1.4 FEED ABS
X2.0 Y1.3 FEED ABS
Etc...
Due to some memory limitations in our firmware for our mills....this executes
as a single command (GO1) with each following coordinate line as a parameter.
This command can grow very large when huge move chains are created in the post.
We would like to break up these large sets of move commands into smaller, more
manageable units. For the GOO and G01 commands, could you either dump an extra
GOO/G0l start command every 20 coordinate sets (preferred), or simply prefix
every coordinate with a GOO/GOl command. i.e. change the above sample to:
G01
X1.0 Y1.0 FEED ABS
G01
Y2.0 Z-.5 FEED ABS
G01
X1.2 Y1.4 FEED ABS
G01
X2.0 Y1.3 FEED ABS
Etc...
Changes to Prog:
Changed FeedC to Feed in GetFeedC sub.
G01 is now considered non-modal.
Jim Radcliffe}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.###;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '###0'
#8 = '##0.000;0.000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(SpeedRPM#,5)
FORMAT(Dwell#,6)
FORMAT(Recall#,7)
FORMAT(FeedContour#,7)
FORMAT(FeedEntry#,7)
FORMAT(ArcFeed#,7)
FORMAT(DecelFeed#,7)
FORMAT(SUB#,8)
FORMAT(XStockMax#,8)
FORMAT(YStockMax#,8)
FORMAT(ZStockMax#,8)
FORMAT(ZStockMin#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

SetSeqOff:
SetLineStrtChr('')
RETURN

SetSeqC:
IF NOT MinimizeSequencing?
SetLineStrtChr('?')
END
RETURN

WFONum:
{ NOTE: This Post Processor does not support WorkFixtureOffsets }
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SetSeqOff
'\ SUB NUMBER: ' Program# EOL
SetSeqC
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
SetSeqOff
IF OperationIDComment?
'\ OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'\ ' OperationComment$ EOL
END
IF WorkGroupComment?
'\ ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'\ TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'\ ' ToolComment$ EOL
END
RestoreScale
SetSeqC
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL
PSStuff
NextPS
RETURN

GetAbsOrInc:
IF AbsValue?
AbsValue
ELSE
IncValue
END
RETURN

GetRapid:
Rapid EOL
SetFlagF('2') { NeedRapidOrFeed }
RETURN

GetRapidC:
IF Flag?('2')
GetRapid
ELSE
RapidC EOL
END
RETURN

GetRapid1:
IF NOT EmptyLine?
' Rapid' GetAbsOrInc
END
RETURN

GetFeed:
Feed EOL
SetFlagF('2') { NeedRapidOrFeed }
RETURN

GetFeedC:
IF Flag?('2')
GetFeed
ELSE
Feed EOL { changed from FeedC to Feed 5/28/98 }
END
RETURN

GetFeed1:
IF NOT EmptyLine?
' Feed' GetAbsOrInc
END
RETURN

GetFeedEnt:
' M07 ' FeedEntry# EOL { Feed Parameter Setting }
Save# Num#('1') FeedEntry#
SetFlag('2') { NeedRapidOrFeed }
RETURN

GetFeedEntC:
IF NotEqual? Recall# Num#('1') FeedEntry#
GetFeedEnt
END
RETURN

GetFeedRate:
' M07 ' FeedContour# EOL { Feed Parameter Setting }
Save# Num#('1') FeedContour#
SetFlag('2') { NeedRapidOrFeed }
RETURN

GetFeedRateC:
IF NotEqual? Recall# Num#('1') FeedContour#
GetFeedRate
END
RETURN

GetDecelFeed:
' M07 ' DecelFeed# EOL { Feed Parameter Setting }
Save# Num#('1') DecelFeed#
SetFlag('2') { NeedRapidOrFeed }
RETURN

GetDecelFeedC:
IF NotEqual? Recall# Num#('1') DecelFeed#
GetDecelFeed
END
RETURN

GetArcFeed:
' M07 ' ArcFeed# EOL { Feed Parameter Setting }
Save# Num#('1') ArcFeed#
SetFlag('2') { NeedRapidOrFeed }
RETURN

GetArcFeedC:
IF NotEqual? Recall# Num#('1') ArcFeed#
GetArcFeed
END
RETURN

EntryMove:
IF FeedEntry?
GetFeedEntC
GetFeed ZIn GetFeed1 EOL
ELSE
GetRapidC ZIn GetRapid1 EOL
END
RETURN

StartSub:
OpenSub
' M98 ' Program# EOL
DoSubComment
Save# Num#('1') Num#('0') { Feed Parameter Setting - Forces FeedRate at start of Sub }
SetFlag('2') { NeedRapidOrFeed - Forces Rapid OR Feed at start of Sub }
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SetSeqOff
' ' EOL
'\ WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
SetSeqC
END
END
RETURN

StdSub:
EachRep
SubCall ' ' Program# EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C GetRapid1
ELSE
IF FIFO?
GetFeedEntC
GetFeedC ZCP3C GetFeed1
ELSE
GetRapidC ZCP3C GetRapid1
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
Preset EOL
ShiftRC EOL
EndSub EOL
CloseSub
' G93' EOL { Axis Reset option, UnshftRC }
SetFlag('2') { NeedRapidOrFeed }
RETURN

OpenMP:
IF NOT WorkFixtureOffsets?
NewProg
SaveProgNum2
StartSub
END
RETURN

CloseMP:
IF NOT WorkFixtureOffsets?
Preset EOL
ShiftPC EOL
EndSub EOL
CloseSub
EachPart
SubCall ' ' Program2# EOL
NextPart
' G93' EOL { Axis Reset option, UnshftPC }
SetFlag('2') { NeedRapidOrFeed }
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
{ Not Supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

FormatArc:
DoAbsOrInc
IF Flag?('3') { First Arc Quadrant }
SetFlagF('3')
IF ArcCW?
CWArc EOL
ELSE
CCWArc EOL
END
ArcIJ GetFeed1 EOL
END
IF XMove? OR YMove? OR ZMove?
MoveXYZC GetFeed1 EOL
END
RETURN

ckCRC:
{ NOTE: This Post Processor does not support CutterRadiusCompensation }
RETURN

ckCRCNum:
{ NOTE: This Post Processor does not support CutterRadiusCompensation }
RETURN

FormatLine:
DoAbsOrInc GetFeedC MoveXYZC GetFeed1 EOL
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF SPXMove? OR SPYMove?
GetRapid MoveSXYC GetRapid1 EOL
END
SubCall ' ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF SPXMove? OR SPYMove?
MoveSXYC MoveSZ GetRapid1 EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
DoAbsOrInc GetRapidC MoveXYZC GetRapid1 EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
GetFeedRateC
DoAbsOrInc GetFeedC MoveXYZC GetFeed1 EOL
DecelMove2
END
GetDecelFeedC
DoAbsOrInc GetFeedC MoveXYZC GetFeed1 EOL
ELSE
GetFeedRateC
DoAbsOrInc GetFeedC MoveXYZC GetFeed1 EOL
END
END
ELSE
IF ArcFeat?
SetFlag('3') { First Arc Quadrant }
IF XMove? OR YMove? OR ZMove?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
GetArcFeedC
FormatArc EOL
DecelMove2
END
GetDecelFeedC
FormatArc EOL
ELSE
GetArcFeedC
FormatArc EOL
END
NEXTQuadrant
ELSE
FormatArc
' G05' EOL { Full Arc }
END
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
GetFeedEntC
GetFeedC ZCP2 GetFeed1
ELSE
GetRapidC ZCP2 GetRapid1
END
END
EOL
EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
SetFlag('2') { NeedRapidOrFeed }
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
GetFeed StrtPos GetFeed1 EOL
ELSE {Entry/Exit Connect}
GetRapid StrtPos GetRapid1 EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
GetFeedEnt
GetFeed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
StrtPosC GetFeed1 EOL
SetAbsOrInc
END
END
ZInPlusInc GetFeed1 EOL
ELSE
IF NOT FirstCycle?
GetRapid
IF SPXMove? OR SPYMove?
SetInc
StrtPosC GetRapid1 EOL
SetAbsOrInc
END
IF FeedEntry?
ZCP2PlusInc GetRapid1 EOL
END
END
IF FeedEntry?
GetFeedEnt
GetFeed ZInPlusInc GetFeed1 EOL
ELSE
IF FirstCycle?
GetRapid
END
GetRapidC ZInPlusInc GetRapid1 EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SubCall ' ' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
GetFeedEnt
GetFeed ZCP2 GetFeed1 EOL
ELSE
GetRapid ZCP2 GetRapid1 EOL
END
END
EndSub EOL
CloseSub
{Element shift, not pattern}
SetFlag('2') { NeedRapidOrFeed }
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedEntry?
GetFeedEnt
END
IF FeedConnect?
GetFeed StrtPos GetFeed1 EOL
ELSE {Entry/Exit Connect}
GetRapid StrtPos GetRapid1 EOL
END
END
IF FeedConnect?
GetFeedC ZInPlusInc GetFeed1 EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
GetRapidC ZCP2PlusIncC GetRapid1 EOL
END
GetFeed ZInPlusInc GetFeed1 EOL
ELSE
GetRapidC ZInPlusInc GetRapid1 EOL
END
END
SubCall ' ' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
EndSub EOL
CloseSub
SetFlag('2') { NeedRapidOrFeed }
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
SetSeqOff
DoOpComments
DoPostScript
Plane { No Output }
CheckPass
SetSeqC
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('2800')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetAbsOrInc
SetSeqOff
Save# Num#('1') Num#('0') { Current FeedEnt, FeedRate, DecelFeed or ArcFeed value in effect }
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { RapidOrFeed Set to Feed }
SetFlagF('3') { First Arc Quadrant }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
'@A=Virtual Gibbs' EOL
'@D=' Program# EOL
'@X=' XStockMax# ' IN.' EOL
'@Y=' YStockMax# ' IN.' EOL
'@Z=' SUB# ZStockMax# ZStockMin# ' IN.' EOL
IF UseComments?
IF ProgramNameComment?
'\ PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'\ ' ProgramComment$ EOL
END
{IF FormatNameComment?
'\ FORMAT: ' FormatName$ EOL
END}
IF TimeComment?
'\ ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'\ OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'\ PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'\ FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane { No Output }
ToolChng ' ' Tool# EOL
DoOpComments
DoPostScript
SetSeqC
' G70' EOL { Inches }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SpinOn ' ' SpeedRPM# EOL
IF Drilling? OR FeedEntry?
GetFeedEnt
END
CheckPass
GetRapid StrtPos GetRapid1 EOL
ZCP1 GetRapid1 EOL { OfstOn }
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SpinOn ' ' SpeedRPM# EOL
GetRapid StrtPos GetRapid1 EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
LoadFeat Num#('0') Num#('0') LAST ClearancePlane1#
IF ZMove?
GetRapidC LAST ZCP1C GetRapid1 EOL { OfstOff }
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
GetRapidC Home GetRapid1 EOL
END

{Start new Operation}

Plane { No Output }
ToolChng ' ' Tool# EOL
DoOpComments
DoPostScript
SetSeqC
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SpinOn ' ' SpeedRPM# EOL
IF Drilling? OR FeedEntry?
GetFeedEnt
END
CheckPass
GetRapid StrtPos GetRapid1 EOL
ZCP1 GetRapid1 EOL { OfstOn }
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SpinOn ' ' SpeedRPM# EOL
GetRapid StrtPos GetRapid1 EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
LoadFeat Num#('0') Num#('0') LAST ClearancePlane1#
IF ZMove?
GetRapidC LAST ZCP1C GetRapid1 EOL { OfstOff }
END

{Start new Operation}

GetStartOfSameTool
SpinOn ' ' SpeedRPM# EOL
IF Drilling? OR FeedEntry?
GetFeedEnt
END
GetRapid StrtPos GetRapid1 EOL
ZCP1 GetRapid1 EOL { OfstOn }
ELSE
IF NewToolOffset?
LoadFeat Num#('0') Num#('0') LAST ClearancePlane1#
IF ZMove?
GetRapidC LAST ZCP1C GetRapid1 EOL { OfstOff }
END

{Start new Operation}

GetStartOfSameTool
IF NOT Equal? SpeedRPM# LAST SpeedRPM#
SpinOn ' ' SpeedRPM# EOL
END
IF Drilling? OR FeedEntry?
GetFeedEnt
END
GetRapid StrtPos GetRapid1 EOL
ZCP1 GetRapid1 EOL { OfstOn }
ELSE

{Start new Operation}

GetStartOfSameTool
IF NOT Equal? SpeedRPM# LAST SpeedRPM#
SpinOn ' ' SpeedRPM# EOL
END
IF Drilling? OR FeedEntry?
GetFeedEnt
END
GetRapid StrtPos GetRapid1 EOL
END
END
END
END
END {common point for all operations}
IF Milling?
ZCP2C GetRapid1 EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF AutoCycle?
GetRapidC ZCP3C GetRapid1 EOL
ELSE
IF FIFO?
GetFeedEntC
GetFeedC ZCP3C GetFeed1 EOL
ELSE
GetRapidC ZCP3C GetRapid1 EOL
END
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
GetRapid StrtPos GetRapid1 EOL
END
IF RetractToCP1? {.81}
ZCP1C GetRapid1 EOL
ELSE
ZCP2C GetRapid1 EOL
END
GetCycle
Cycle EOL
StrtPos ZDepth GetRapid1 EOL
TrackZNO# FIRST SPZ#
ToolPath
SetDrillEndOpZ
' G80' EOL
SetFlag('2') { NeedRapidOrFeed }
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
GetRapidC ZCP3C GetRapid1 EOL
END
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
LoadFeat Num#('0') Num#('0') ClearancePlane1#
IF ZMove?
GetRapidC ZCP1C GetRapid1 EOL { OfstOff }
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
GetRapidC FirstHome GetRapid1 EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
SetSeqOff
IF NOT MinimizeSequencing?
Retag
END
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'\ FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'\ FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'\ FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END