{Change Comments ***********************************************************}

{10/23/90
Copied & modified: Fanuc 10T MS [-] L001.71
For: Chandler Evans (Colt Ind.)
Machine: Wasino TH-102 Dual Spindle
Control: Fanuc OT
Changed NegSideLathe to PosSideLathe
Changed ReverseXZArcs to StandardXZArcs
Using Tool Offset Number for Minimum Sequencing.
Deleted Preset Home from beginning of EACH Tool. Geometry Offset is stored with Tool Offset.
Do not cancel the Tool Offset in CheckOffset, call the new one only.
Go to machine Home and turn CoolOff at end of EACH Tool.
Deleted UnTool from end of Prog.
Added OptCyc1 PostScript to Call Sub for Spindle switch at beginning and/or end of Program.
Added literal 'G1G98F190.' for Rapids, modified all occurances except in Canned Cycles.
Add Spaces between codes.
NOTE: Modifications to Canned Cycles were not done as Ron said they were not using them due to
not being allowed to make Rapid Moves around the part in there shop & Canned Cycles will do that.
JR}

{2/12/91
Copied & modified: Fanuc 0T Wasino L182.71
For: Gibbs & Associates
Machine: Wasino
Control: Fanuc 0T
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.4 Format.
DWB}

{10/1/91
Updated: Fanuc 0T Wasino L182.71.4
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
KM}

{10/10/91
Updated: Fanuc 0T Wasino L182.82
For: Gibbs & Associates
Made minor fixes.
ncPost was bombing out, and reporting error #28.
Arc EndPoints were not being output at ArcFeat.
ArcIJC sometimes output '?' which screwed Retag.
Copied & modified Fanuc 10T MS [-] L001.82 MachSpec.
Only differences were:
Use 'F' for Rapid Moves = TRUE
Rapid Feed Rate (XXXX^X) = 1900
Default FORMAT for 'F' = '###.####;0'
Spaces between codes.
Changed Rapid Label from ' G0' to ' G98' in MachSpec.
Changed Feed Label from ' G1' to ' G99' in MachSpec.
Outputting literal ' G1' on startup blocks at FirstOperation and NewTool.
Also outputting literal ' G1' for ToolPath Features following ArcFeat.
DWB}

{4/12/92
Updated: Fanuc 0T Wasino L182.82.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 0T/3T Miyano L008.82.1 Format.
KM}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(RapidF#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(ToolOffset#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
OptCyc1F {reset OptCyc1}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC FeedRate EOL
ELSE
RapidF# { No Output - Forces FeedRate in ToolPath }
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC FeedRate EOL
ELSE
RapidF# { No Output - Forces FeedRate in ToolPath }
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC Feed ZSPC FeedRate EOL
ELSE
RapidF# { No Output - Forces FeedRate in ToolPath }
END
RETURN

AppMove:
ZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqLabC XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
ELSE
SeqLabC SpeedC EOL
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

CheckFeed:
IF NOT FirstFeat?
IF LAST ArcFeat?
' G1'
END
END
RETURN

FormatArc:
IF ArcCW?
' G2'
ELSE
' G3'
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC CheckFeed RapidC MoveXC MoveZC RapidFC EOL
ELSE
IF LineFeat?
SeqLabC CheckFeed FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

CheckRapidF1:
IF LAST CannedCycle?
RapidF
ELSE
RapidFC
END
RETURN

CheckRapid2:
IF CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

CheckRapidF2:
IF CannedCycle?
RapidF
ELSE
RapidFC
END
RETURN

GetSequence:
IF MinimizeSequencing?
'N' ToolOffset#
ELSE
SeqLab
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' OptionalCycle1, OptCyc1 -' EOL
' If called in the first operation before an ENDOP,' EOL
' The following will be ouput at the beginning of the program.' EOL
' M98P200' EOL
' G28U0W0T00' EOL
' If called in the last operation after an ENOP,' EOL
' The following will be ouput at the end of the program.' EOL
' M98P100' EOL
' G28U0W0T00M11' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoPostScript
IF OptCyc1?
IF MinimizeSequencing?
'N8'
ELSE
SeqLabC
END
' M98 P200' EOL
SeqLabC ' G28 U0 W0 T00' EOL
SeqLabC ' M1' EOL
END
DoOpComments
Plane
GetSequence
IF ConstantSurfaceFeed?
Preset MaxRPM EOL
SeqLabC
END
' G1' Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset RapidF SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid1
IF LAST ApproachOD?
SeqLabC XCPC CheckRapidF1 EOL
SeqLabC ZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
SeqLabC ZCPC EOL
ELSE { LAST ApproachFace }
SeqLabC ZCPC CheckRapidF1 EOL
END
END
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 EOL
END
SeqLabC NewHome CoolOff EOL
SeqLabC ' G28 U0 W0 T00' EOL
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
GetSequence
IF ConstantSurfaceFeed?
Preset MaxRPM EOL
SeqLabC
END
' G1' Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset RapidF SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqLabC StockOnNoCan XSPC ZSPC CheckRapidF1 EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
SeqLabC ZCPC EOL
ELSE { LAST ApproachFace }
SeqLabC ZCPC CheckRapidF1 EOL
END
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC CheckRapidF1 EOL
SeqLabC ZCPC EOL
ELSE { LAST ApproachFace }
SeqLabC ZCPC CheckRapidF1 EOL
END
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC CheckRapidF1 EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC CheckRapidF1 EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn ' G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle ' Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
IF Rapid?
RapidF
END
EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos RapidF EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC ' M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead ToolAngle EOL
IF AutoFinish?
SeqLabC ' G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLabC ' M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth ' E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G4 P' Dwell# EOL
END
SeqLabC Rapid ZSP RapidF EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos RapidFC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CheckRapid2
IF ApproachOD?
SeqLabC XCPC CheckRapidF2 EOL
SeqLabC ZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CheckRapidF2 EOL
SeqLabC ZCPC EOL
ELSE { ApproachFace }
SeqLabC ZCPC CheckRapidF2 EOL
END
END
DoEndOpPS
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqLabC FirstHome CoolOff EOL
SeqLabC ' G28 U0 W0 T00' EOL
SeqLabC ProgStop EOL
SeqLabC SpinOff EOL
SeqLabC ' M0' EOL
IF OptCyc1?
IF MinimizeSequencing?
'N8'
ELSE
SeqLabC
END
' M98 P100' EOL
SeqLabC ' G28 U0 W0 T00 M11' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END