{Change Comments ***********************************************************}

{7/19/96
Copied: Fanuc 10T MS [-] L001.85.01
Created: Fanuc 16T Studer L478.85
For: Cimetrix/Boeing
Machine: Studer Grinder
Control: Fanuc 16T
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Bede Kortegast of Cimetrix
Rediculously simple.
No Tools, no spindle, no coolant, nothing but FirstOperation Approach, ToolPath, and Home.
DWB}

{8/9/96
Modified: Fanuc 16T Studer L478.85
Created: Fanuc 16T Studer L478.85.1
For: Cimetrix/Boeing
Versions: Catalyst v3.05.03C/Compost 4.21.37/v1.0b1
Corrected prog due to crashing.
Added OpenSub command at FirstOperation.
Moved final StockOff command to after NextOp command.
Deleted Exit sub and call to same.
Moved contents to after NextOp command.
Changed Home command to FirstHome command and moved to after NextOp command.
Moved literal 'M99' block to after NextOp command.
Moved EOP EOR commands to after NextOp command.
Moved Post command to after NextOp command.
Moved Close command to after NextOp command.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '0000'
#7 = '#'

FORMAT(Program#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan FeedRateNoCan ZSPC EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan FeedRateNoCan XSPC EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
FeedRateC MoveXC MoveZC ArcRC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC FeedC FeedRateC CkCRC MoveXC MoveZC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'O' Program# EOL
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoPostScript
Plane
Approach
StockOn
SetPass1
ToolPath
END
NextOp {loops back to EachOP until last Operation}
StockOff
CRCOffC RapidC
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC Home EOL
SeqC 'M99' EOL
SeqC EOP EOR EOL
Post
Close