{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/21/90, Updated: Fanuc 6T MS [+] L016.53 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}
{12/21/90, Modified from L016.71
Changed threading to longhand style (G32), no canned cycle on machine, JC}
{6/4/91, Updated Fanuc TC-F TS (PM) L214.71 to .81 format, JR}
{6/17/91, Changed Thread Lead from E0.6 to F1.4 Format, JC}

{08/06/91
Updated: Fanuc TC-F TS (PM) L214.81.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{01/07/91
For: Precision Machine (Phoenix)
Modified: Fanuc TC-F TS (PM) L214.82
Changed Tailstock positioning ('X' and 'Z' moves to separate lines
To avoid tools that overhang the chuck and part putting the 'Z' move first)
Changed 'G50' output adding 'home'.
Moved 'G96' block in front of first 'G1' block.
Added PalletIn/PalletOut commands to advancing -'M10'
and retracting -'M11' tailstock.
Added 'M68' and 'M69' to open and close chuck.
Added 'G94' (IPM Mode) and 'G95' (IPR Mode) to the Toolpath in the IF Drilling? AND OptCyc?
Added AFODApproachSP, AFIDApproachSP, AFFaceApproachSP subs for the AutoFinish w/o Canned Cycles.
Added Approach section to the IF AutoFinish? - IF Turning? - IF NOT Canned Cycle? This is only needed in long hand SetPass1.
*The added section to the AutoFinish is a BUG in all Lathe processors and needs to be corrected.
Kim Michelman}

{02/13/92
Modified: Fanuc TC-F TS (PM) L214.82.1
For: Precision Machine
Changed the HomeX# & HomeZ# to NewHomeX# & NewHomeZ# in NewTool Section.
Changed HomeX# & HomeZ# to FirstHomeX# & FirstHomeZ# at the end of the program.
Kim Michelman}

{03/18/92
Modified: Fanuc TC-F TS (PM) L214.82.2
For: Precision Machine
Added FORMAT(NewHomeX#,7) and FORMAT(NewHomeZ#,7), not added when last modified.
And FORMAT(FirstHomeX#,7), FORMAT(FirstHomeZ#,7).
Kim Michelman}

{1/9/97, updated to .85 format, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.0###'
#3 = '########;0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(HomeX#,7)
FORMAT(HomeZ#,7)
FORMAT(NewHomeX#,7)
FORMAT(NewHomeZ#,7)
FORMAT(FirstHomeX#,7)
FORMAT(FirstHomeZ#,7)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
PalletInF
PalletOutF
OptCyc1F
RETURN

PSStuff:
IF PalletIn? {For advancing Tailstock}
SeqLabC 'M10' EOL
END
IF PalletOut? {For retracting Tailstock}
SeqLabC 'M11' EOL
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

TurnOnCSS:
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
TurnOnCSS
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
TurnOnCSS
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
TurnOnCSS
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

AppMove:
OpToolID LatheOffset CoolOn
RETURN

Approach: { FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqLabC Rapid ThisOpEntryZCP AppMove EOL
SeqLabC ThisOpEntryXCP EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC Rapid ThisOpEntryZCP AppMove EOL
SeqLabC XOpCD EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC Rapid ThisOpEntryZCP AppMove EOL
SeqLabC StockOnNoCan XSP StockOff EOL
FaceApproachSP
END
END
RETURN

AFODApproachSP: {Without the 'TurnOnCSS' sub to avoid double execution of 'G96' line}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

AFIDApproachSP: {Without the 'TurnOnCSS' sub to avoid double execution of 'G96' line}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

AFFaceApproachSP: {Without the 'TurnOnCSS' sub to avoid double execution of 'G96' line}
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqLabC SpeedC EOL
ELSE
SeqLabC Preset Home MaxRPM EOL
SeqLabC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed EOL
ELSE
SeqLabC SpeedC EOL
END
END
IF LAST ProgStop?
SeqLabC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF NEXT ThreadFeat?
SeqLabC Feed MoveXC MoveZC 'F.05' EOL { If next feature is Thread, output G01 }
ELSE
SeqLabC RapidC MoveXC MoveZC FeedRateC EOL
END
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC XTapAtZ ThrdLead EOL
END
END
END
END
END
IF Drilling? AND OptCyc1?
IF FirstFeat?
SeqC 'G94' EOL {IPM Mode}
SeqC 'M68' EOL {Open Chuck}
SeqC 'G4P' EOL {Dwell}
END
IF LastFeat?
SeqC 'M69' EOL {Close Chuck}
SeqC 'G4P' EOL {Dwell}
SeqC 'G95' EOL {IPR Mode}
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' PalletIn() -' EOL
' PalletIn will need an argument (any number) between the ()' EOL
' when Palletin is used, it will output the M code for advancing tailstock ' EOL
' PalletOut -' EOL
' Will retract the tailstock with the M code for retracting tailstock ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF Drilling? AND OptCyc1?
SeqLab OpToolID '00' SpinOff EOL { Programmer is doing BarFeed Operation }
ELSE
SeqLab Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID '00' SpinOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC Rapid 'X' NewHomeX# LOfstOff '00' EOL
SeqLabC 'Z' NewHomeZ# EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Plane
IF Drilling? AND OptCyc1?
SeqLabC OpToolID '00' SpinOff EOL { Programmer is doing BarFeed Operation }
ELSE
SeqLabC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID '00' SpinOn EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
SeqLabC Feed XatFinZ EOL
SeqLabC 'G32' FinZ ThrdLead EOL
SeqLabC RapidC XCSP EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning? {OR RoughSimple?}
SetPass1
IF ApproachOD?
SeqLabC RapidC XOpECDC EOL
AFODApproachSP
ELSE
IF ApproachID?
SeqLabC RapidC XOpECDC EOL
AFIDApproachSP
ELSE {ApproachFace}
SeqLabC RapidC ZOpECPC EOL
AFFaceApproachSP
END
END
ELSE
SetPass2
END
SeqLab RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC Rapid 'X' FirstHomeX# EOL
SeqLabC 'Z' FirstHomeZ# OpToolID '00' SpinOff EOL
SeqLabC UnTool '00' EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END