{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=T
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{5/15/98,
Updated: Fanuc 6M (FW) B001.15
Created: Fanuc 6M [FW] B001.16
For: Gibbs & Associates
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Corrected support for Linear ChangeCS.
Linear ChangeCS covers Multiple CSGroups in One Plane.
Post does not output CSWFOComments, G52Comments or G52Stuff for this situation.
IF AAxisAvail? OR BAxisAvail? does not automatically support this.
Deleted IF AAxisAvail? OR BAxisAvail? at G52Stuff, DoCSComment and DoCSWFOComment.
Post retracts Tool at SameTool for this situation.
Retraction is only necessary for AChange OR BChange situations.
Changed ChangeCS? to AChange? OR BChange at SameToolOp1.
Changed ChangeCS? to AChange? OR BChange at SameToolOp3.
Simplified ClearCSOffset occurance.
ClearCSOffset occurs at 5 different places, including at the output of CSComments.
Discovered that CheckPass is a good place for all situations.
Deleted ClearCSOffset at CSComments.
Caused simplification of Procedure.
Deleted ClearCSOffset at CSG52, DoCSWFOComment, OpenMP and SubCSMP Procedures.
Added ClearCSOffset at CheckPass.
Additional modifications.
Moved IF FirstOperation? OR NewTool? OR ChangeCS? Boolean from CSG52 to G52Stuff.
Moved DoSubComment Procedure to before DoOpComments Procedure.
To keep CSStuff together.
Moved call to CSComments Procedure to inside IF UseComments? Boolean at DoOpComments.
To suppress when Comments are turned off.
Added AbsValueC, IncValueC and AbsOrIncC Procedures.
Simplifies readability of Prog.
Reduces redundancy of output.
Allows us to return to earlier versions
Improves upon earlier problem with incremental output of ShiftPC command at CloseMP while
allowing us to return to .85 OfstOff blocks.
AbsValueC called from AbsOrIncC.
IncValueC called from AbsOrIncC, DoAbsOrInc and DoDrillAbsOrInc.
IncValueC called for OfstOff Blocks at NewToolOp1, two places at SameToolOp1 and DoAbsOrInc.
AbsOrIncC called for ShiftPC Block at CloseMP.
AbsOrIncC called from DoAbsOrInc, DoDrillAbsOrInc and RestoreAbsOrInc.
AbsOrIncC called for Home Block at NewToolOp2.
AbsOrIncC called for FirstHome Block at End2.
Added CRCOffC at AutoCycCutSub2.
Corrects unique situation in ZonlyRepAutoCycle where one Operation is CRCLeft and LastFeat
is an ArcFeat followed by another Operation that is CRCRight.
CRCOffC did not get output at end of CRCLeft Operation and CRCOnC did not get output at start
of CRCRight Operation.
Oddly, CRCOnC only outputs if CRCOffC has been output, not if CRCSide changes.
Moved call to InitOp Procedure to top level at end of Prog.
Personal Preference.
6/18/98
Changed to Lowercase Procedure Names.
Added comments to all SetFlag, SetFlagF and IF Flag statements.
Added Flag(6) to switch from B-Style to C-Style at progStart.
TRUE = B-Style Output, FALSE = C-Style Output.
Added Flag(7) to switch from local coordinates to uncompensated coordinates at progStart.
TRUE = Local WFO Coordinates, FALSE = D-Style Output.
Added pertinent comments at progStart.
Added IF Equal? NumOfCS# Num#('1') at progStart.
This is a standard 3 Axis - Output M-Style.
Changed Seq to SeqC at autoCycCutSub1.
Added CRCOffC to AutoCycle ZCP3C at end of IF Milling?
Moved CRCOffC to before FeedC and RapidC for ZCP3C at end of IF Milling?
To stay consistant with CRCOnC/CRCOffC Rapid/Feed/CWArc/CCWArc throughout Prog.
Changed literal 'G80' to DrillOff at end of IF Drilling.
Changed literal 'G80' to DrillOff at firstOp1 and newToolOp3.
To allow for change in FORM without having to recompile.
Changed SpeedC to Speed at for LAST ProgStop condition at sameToolOp3.
6/30/98
Deleted Gibbs System XYRepeat support.
Virtual only support ZShiftOnly Repeats.
Rewrote OpGuts Procedure.
Limited Milling Repeats to ZShiftOnly at IF Milling.
Deleted Drilling Repeats at IF Drilling.
Rewrote PostScript instructions at progStart.
7/22/98
Reverted back to Gibbs System XYRepeat support.
IF setup correctly, Virtual will support XShift and/or YShift Repeats for both Contour and
Patterns.
Rules for correct setup (as best as I understand at the moment).
Geometry CSGroup must be oriented to a plane that intersects CS#1 in a perpendicular direction.
Example, XZPlane and YZPlane, and any oriented rotation of either Plane around the XYPlane.
Any change in the ZPitch of the Origin will cause ZShiftOnly Repeat Operation.
Set Desired ZStep so that Operation will result in multiple passes.
NOTE: If correctly setup, ZStep would be misleading.
Step will be in line with depth axis of CSGroup.
Restored related code to OpGuts Procedure.
ZShiftOnly Contour Operations remain Full SepSub.
Any customer requesting G92 Style will require copying code from archives.
Deleted Deceleration from ToolPath LineFeat and ArcFeat.
There are plans to support this in the future through the use of Construction Tools in the
Virtual Process.
9/1/98
Added forced FeedRate for RI-RO Milling Operations.
When a RI-RO Operation follows either a FI-RO or RI-RO Operation, and both contain the same
FeedRate values, the second Operation does not get a FeedRate output due to the conditional
FeedRateC command. A problem arises for MultipleParts - OneToolAllParts - ExitClearancePlane
Programs when both Operations use different Tools, and a third Operation uses the SameTool as the
second Operation, but has a different FeedRate value. The result is that when the Program moves
to machine the additional parts with the second Operation at the FeedRate value of the third
Operation. It is safer to just force the FeedRate in the second Operation.
Added FORMAT#7, '#' at Prog Numeric Format Definitions.
Added RapidF# to Format#7 at Prog Numeric Format Definitions.
RapidF# equals zero and this FORMAT allows for nothing to be output.
Added RapidF# at entryMove Procedure.
Added IF FirstOperation? OR NewTool? condition two places at entryMove Procedure.
To force FeedEnt and RapidF#.
SameTool condition outputs conditional FeedEntC.
Added IF NOT AbsoluteMoves? Boolean and SetSRXYtoEP command to zonlyRep.
This fixes problem with Incremental output of move back to StrtPos for additional passes.
Deleted UseSeparateSubCalls at ProgStart Procedure.
Deleted SetMaxSeparateSubCalls('50') at ProgStart Procedure.
Moved IF ToolChangeAtHome? Boolean and SetHome command from InitOp to FirstOp1.
Personal preference for moving Procedure call to top level at end of Prog on 5/15/98 was to
reduce it to one occurance, consistant with LongHand version where it works. However, it was
reported that the IF ToolChangeAtHome? Boolean and SetHome command occuring outside of
EachOp/NextOp loop was causing Windows version to crash. Duplicating problem required having a
part file open and a post processor loaded, and then opening a new part with one of the beta
masters. I was not able to duplicate this on the Macintosh.
Changed name of doCSG52Ops Procedure to doWFOOps.
Changed call of same two places at openMP.
Name was misleading because Procedure is also called for standard MultipleParts output, not just
G52Style and contents are identicle to M001.
9/24/98
Added Post Header Comment at top.
Added missing END command at entryMove.
Changed IncValue to incValueC at autoCycCutSub1.
Changed AbsOrInc to absOrIncC at autoCycCutSub2.
Changed AbsOrInc to absOrIncC at g92Sub.
Added support of Incremental Output for SepSubs.
When user selects Incremental Output, SepSubZMoves are incorrect.
Added doSepSubZMoves Procedure.
Contains code for ZPosMoves from zonlyRepAutoCycle and zonlyRep Procedures.
Outputs Incremental ZExitMove for Exit/Entry.
AutoCycles Retract to ZCP2.
Non-AutoCycles Retract to ZCP3.
Added setSepSubZ Procedure.
Updates Status Register to final ZInPos for FeedEntry.
Modified zonlyRepAutoCycle Procedure.
Modified zonlyRep Procedure.
Expanded Advanced Milling Flags for easier developing.
Changed Flag(7) to be dedicated to D-Style Output only.
Added Flag(8) for Toggle between D-Style and G52-Style Output.
5 possible combinations:
BStyle/G52Style Flag(6) FlagF(7) FlagF(8)
BStyle/DStyle Flag(6) FlagF(7) Flag(8)
CStyle/G52Style FlagF(6) FlagF(7) FlagF(8)
CStyle/DStyle FlagF(6) FlagF(7) Flag(8)
DStyle FlagF(6) Flag(7) Flag(8)
10/1/98
Versions: Virtual 4.29.75(Mac)/ComPost2 1.7b10 (Mac)
Versions: Virtual 4.29.75(Win)/ComPost2 1.7b10 (Win)
Corrected old problem with Incorrect Status Register XYPos at end of Pattern AutoCycle Operation.
Problem is caused because Status Register is left in SetPass1 [ Contouring ] Mode and does not compensate
for SetPass2 [ PointFeat Position ] Mode Coordinates
Correction fixes known problems with Full Incremental Output.
Correction also fixes known problems with MultipleParts EquallySpacedOffsets ShiftPC and UnshftPC commands.
Added TrackXNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added TrackYNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added getACEPXY Procedure.
Called from ToolPath PointFeat.
Stores uncompensated LastFeat SPX# to Var(1).
Stores uncompensated LastFeat SPY# to Var(2).
Added setSRXYtoACEP Procedure.
Called at end of OpGuts IF Milling.
Adds SetPass1 LastFeat SPXY# to uncompensated SetPass2 LastFeat SPXY#.
Added Var(1) for storage of XPosition at progStart Procedure.
Added Var(2) for storage of YPosition at progStart Procedure.
DWB}

{11/25/98,
Initial : Fanuc 6M [FW] B001.16
Created: Okuma OSP 7000M [AB] BT42.16
Customer: Armstrong Blum, Lee Hench - 920/236-7200 ext. 119
ComPost2: Compiled with v1.7b13 - VG v5.03.03 or higher
MDD: Must use VM3_wSH.mch

This machine has one rotary around the Y-axis (B-axis) with -5 thru +95 deg limits
and one rotary around the Z-axis (C-axis) with -big thru +big limits.

Changes to "Form":

1. Under Default Formats, changed M to #00 and Q to #0
2. Under Origins and Values, changed First WFO to H1 and Last WFO to H50
3. Under Subs, changed Sub Call Label to O and Repeat label to Q
4. Under Tool Offsets, changed Tool Length Offset Enable to 56
5. Under Spindle and Coolant, changed Tool Change to G111 and Tool ID Label to Q
6. Under Drill Cycles, changed Drill from Part Clearance to M53 and from Entry
Clearance to M54.

Changes to "Prog":

1. Changed Program ID block in initOp sub.
2. Changed fixture offset from G54 thru G59 to G15H1 thru G15H50 and added 'G15'
to SetWFO.
3. Changed DrillCP with 'G71' ZCP1.
4. Changed Peck to 'Q' Peck# and added format for Peck#.
5. Changed all SubCall to 'CALL ' and all EndSub to 'RTS'.
6. Removed all calls to cSAngleA and cSAngleB subs.
7. Changed firstOp1, 2, & 3 subs per customer spec.
8. Changed newToolOp1, 2, 3, 4, & 5 subs per customer spec.
9. Changed sameToolOp1 & 3 subs per customer spec.
10. Changed end1 & 3 subs per customer spec.
11. Changed all CSOffsetB# to CSOffsetC# and all CSOffsetA# to CSOffsetB#.
Changed all BChange? to CChange? and all AChange? to BChange?.
12. Added doSpindle sub to select Vertical or Hrizontal Spindle.
13. Added calcXVector sub to calculate new coordinate X-axis vector angle.
14. Added doSlopeCSOn sub to output G333 and G69 blocks.
15. Added doSlopeCSOff sub to output G334 and G68 blocks.
16. Added calcRotary sub to calculate the C-axis location from 0 thru 359.
17. Added doRotaryCCW sub to output PM=17 for C-axis CCW rotation.
18. Added Save# Num#('5') to save the B-axis location.
19. Added Save# Num#('6') to save the C-axis location.
20. Added Save# Num#('27') to save the C-axis output location from 0 thru 359.
21. Added Save# Num#('28') to calculate the X-axis Vector.
22. Removed the output of doCSWFOComment.
JHE}

{1/20/99,
Initial : Okuma OSP 7000M [AB] BT42.16
Created: Okuma OSP 7000M [AB] BT42.16.1
Customer: Armstrong Blum, Lee Hench - 920/236-7200 ext. 119
ComPost2: Compiled with v1.7b15 - VG v5.04 or higher
MDD: Must use VM3_1DwSH.mch

Changes to "Prog":

1. Moved Rapid ZCP3 before G80.
2. Moved ZCP1 after the 2nd G69 block.
3. Added Bore & Dwell (G89) and FI-Stop-RO (G86) cycles.
JHE}

{3/2/99,
Initial : Okuma OSP 7000M [AB] BT42.16.1
Created: Okuma OSP 7000M [AB] BT42.16.2
Customer: Armstrong Blum, Lee Hench - 920/236-7200 ext. 119
ComPost2: Compiled with v1.7b15 - VG v5.04 or higher
MDD: Must use 1D2C_VM3_wSH.mch

This machine has one rotary around the negative X-axis (A-axis) with -5 thru +95 deg
limits and one rotary around the negative Z-axis (C-axis) with -big thru +big limits.

Changes to "Prog":

1. Removed 'G30P25' SpinOff block from firstOp1 and added it in doSlopeCSOn sub.
2. Under newToolOp1, sameToolOp1, and end1, output 'G30P25' SpinOff block only
when B-axis not at zero.
3. Changed all CoolOn to doCoolOn and added M12 for Mist Coolant.
4. Added doLargeToolChng sub to output a tool change line for tools larger than 5.00
inches. Also added a call to the sub in newToolOp3 sub.
5. Added SetPalletIn('0') in progStart and newToolOp3 subs.
6. Added output for manual tool change in firstOp1, newToolOp2, newToolOp3, and end2
subs when PIN(1) is entered thru Utility Data.
7. Added PIN(1) description in progStart sub (Utility Data).
8. In the MDD, changed the 5th axis orientation from -Y to -X.
9. Changed all CSOffsetB# to CSOffsetA#, all BChange? to AChange?, and all B-axis
comment to A-axis.
10. Changed all Save# and Recall# Num#('5') (B-axis) to Num#('4') (A-axis).
11. Under calcRotary, added SUB# Num#('90') to CSOffsetC# for Save# Num#('22').
This is due to changing the rotary orientation from -Y to -X.
12. Changed SetMaxRPM from 10000 to 3000.
JHE}

{Prog Numeric Format Definitions *********************************}

#1 = '###.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####.###;0.'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,2)
FORMAT(CSOffsetC#,2)
FORMAT(Recall#,2)
FORMAT(SUB#,2)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(CS1OffsetX#,4)
FORMAT(CS1OffsetY#,4)
FORMAT(CS1OffsetZ#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(Peck#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(CSSubID#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines ****************************************}

doLargeToolChng: {Added this sub - JHE 3/2}
IF GreaterThan? ToolDiameter# Num#('5.0')
{if tool dia is greater than 5.00 inches}
IF NotEqual? CSOffsetA# Recall# Num#('4')
{if current A-axis is not equal to last A-axis location}
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
SeqC ToolChng 'T50V1' EOL
ELSE {implies Horizontal Spindle}
SeqC ToolChng 'T50H1' EOL
END
END
END
RETURN

doSpindle:
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
'V1H0'
ELSE {implies Horizontal Spindle}
'V0H1'
END
RETURN

calcRotary:
Save# Num#('22') SUB# CSOffsetC# Num#('90') {C-axis location - 90 deg}
Save# Num#('23') DIV# Recall# Num#('22') Num#('360') {C-axis expressed in Rev}
Save# Num#('24') TRUNC# Recall# Num#('23') {full 360 Rev's of C-axis}
Save# Num#('25') SUB# Recall# Num#('23') Recall# Num#('24') {fraction Rev's of C-axis}
{#26 = current C-axis location in degrees from -360 thru +360}
Save# Num#('26') MUL# Recall# Num#('25') Num#('360')
{#27 = current Absolute C-axis location in degrees from 0 thru +360}
IF GreaterThan? Recall# Num#('26') Num#('0')
Save# Num#('27') SUB# Num#('360') Recall# Num#('26')
ELSE
IF LessThan? Recall# Num#('26') Num#('0')
Save# Num#('27') MUL# Recall# Num#('26') Num#('-1')
ELSE {implies #26 = 0}
Save# Num#('27') Recall# Num#('26')
END
END
'PAC=' Recall# Num#('27')
RETURN

doRotaryCCW:
IF GreaterThan? CSOffsetC# Recall# Num#('6')
'PM=17'
END
RETURN

calcXVector:
{(Recall# Num#('27') - 90) * -1}
Save# Num#('28') MUL# SUB# Recall# Num#('27') Num#('90') Num#('-1')
IF LessThan? Recall# Num#('28') Num#('0')
'P' SUB# Num#('360') ABS# Recall# Num#('28')
ELSE
'P' Recall# Num#('28')
END
RETURN

doSlopeCSOn:
IF NotEqual? CSOffsetA# Num#('0')
{if A-axis not at zero - Slope Coordinate System On}
SeqC 'G30P25' SpinOff EOL {Motion Home} {Added - JHE 3/2}
SeqC 'G333PAT=1' calcRotary ToolOfst doRotaryCCW EOL
SeqC 'G69X' CS1OffsetX# 'Y' CS1OffsetY# 'Z' CS1OffsetZ# calcXVector EOL
SeqC 'G69R' CSOffsetA# EOL
SeqC ZCP1 EOL
END
RETURN

doSlopeCSOff:
IF NotEqual? LAST CSOffsetA# Num#('0')
{if last A-axis not at zero - Slope Coordinate System Off}
SeqC 'G334' EOL
SeqC 'G68' EOL
SeqC 'G68' EOL
END
RETURN

doCoolOn: {Added this sub - JHE 3/2}
IF Mist?
'M12'
ELSE
CoolOn {M8}
END
RETURN

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

cSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

cSWFO:
'G15H' ADD# cSPartNum# Num#('0')
RETURN

wFO:
'G15H' ADD# PartNum# Num#('0')
RETURN

wFOStuff:
IF Flag?('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF WFOCS?
cSWFO
ELSE
wFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in subCSMP and closeMP}
ELSE
cSWFO
END
END
END
END
END
SetFlagF('2') { Do not output WFO second time wFOStuff is called for MP-WFO-OTAP-ECP }
RETURN

cSG52:
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

g52Stuff:
IF NOT Flag?('7') AND NOT WFOCS?
IF FirstOperation? OR NewTool? OR ChangeCS?
IF MultipleParts?
IF WorkFixtureOffsets?
cSG52
END
ELSE
cSG52
END
END
END
RETURN

doCSComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

doCSWFOComment: {Removed all calls to this sub - JHE}
RETURN

cSComments:
doCSComment
IF WFOCS? AND NOT MultipleParts?
{doCSWFOComment} {Removed - JHE}
END
RETURN

doSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
restoreScale
cSComments
END
RETURN

cSAngleA: {Removed all calls - JHE}
RETURN

cSAngleAC: {Removed all calls - JHE}
RETURN

cSAngleB: {Removed all calls - JHE}
RETURN

cSAngleBC: {Removed all calls - JHE}
RETURN

pSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

pSStuff:
RETURN

doPostScript:
pSInit
EachPS
SeqC PostScript EOL
pSStuff
NextPS
RETURN

doEndOpPS:
pSInit
EachEOPS
SeqC EndOpPS EOL
pSStuff
NextPS
RETURN

entryMove:
IF FeedEntry?
SeqC Feed ZIn
IF FirstOperation? OR NewTool?
FeedEnt
ELSE
FeedEntC
END
EOL
ELSE
SeqC RapidC ZIn EOL
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedRate }
END
END
RETURN

startSub:
OpenSub
SubID EOL
doSubComment
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

stdSub:
SeqC 'CALL ' CallLab RepLab RepCycs EOL
startSub
RETURN

finishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

finishSubG92: {part 2}
SeqC Preset ShiftRC EOL
'RTS' EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

toggleIncDecWFO:
IF Flag?('3') { Incrementing WFOs in effect }
SetFlagF('3')
ELSE { Decrementing WFOs in effect }
SetFlag('3')
END
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqC 'G15' SetWFO EOL
END
SeqC 'CALL ' CallLab RepLab OnePart EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
startSub
SaveCSProg
SaveCSOpStart
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE { Decrementing WFOs in effect }
LastWFO
EachWFO {simple eachPart}
doWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
toggleIncDecWFO
END
startSub
END
ELSE
SeqC 'CALL ' CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
startSub
END
RETURN

doCSWFOOps:
EachCSOp
{doCSWFOComment} {Removed - JHE}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqC cSWFO EOL
END
SeqC 'CALL ' CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
RETURN

closeMP:
IF WorkFixtureOffsets?
'RTS' EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
EachWFO {simple eachPart}
doCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE { Decrementing WFOs in effect }
LastWFO
EachWFO {simple eachPart}
doCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
toggleIncDecWFO
END
END
ELSE
SeqC absOrIncC EOL
SeqC Preset ShiftPC EOL
'RTS' EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

subCSMP:
IF WFOCS?
IF ChangeCS?
'RTS' EOL
CloseSub
NewProg
startSub
SaveCSProg
END
END
RETURN

doAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

doDrillAbsOrInc:
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

restoreAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqC absOrIncC EOL
END
RETURN

formatArc:
doAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

getACEPXY:
SetACSPCompF
Save# Num#('1') SPX# { Status Register Variable for X Axis }
Save# Num#('2') SPY# { Status Register Variable for Y Axis }
SetACSPComp
RETURN

setSRXYtoACEP:
SetPass1
SetSRXYtoEP
LoadFeat Num#('0') Num#('0') Num#('0')
TrackXNO# ADD# Recall# Num#('1') SPX# { Status Register Variable for X Axis }
TrackYNO# ADD# Recall# Num#('2') SPY# { Status Register Variable for Y Axis }
RETURN

toolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF LastFeat?
getACEPXY
END
SeqC MoveSXYC EOL
SeqC 'CALL ' CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC doDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC doAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
SeqC doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqC formatArc ArcFeedC EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqC incValueC EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqC absOrIncC CRCOffC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
'RTS' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqC absOrIncC Connect StrtPos EOL
milling
finishSub1
finishSubG92
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusInc EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
SeqC 'CALL ' CallLab EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqC ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
TrackZNO# ADD# FIRST SPZ# MUL# RepsLess1# RepeatZ#
RETURN

zonlyRepAutoCycle:
autoCycPat {write pattern moves and main calls}
startSub
NewProg
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqC incValueC StrtPosC EOL
absOrIncC
END
END
SetStatusOn
doSepSubZMoves
SetStatusOff
NextCycle
SetStatusOn
autoCycCutSub1 {build element sub}
TrackZNO# FIRST SPZ#
autoCycCutSub2
IF FeedConnect?
IF NOT AbsValue?
setSepSubZ
END
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
'RTS' EOL
CloseSub
{Element shift, not pattern}
RETURN

zonlyRep:
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqC StrtPosC EOL
END
END
doSepSubZMoves
NextCycle
startSub
TrackZNO# FIRST SPZ#
toolPath
finishSub1
'RTS' EOL
CloseSub
IF FeedConnect? AND NOT AbsValue?
setSepSubZ
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
IF NOT Flag?('7')
ClearCSOffset
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

opGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
zonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqC CRCOffC ZCP3C EOL
setSRXYtoACEP
ELSE
IF FIFO?
SeqC CRCOffC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC CRCOffC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF RetractToCP1?
SeqC 'G71' ZCP1 EOL
ELSE
SeqC ZCP2C EOL
END
GetCycle
IF FIFO? AND Dwell? {Added - JHE 1/20}
SeqC 'G89'
ELSE
IF FIStopRO? {Added - JHE 1/20}
SeqC 'G86'
ELSE
SeqC Cycle
END
END
StrtPos ZDepth RLevel Dwell
IF Peck?
'Q' Peck# {Changed - JHE}
END
Retract FeedEnt FromCP EOL
IF CallMasterOp?
SeqC 'CALL ' CallLabB CallMasterNum# EOL
skipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') { DrillSubs activated }
NewMasterProg
SeqC 'CALL ' CallLab EOL
startSub
toolPath
'RTS' EOL
CloseSub
SetFlagF('1') { DrillSubs deactivated }
ELSE
toolPath
END
END
setDrillEndOpZ
SeqC Rapid ZCP3 EOL
SeqC DrillOff EOL {G80 before G0 stops the spindle - JHE 1/20}
END
END
Save# Num#('4') CSOffsetA# {A-axis location - JHE}
Save# Num#('6') CSOffsetC# {C-axis location - JHE}
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('3000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('3') Num#('0') { Status Register Variable for Z Axis }
Save# Num#('4') Num#('0') {set A-axis location to zero}
Save# Num#('6') Num#('0') {set C-axis location to zero}
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlag('3') { Incrementing WFOs in effect }
SetFlag('4') { This post supports IncWFO/DecWFO }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
SetFlag('6') { TRUE = B-Style Output, FALSE = C-Style Output }
SetFlagF('7') { TRUE = D-Style Output }
SetFlagF('8') { TRUE = D-Style Output, FALSE = Local G52-WFO Coordinates }
SetPalletIn('0') {Added for manual tool change - JHE 3/2}
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' ' EOL
' pin(1) - when entered at op start, specifies output of manual tool change sequence.' EOL
' ' EOL
END

IF NOT Flag?('7')
IF Equal? NumOfCS# Num#('1') { 3 Axis Part - Output M-Style }
SetFlag('7')
ELSE
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('50')
SetWFOCS { use WFO for CS changes }
ELSE
IF Flag?('8')
SetFlag('7')
END
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to '
IF Flag?('7')
'non'
ELSE
'G52'
END
'-wfo style output. )' EOL
END
END
ELSE
SetFlag('7')
END
ELSE
IF LTEqual? NumOfCS# Num#('50')
SetWFOCS { use WFO for CS changes }
ELSE
IF Flag?('8')
SetFlag('7')
END
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to '
IF Flag?('7')
'non'
ELSE
'G52'
END
'-wfo style output. )' EOL
END
END
END
END
END
RETURN

initOp:
'$' ProgID1 EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
restoreScale
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
Seq Plane 'G20' CRCOff DrillOff AbsOrInc EOL
{SeqC 'G30P25' SpinOff EOL} {Motion Home} {Removed - JHE 3/2}
SeqC ProgStop EOL
doOpComments
doPostScript
IF Equal? Pallet# Num#('1') {Added - JHE 3/2}
{if manual tool change}
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
SeqC ToolChng 'T50V1' EOL
ELSE {implies Horizontal Spindle}
SeqC ToolChng 'T50H1' EOL
END
SeqC 'Y-100.' EOL {move to manual tool change location}
SeqC 'M70' EOL {manual tool change}
ELSE
SeqC ToolChng 'T' Tool# PreTool doSpindle EOL
END
RETURN

firstOp2:
SeqC wFOStuff EOL
g52Stuff
doSlopeCSOn
SeqC Speed SpinOn EOL
checkPass
SeqC Rapid AbsOrInc StrtPos doCoolOn EOL
RETURN

firstOp3:
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
SeqC OfstOn EOL
END
RETURN

newToolOp1:
doSlopeCSOff
SeqC RapidC ZCP1 CoolOff EOL
IF NotEqual? LAST CSOffsetA# Num#('0') {Added - JHE 3/2}
{if last A-axis not at zero - go Home and stop the spindle}
SeqC 'G30P25' SpinOff EOL {Motion Home}
END
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqC Rapid absOrIncC Home EOL
END
IF Equal? Pallet# Num#('1') {Added - JHE 3/2}
{if manual tool change}
SeqC 'Y-100.' EOL {move to manual tool change location}
SeqC 'M70' EOL {manual tool change}
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
SetPalletIn('0') {Added for manual tool change - JHE 3/2}
doLargeToolChng {Added - JHE 3/2}
doOpComments
doPostScript
IF Equal? Pallet# Num#('1') {Added - JHE 3/2}
{if manual tool change}
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
Seq ToolChng 'T50V1' EOL
ELSE {implies Horizontal Spindle}
Seq ToolChng 'T50H1' EOL
END
SeqC 'Y-100.' EOL {move to manual tool change location}
SeqC 'M70' EOL {manual tool change}
ELSE
Seq ToolChng 'T' Tool# PreTool doSpindle EOL
END
RETURN

newToolOp4:
SeqC Rapid Plane AbsOrInc wFOStuff EOL
g52Stuff
doSlopeCSOn
SeqC Speed SpinOn EOL
checkPass
SeqC Rapid AbsOrInc StrtPos doCoolOn EOL
RETURN

newToolOp5:
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
SeqC OfstOn EOL
END
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
doSlopeCSOff
SeqC RapidC ZCP1 CoolOff EOL
IF NotEqual? LAST CSOffsetA# Num#('0') {Added - JHE 3/2}
{if last A-axis not at zero - go Home and stop the spindle}
SeqC 'G30P25' SpinOff EOL {Motion Home}
END
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR AChange? OR CChange?
doSlopeCSOff
SeqC RapidC ZCP1 EOL
SeqC 'G30P25' EOL {Motion Home}
END
END
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
SeqC wFOStuff EOL
g52Stuff
IF LAST ProgStop?
doSlopeCSOn
SeqC Speed SpinOn EOL
SeqC Rapid PlaneC AbsOrInc StrtPos doCoolOn EOL
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
SeqC OfstOn EOL
END
ELSE
IF NewToolOffset? OR AChange? OR CChange?
doSlopeCSOn
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
IF Equal? CSOffsetA# Num#('0')
{if A-axis at 0 - Vertical Spindle}
SeqC OfstOn EOL
END
ELSE
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC doCoolOn EOL
END
END
RETURN

end1:
IF NotEqual? Recall# Num#('4') Num#('0')
{if A-axis not at zero - Slope Coordinate System Off}
SeqC 'G334' EOL
SeqC 'G68' EOL
SeqC 'G68' EOL
END
SeqC RapidC ZCP1 CoolOff EOL
IF NotEqual? Recall# Num#('4') Num#('0') {Added - JHE 3/2}
{if A-axis not at zero - go Home and stop the spindle}
SeqC 'G30P25' SpinOff EOL {Motion Home}
END
RETURN

end2:
doEndOpPS
IF FIRST ToolChangeAtHome?
SeqC RapidC absOrIncC FirstHome EOL
END
IF Equal? Pallet# Num#('1') {Added - JHE 3/2}
{if manual tool change}
SeqC 'Y-100.' EOL {move to manual tool change location}
SeqC 'M70' EOL {manual tool change}
END
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

end3:
SeqC 'M60' EOL {pallet change}
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

mPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
subCSMP
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
end2
closeMP
end3
RETURN

mP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
closeMP
end2
end3
RETURN

mP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
openMP
firstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
end2
end3
RETURN

{Start of executable Prog, Top Level **********************}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF AllToolsOnePart?
mPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mP1ToollAllPXcp
END
END
ELSE
noMPs
END