{Change Comments ***********************************************************}

{12/2/88
General change to all Bandits.
Deleted CRCOnC & CRCOffsetC commands from 6 places in ToolPath.
Added Comments.
Changed FormatArc to unconditionaly move X & Y & I & J
JR}

{6/20/89
Modified: Bandit IIIA Shizouka M011.55.
Changed AbsValue in FirstOperation to AbsOrInc.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/30/90, Updated: Bandit IIIA Shizouka M011.57 to .73 format, JR}

{4/26/91,
Modified: Bandit IIIA Shizouka M011.73
For: Gibbs & Associates
Updated to new 4.0 Version per Fanuc 6M M001.80
DWB}

{03/10/98,
Initial: Bandit IIIA Shizouka M011.79
Created: Bandit IIIA Shizouka Mxxx.79
For: Dew Manufacturing

Added literal 'N001&G90' in FirstOp.
Added literal 'S70' in FirstOp after SpinOn.
Added CoolOff in NewTool before OfstOff.
Created DoToolChng and DoToolCode sub-routines:
The DoToolChng sub-routine first outputs a literal "M20' and then a
'/T.2'. It then saves the absolute difference between the Last ops
tool number and the current tool number. Then it initializes Variable 3
to 1. If the tool number is incrementing then flag 1 is set so that it will
output a literal 'M22'. If the tool number is decrementing then it will output
a 'M21'. It then calls the DoToolCode sub-routine and then outputs literal '/T.2''s
and a 'M23'.
The DoToolCode sub-routine determines how many times to output either M22 or M21 based
on the difference between the previous tool num and the new tool num. A counter keeps track of
how many times it outputs.
Added literal M codes and '/T.2's at end of program.
CDH}

{3/16/98,
Updated to .89 version.
CDH}

{03/26/98,
Initial: Bandit IIIA Shizouka [DM] MV31.89
Created: Bandit IIIA Shiz [DM] MV31.89.1
For: Dew Manufacturing

Changes to Prog:
1) Added blank line to beginning of Prog.
2) Added literal '/T2.0' to after 'S70' line in FirstOp.
3) Added literal 'S50' and a literal '/T2.0' in NewTool.
CDH}

{7/31/98,
Initial : Bandit IIIA Shiz [DM] MV31.89.1
Created: Bandit IIIA Shiz [DM] MV31.89.2
Customer: Dew Manufacturing, Jim Whitehead 760/941-6466

Changes to "Form":

1. Under Subs, removed all Labels.

Changes to "Prog":

1. Removed SpeedB (output M24 for RPM up and M25 for RPM down).
2. Added CoolOn (M8) after tool change.
3. Removed all SeqC.
4. Moved ZCP3 to be output after G80.
5. Added FORMAT to TrackZNO#.
6. The following changes to sub routines:
- Changed CallLab & CallLabB to '/N', EndSub to '/N0', RepCycs to Repeats#,
RepLab to '/G', and Parts to Parts#.
- Removed MarkSub and all SubCall. Added FORMAT to Repeats# and CallMasterNum#.
- Added NewProg in 2 places and Program# after '/N'.
JHE}

