{Change Comments ***********************************************************}

{5/12/92
Copied & modified: Fanuc 6M M001.81
For: Armco.
Machine: Giddings & Lewis Horizontal Machining Center
Control: G & L NumeriPath 8000B
Changes made per conversation with Bill Barber @ Armco, and manual.
Changed all occurances of Z address to W address in Form and Prog.
FORM Changes:
Use Absolute Arc Centers = T
Allow R-Format Arcs = F
Keep Subs in Front of Program = T
Z EndPoint Label = W
Rapid Z EndPoint Label = W
Sub Call Label =
Sub Repeat Label =
Program ID Label =
Optional Program ID Label =
Tool Length Offset Label = D
Call sub =
Return from Sub =
Tool Length Offset Enable =
Tool Length Offset Cancel =
First Work Fixture Offset = E1
Last Work Fixture Offset = E99
Drill from CP1 =
Drill from CP2 =
PROG Changes:
Changed FORMAT 6 for Dwell# from ####^##0 to ###.#;0.
Added FORMAT 7 ##.#####;0. for FeedTapIPR# used in Canned Tapping Cycle.
Added Address 'K' for this.
Added ClearancePlane1# and ClearancePlane2# to FORMAT 4 used in Canned Drilling Cycles
and based on RetractToCP1 Boolean, and replaces FromCP Command.
Added ArcZRads# to FORMAT 4 used for 3-Axis ArcFeat.
Added Repeats# to FORMAT 5.
Added TYPE II Conversational Codes:
PGM, Program Name
MSG, Operator Message
CLS, Call Subroutine
Changed all SeqC EndSub to EOR.
Modified FormatArc Sub to handle all Planes.
Unconditional h, v, I and J; d and K for Helical ArcFeat.
Added Flag('1') to bypass Helical ArcFeat for ZonlyRep Sub which uses SkipZ Command.
Changed Address G to Address E at WFOStuff Sub.
Added literal 'D0' to IncValue OfstOff.
Changed Address P to Address F for Canned Drilling Cycle Dwells.
Dwell for Canned Cycle is output as 'G4' Dwell.
Deleted FeedEnt from Canned Drilling Cycles.
I didn't see an example of FeedEnts being used in the manual, I assume it is defaulted.
DWB}

{7/1/92
Modified: G & L Numeripath 8000 M499.81
For: Armco.
Changes made per conversation with Bill Barber @ Armco.
Bill requested that the Tool Length Offset be output prior to any table motion. The D Address
controls both the Length AND Diameter Offset values.
Deleted CRCOffsetC 3 places at StdLine sub.
Deleted ResetCRCNum at ToolPath sub.
Added ToolOfst to block prior to StrtPos at FirstOperation, NewTool and 2 places at SameTool.
Changed OfstOn to ZCP1 at FirstOperation, NewTool and 2 places at SameTool.
DWB}

{11/15/94
Modified: G & L Numeripath 8000 M499.81.1
For: Armco
Changes made per fax from Bill Barber @ Armco
All lines (Including comments) now get sequence numbers
Moved the (PGM, #######) line to be the first line after the % sign
Changed tool change from M06 to M00 (For manual tool changes)
Moved the T command to it is on the same line as the D command
Replaced the AbsOrInc command with the suggested changes in the ComPost manual
TH}


{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0.'
#7 = '##.#####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ArcZRads#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Repeats#,5)
FORMAT(Dwell#,6) {.72}
FORMAT(FeedTapIPR#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqC '(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqC '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqC '(PGM,' Program# ')' EOL { SubID }
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqC ' ' EOL
SeqC '(MSG, WARNING W CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
SeqC ' ' EOL
END
END
RETURN

StdSub:
SeqC '(CLS,' Program# ';' Repeats# ')' EOL { CallSub }
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
EOR EOL { EndSub }
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC '(CLS,' Program# ')' EOL { CallSub }
IncWFO
NextWFO
ELSE
SeqC '(CLS,' Program# ';' Parts# ')' EOL { CallSub }
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
EOR EOL { EndSub }
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
EOR EOL { EndSub }
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove? AND NOT Flag?('1') { For SkipZ MoveZ ArcFeats in ZonlyRep Sub }
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveXY ArcIJ
END
ELSE
IF XZPlane?
IF YMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveY MoveZ ArcIJ
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC '(CLS,' Program# ')' EOL { CallSub }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'E' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqC 'E' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
EOR EOL { EndSub }
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
{ SeqC AbsOrInc Connect StrtPos EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(CLS,' Program# ')' EOL { CallSub }
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
EOR EOL { EndSub }
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC '(CLS,' Program# ')' EOL { CallSub }
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
EOR EOL { EndSub }
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { For SkipZ MoveZ ArcFeats in ZonlyRep Sub }
IF PSComment? AND UseComments?
SeqC 'PostScript:' EOL
SeqC ' Literals: put between single or double quotes.' EOL
SeqC ' Separate commands and literals with at least one space.' EOL
SeqC ' A CR ( RETURN key ) will start a new line.' EOL
SeqC ' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
SeqC ' EndOP -' EOL
SeqC ' all literals and commands before an ENDOP command' EOL
SeqC ' will appear at the beginning of the operation. All ' EOL
SeqC ' literals and commands after an ENDOP command will appear' EOL
SeqC ' at the end of the operation. ' EOL
SeqC ' NewWFO(56), NWFO(56) -' EOL
SeqC ' The Work Fixture Offset # you specify will be used for all following operations.' EOL
SeqC ' Do not use with the ncPost multiple part option.' EOL
SeqC ' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
SeqC ' generates a + A move of the value you specify' EOL
SeqC ' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
SeqC ' generates a - A move of the value you specify' EOL
SeqC ' 5thAxisCW(30), 5ACW(30) -' EOL
SeqC ' generates a + B move of the value you specify' EOL
SeqC ' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
SeqC ' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
SeqC '(PGM,' Program# ')' EOL { ProgID }
IF UseComments?
IF ProgramNameComment?
SeqC '(MSG, PROGRAM: ' ProgramName$ ' )'
END
IF ProgramComment?
SeqC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqC '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqC '(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
{ SeqC '(PGM,' Program# ')' EOL { ProgID }}
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Plane 'G80' CRCOff EOL
{ SeqC OpToolID EOL}
SeqC ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqC ToolOfst OpToolID EOL
CheckPass
{ SeqC AbsOrInc Rapid StrtPos EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC IncValue OfstOff 'D0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
{ SeqC AbsOrInc Rapid Home SpinOff EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq Plane 'G80' CRCOffC EOL
{ SeqC OpToolID EOL}
SeqC ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC ToolOfst OpToolID EOL
{ SeqC AbsOrInc Rapid StrtPos EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue OfstOff 'D0' EOL
SeqC SpinOff EOL
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC ToolOfst OpToolID EOL
{ SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid StrtPos SpeedC SpinOn EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue OfstOff 'D0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC ToolOfst OpToolID EOL
{ SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid StrtPos SpeedC EOL
SeqC ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
{ SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
SetFlag('1') { For SkipZ MoveZ ArcFeats in ZonlyRep Sub }
ZonlyRep
SetFlagF('1')
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
{ SeqC AbsOrInc Rapid StrtPos EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle StrtPos RLevel ZDepth
IF RetractToCP1? {.81}
'P' ClearancePlane1# { FromCP }
ELSE
'P' ClearancePlane2# { FromCP }
END
Peck
IF Dwell?
'G4' Dwell
END
IF Tap?
'K' FeedTapIPR#('1')
END
EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC IncValue OfstOff 'D0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
{ SeqC AbsOrInc Rapid FirstHome SpinOff EOL}
SeqC PlaneC
IF AbsoluteMoves?
AbsValue
ELSE
IncValue
END
Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
SeqC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END