{Change Comments ***********************************************************}

{4/10/92
Updated: Fanuc 0T Mate MS L031.82
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 0T/3T Miyano L008.82.1 Format.
KM}

{8/26/95, Updated Fanuc 0T Mate MS L031.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{
Format: Fanuc 0T MS Lxxx.85.1
10/3/95
For: Haas Automation
Removed tool ofset cancels.
Put tool offset in place of offset cancel at start if operation
Changed to R format arcs
TH}

{8/20/97
Initial: Fanuc 0T MS [HA] L383.85.1
Created: Fanuc 0T Lxxx.85
For: Speedway
Changed G28s to G30s in FirstOp, NewTool, and end of program,
changed to negative Xs,
moved SpinOn to Preset block when doing CSS in FirstOp and NewTool,
changed all SeqLab to SeqLabC except where required for tagging,
changed ProgID1 to ':' Program#, formatted Program# with format #6,
MPK
}

{8 Oct97
Original: Fanuc 0T MS [SE] L629.85
Created: Fanuc 0T MS [SE] L629.85.1
For: Speed Way Engineering
Changes made per: Corey Paugh
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Switched G2 to G3 and G3 to G2 in MachSpec
Changed literal 'G30U0.W0.' to 'G30U0.W0.T0' in FirstOperation, NewTool and End of Prog
Added Home to Preset line in FirstOperation and NewTool
Charles Winston}

{10/21/97,
Initial: Fanuc 0T MS [SE] L629.85.1
Created: Fanuc MF-T6 MS [DHT] L653.85
For: Delta Hi-Tech Inc

Changes to "Form":

1. Changed Thread Lead Format from 0.6 to 1.4.
2. Changed Thrading Cycle (G76) X Taper Lable from R to I.

Changes to "Prog":

1. Removed 'T0' from all G30 blocks.
2. Changed SeqLabC to SeqLab at the G30 restart blocks.
3. Removed Home from Preset (G50) blocks.
4. Hard coded 'R.02' in RoughContour cylce (G71).
5. Added FORMAT #8 for LastCutXRadius#.
6. Changed Q and R in Treading Cycle (G76) to be the LastCutXRadius#.
JHE}

{10/22/97
Initial: Fanuc MF-T6 MS [DHT] L653.85
Created: Fanuc MF-T6 MS [DHT] L653.85.1
For: Delta Hi-Tech Inc
Fixed Bad Character in Thread Lead format.
JM}

{05/21/98,
Initial: Fanuc MF-T6 MS [DHT] L653.85.1
Created: Fanuc MF-T6 MS [BLS] Lxxx.85
For: Bestline Liner Sys.

Changes To Prog:
1) Setup & Init - Changed NegSideLathe to PosSideLathe
2) DoRangeCode - Added this sub-routine to do gear changes.
3) DoRangeCodeSameTool - Added this sub-routine to check to see
if DoRangeCode needs to be output in SameTool situations.
4) Deleted all GearRange commands, and IF NewGear booleans.
5) CheckGear - Commented out this sub-routine.
6) NewTool - Added CWSpindle boolean to output SpinOff if there was
change in spindle direction between tools.
CDH}

{06/29/98,
Initial: Fanuc MF-T6 MS [BLS] L731.85
Created: Fanuc MF-T6 MS [BLS] L731.85.1
For: BestLine Liner Sys.

Changes to Prog:
1) Setup & Init - Added ReverseXZArcs.
CDH}

{02/09/99,
Initial: Fanuc MF-T6 MS [BLS] L731.85.1
Created: Fanuc MF-T6 MS [BLS] L731.85.2
For: BestLine Liner Sys.

Changes to Form:
1) Spindle & Coolant - Interchanged Spindle Forward and Reverse numbers.
2) Threading - Changed X Taper at Z Label to R instead of I.

Changes to Prog:
1) Common Point - Added G92 threading cycle. It will do the G92 when not
doing Canned Cycle.
2) ToolPath - Deleted G32 threading format.
CDH}

{02/19/99,
Initial: Fanuc MF-T6 MS [BLS] L731.85.2
Created: Fanuc MF-T6 MS [BLS] L731.85.3
For: BestLine Liner Sys.

Changes to Prog:
1) Moved positions of DoPostScript and DoEndOpPS.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '###.####;0.'
#6 = '###0'
#7 = '#'
#8 = '^###0' {Added - JHE}

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(CutDepth#,5)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(Program#,6)
FORMAT(RapidF#,7)


{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckGear: {Commented out - CDH}
{ IF NewGear?
SpinOn
END}
RETURN

DoRangeCode:
IF ConstantSurfaceFeed?
IF GreaterThan? CalcRPM1# NUM#('226')
SeqLabC 'G99M42' EOL {High Range}
SeqLabC Preset 'S660' EOL
Save# NUM#('1') NUM#('2')
ELSE
SeqLabC 'G99M41' EOL
SeqLabC Preset 'S225' EOL
Save# NUM#('1') NUM#('1')
END
ELSE
IF GreaterThan? SpeedRPM# NUM#('226')
SeqLabC 'G99M42' EOL {High Range}
Save# NUM#('1') NUM#('2')
ELSE
SeqLabC 'G99M41' EOL
Save# NUM#('1') NUM#('1')
END
END
RETURN

DoRangeCodeSameTool:
IF ConstantSurfaceFeed?
IF GreaterThan? CalcRPM1# NUM#('226')
IF NOT Equal? Recall# NUM#('1') NUM#('2')
DoRangeCode
END
ELSE
IF NOT Equal? Recall# NUM#('1') NUM#('1')
DoRangeCode
END
END
ELSE
IF GreaterThan? SpeedRPM# NUM#('226')
IF NOT Equal? Recall# NUM#('1') NUM#('2')
DoRangeCode
END
ELSE
IF NOT Equal? Recall# NUM#('1') NUM#('1')
DoRangeCode
END
END
END
RETURN

CheckOffset:
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
DoRangeCodeSameTool Speed
END
ELSE
DoRangeCodeSameTool
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
DoRangeCodeSameTool
SeqLabC CSSOff 'G97' Speed CheckGear
END
END
IF LAST ProgStop?
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
ReverseXZArcs
SetMaxRPM('660')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
':' Program#
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoPostScript
DoOpComments
Plane
SeqLab Rapid EOL
SeqLab 'G30U0.W0.' EOL {Removed 'C' and T0 - JHE}
DoRangeCode
SeqLabC OpToolID LatheOffset EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1 SpinOn
ELSE
Speed SpinOn
END
EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC 'G30U0.W0.' EOL {Removed T0 - JHE}
IF CWSpindle? AND LAST NOT CWSpindle?
SeqLabC SpinOff EOL
ELSE
IF NOT CWSpindle? and LAST CWSpindle?
SeqLabC SpinOff EOL
END
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
DoEndOpPS

{Start new Operation}

DoPostScript
DoOpComments
SeqLab Rapid EOL
SeqLab 'G30U0.W0.' EOL {Removed 'C' and T0 - JHE}
DoRangeCode
SeqLabC OpToolID LatheOffset EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1 SpinOn
ELSE
Speed SpinOn
END
EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoEndOpPS
DoPostScript
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle CutDepth 'R.02' {'R' CutDepth#} EOL {Hard coded R.02 - JHE}
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {2 finish passes}
ELSE
'01'
END
IF Chamfer?
'07' {.7 thread lead distance for chamfer}
ELSE
'00'
END
IF SingleEdgeCut?
'60' {using 60 for standard tool angle, need ToolAnge# command}
ELSE
'00'
END
FORMAT(LastCutXRadius#,8) {Added - JHE}
'Q' LastCutXRadius# EOL {Added - JHE}
{ IF ConstantVolumeCut? }
{ '20' } {.0020 minimum cut depth} {Removed - JHE}
{ ELSE }
{ CutDepth# } {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
{ END }
{ 'R0'} {using zero for no finish stock allowance, need XStckLeft# command}
{ EOL }
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth Dwell Peck Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
IF Threading?
SeqLabC 'G92X' FirstMoveEPX# FinZ
IF Taper?
XTapAtZ
END
'F' FeedIPR# EOL
SimpleRough
ELSE
StockOn
SetPass1
ToolPath
END
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC 'G30U0.W0.' SpinOff EOL {Removed T0 - JHE}
SeqLabC UnTool '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END