{8/3/98,
Initial : Bandit IIIA Shiz [DM] MV31.89.2
Created: Bandit IIIA Shiz [DM] MV31.89.3
Customer: Dew Manufacturing, Jim Whitehead 760/941-6466

Changes to "Form":

1. Under Drill Cycles, removed / before Z in Bore and Tap cycles.

Changes to "Prog":

1. Added Feed to Preset blocks in 3 places.
2. Switched output order between Program# and Repeats#.
3. Added 'N12' block after MP sub call.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '##.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4) {Added - JHE}
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Repeats#,5) {Added - JHE}
FORMAT(CallMasterNum#,5) {Added - JHE}
FORMAT(Dwell#,6)

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoToolCode:
IF LTEqual? Recall# NUM#('3') Recall# NUM#('2')
IF Flag?('1')
'M22' EOL
ELSE
'M21' EOL
END
END
Save# NUM#('3') ADD# Recall# NUM#('3') NUM#('1')
RETURN

DoToolChng:
'M20' EOL
'/T.2' EOL
Save# NUM#('2') ABS# Sub# Tool# LAST Tool#
Save# NUM#('3') NUM#('1')
IF GreaterThan? Tool# LAST Tool#
SetFlag('1')
ELSE
SetFlagF('1')
END
DoToolCode DoToolCode DoToolCode DoToolCode DoToolCode
DoToolCode DoToolCode DoToolCode DoToolCode DoToolCode
'/T.2' EOL
'M23' EOL
'/T.2' EOL
RETURN

EntryMove:
IF FeedEntry?
FeedEnt EOL
Feed ZIn EOL
ELSE
RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL {Added 3 space lines - JHE}
' ' EOL
' ' EOL
{MarkSub EOL} {Removed - JHE}
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
'/N' Program# EOL {Switched output order - JHE 8/3}
'/G' Repeats# EOL
'N12' EOL {Added this line - JHE 8/3}
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
RapidC ZCP3C EOL
END
RETURN

FinishSubG92: {part 2}
Feed ShiftRC Preset EOL
'/N0' EOL
CloseSub
Feed UnshftRC Preset EOL
RETURN

OpenMP:
NewProg {Added - JHE}
IF EquallySpacedOffsets?
'/N' Program# EOL {Switched output order - JHE 8/3}
'/G' Parts# EOL
'N12' EOL {Added this line - JHE 8/3}
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
Feed ShiftPC Preset EOL {Added Feed - JHE 8/3}
'/N0' EOL
CloseSub
Feed UnshftPC Preset EOL {Added Feed - JHE 8/3}
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
CRCOnC EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
FeedRateC EOL
DoAbsOrInc EOL
FeedC MoveXYZC EOL
DecelMove2
END
DecelFeed EOL
DoAbsOrInc EOL
FeedC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
FeedRateC EOL
DoAbsOrInc EOL
FeedC MoveXYZC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
DoDrillAbsOrInc EOL
MoveSXYC EOL
IF AutoCycle?
'/N' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
CRCOffC EOL
END
IF XMove? OR YMove? OR ZMove?
DoAbsOrInc EOL
RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
CRCOffC EOL
FeedRateC EOL
DoAbsOrInc EOL
FeedC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
FeedRateC EOL
DoAbsOrInc EOL
FeedC MoveXYZC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
ArcFeedC EOL
FormatArc EOL
DecelMove2
END
DecelFeed EOL
FormatArc EOL
ELSE
ArcFeedC EOL
FormatArc EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
'/N0' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
CRCOnC EOL
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
AbsOrInc EOL
Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
Feed IncValue StrtPosC EOL
AbsOrInc
ELSE
Feed
END
ELSE
Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
Rapid IncValue StrtPosC EOL
IF FeedEntry?
AbsOrInc ZCP2PlusInc EOL
Feed ZInPlusInc FeedEnt EOL
ELSE
AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
Rapid ZCP2PlusInc EOL
Feed ZInPlusInc FeedEnt EOL
ELSE
Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
Feed ZInPlusInc FeedEnt EOL
ELSE
Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'/N' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
Rapid ZCP2 EOL {.69}
END {.69}
'/N0' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
FeedEnt EOL
FeedC ZInPlusInc EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE
RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
'/N' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'/N0' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *****************************}
IF FirstOperation?
' ' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
'N001&G90' EOL
SpinOn EOL
'S70' EOL
CoolOn EOL {Added this line - JHE}
'/T2.0' EOL
Feed Home Preset EOL {Added Feed - JHE 8/3}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Rapid StrtPos EOL
OfstOnB3 EOL
Plane Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP Rapid StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
CoolOff EOL
OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SpinOff EOL
AbsOrInc EOL
Rapid Home EOL
IF LAST ProgStop?
'M00' EOL
ELSE
ProgStop EOL
END

{Start new Operation, NewTool}

DoOpComments
DoPostScript
DoToolChng Plane SpinOn EOL
'S50' EOL
CoolOn EOL {Added this line - JHE}
'/T2.0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
AbsOrInc EOL
Feed Home Preset EOL
CheckPass
{SpeedB} Rapid StrtPos EOL {Removed SpeedB - JHE}
OfstOnB3 EOL
Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
OfstOff EOL
SpinOff EOL
'M00' EOL

{Start new Operation, SameTool}

GetStartOfSameTool
Plane SpinOn EOL
'S50' EOL {Added this line - JHE}
CoolOn EOL {Added this line - JHE}
'/T2.0' EOL {Added this line - JHE}
{SpeedB} Rapid StrtPos EOL {Removed SpeedB - JHE}
OfstOnB3 EOL
Feed ZCP1 Preset EOL
ELSE
IF NewToolOffset?
OfstOff EOL

{Start new Operation, SameTool}

GetStartOfSameTool
PlaneC EOL
{SpeedB} Rapid StrtPos EOL {Removed SpeedB - JHE}
OfstOnB3 EOL
Feed ZCP1 Preset EOL
ELSE
{Start new Operation, SameTool}

GetStartOfSameTool
PlaneC EOL
{SpeedB} Rapid StrtPos EOL {Removed SpeedB - JHE}
END
END
END
END
END {common point for all operations}
IF Milling?
RapidC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
RapidC ZCP3C EOL
CRCOffC EOL
ELSE
IF Drilling?
Rapid ZCP2 EOL
IF Repeats?
NewProg {Added - JHE}
StdSub
AbsOrInc EOL
Rapid StrtPos EOL
END
GetCycle
FromCP ZDepth Dwell Peck Retract Cycle EOL
FeedEnt EOL
StrtPos EOL
IF CallMasterOp?
'/N' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
'/N' Program# EOL
StartSub
ToolPath
'/N0' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
Rapid 'G80' EOL {Moved ZCP3 to next line - JHE}
ZCP3 EOL {Added this line - JHE}
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
CoolOff EOL
DoEndOpPS
AbsOrInc EOL
Rapid FirstHome EOL
SpinOff EOL
'/T.2' EOL
'M20' EOL
'/T.2' EOL
'M27' EOL
'/T.2' EOL
'M23' EOL
'/T.2' EOL
IF ProgStop?
'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum