{Change Comments ***********************************************************}

{
10/24/94 [cwh]
B001.81.4 ( from B001.81.3 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves.
}

{11/8/94
Modified: Fanuc 6M (FW) B001.81.4
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{
12/01/94
B001.81.6
Changed FirstOp3 to call out A0B0 to move to the first CS.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.

Added RecallWFO sub-routine to NotSameToolWFO and SameToolWFO to ouput the current fixture offset
and A0B0. Added for easier restarts at the machine. Both are only called from NoMPs.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.
}

{
12/02/94
Changed version number to .00 from .81
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/08/94
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added WFO1 and A0B0 if AxisAvail to End2:
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/09/94
Fixed RecalWFO to check AAxisAvail? and BAxisAvail?
Cleaned up FirstOp3 to use new checks placed in CSAngleA and CSAngleB
TH}

{
Format: Fanuc 6M (FW) B001.00.03
12/19/94
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Fanuc 6M (FW) B001.00.04
1/10/95
NewToolOp3 now has an AbsOrInc on the line that calls out the Plane 'G80' CRCOff
NewToolOp5 no longer has the AbsOrInc command
NewToolOp5b has been created and has the AbsOrInc command
Changed MP1ToollAllPfu to call NewToolOp5b
Added AbsOrInc and Rapid to the FirstOperation? section of MP1ToollAllPXcp
Added Rapid to the NewTool? section of MP1ToollAllPXcp
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
MP1ToollAllPXcp, MP1ToollAllPFU, and MPallTools1P now output WFO if NOT WorkFixtureOffsets?
TH}

{
Format: Fanuc 6M (FW) B001.00.05
1/13/95
Replaced TrackZNO# ZDepth# with TrackZNO# FIRST SPZ# in the drilling section
Formatted TrackZNO# to #4
}

{
Format: Fanuc 6M (FW) B001.00.06
2/15/95
Fixed RecallWFO: to output correct WFO# if WFOCS
TH}

{ Added ClearCSOffset to SubCSMP TH}

{
Format: Fanuc 6M (FW) B001.10
7/27/95
Added G52 style output for too many coordinate systems
Updated to .10 format
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{2/26/96
Initial: Fanuc 6M (FW) B001.11
Created: Fanuc 6M (FW) B001.11.01
Develop: ComPost 4.21.34, Catalyst68K v3.02.02C
Comment: Corrections to Processor.
Corrected format of CSOffsetA# and CSOffsetB#.
To correct multiple parts output:
Added "OR Flag?('2')" to "IF WFOCS?" in "SubCSMP:".
To Simplify prog subs and correct errors in MP1ToollAllPXcp:
Changed FirstOp3a/NewToolOp5a to FirstOp4/NewToolOp6
Deleted NewToolOp5b sub and changed call to NewToolOp5 (they were identical!)
Deleted OfstOn and Cool On from FirstOp3/NewToolOp5
Added calls to FirstOp4/NewToolOp6 after calls to FirstOp3/NewToolOp5.
Changed StrtPos in MP1ToollAllPXcp to FirstOp3/NewToolOp5.
To correct a literal number 2 from being output when processing multiple parts:
Changed order of booleans from:
IF WFOCS? OR Flag?('2')
to:
IF Flag?('2') OR WFOCS?
Modified WFO Handling:
Changes:
Deleted RecallWFO sub. It was not used!
Deleted NotSameToolWFO & SameToolWFO subs.
Added WFOStuff sub.
Changed all WFO calls in main loops to WFOStuff.
Results:
Changes do not effect Multiple Parts output.
Correct WFO is output by default at the beginning of each tool.
G52, if used, is output by default at the beginning of each tool.
G52, without WFO, is output at SameTool only if there is a change.
Jim Radcliffe}

{4/17/96
Initial: Fanuc 6M (FW) B001.11.01
Created: Fanuc 6M (FW) B001.12.01
Comment: Changed version number to reflect new identification scheme.
Jim Radcliffe}

{6/14/96
Initial: Fanuc 6M (FW) B001.12.01
Created: Fanuc 6M (FW) B001.12.02
Comment: Modified CRC handling to reflect the way I do it and same as M001.89.
Jim Radcliffe}

{6/24/96
Initial: Fanuc 6M (FW) B001.12.02
Created: Fanuc 6M (FW) B001.12.03
Comment: Added Missing prog formatter for CSSubID#.
Jim Radcliffe}

{6/24/96
Initial: Fanuc 6M (FW) B001.12.03
Created: Fanuc 6M (FW) B001.12.04
Comment: In MP1ToollAllPXcp added positioning BEFORE OfstOn!
Jim Radcliffe}

{6/24/96
Initial: Fanuc 6M (FW) B001.12.04
Created: Fanuc 6M (FW) B001.12.05
Comment: Simplified
reduced nnnnOp# sub calls to reflect the MPs cut off points.
Moved WFOstuff to FirstOp1 & NewToolOp3
Jim Radcliffe}

{6/25/96
Initial: Fanuc 6M (FW) B001.12.05
Created: Fanuc 6M (FW) B001.12.06
Comment: Further simplified WFO handling.
Jim Radcliffe}

{8/10/96
Initial: Fanuc 6M (FW) B001.12.06
Created: Fanuc 6M (FW) B001.12.07
Comment: Modifications per bug reports from Aavid, myself and Danny Ball
Corrected output of MultipleParts WorkFixtureOffsets OneToolAllParts ExitClearancePlane.
Modified WFOStuff sub to allow output for MultipleParts WorkFixtureOffsets
The output was being suppressed!
I then simplified WFOStuff sub.
Added DecWFO after NextWFO and added IncWFO after NextPrevWFO.
This will leave the output of WFOStuff on the correct WFO!
In doing the above fixes, OpenMP and CloseMP were modified with no change to output.
Added 2 new Prog Subs DoCSWFOOps & DoCSG52Ops
This simplifies and shortens the prog and CloseMP
Deleted the use of Flag#2
It was just the opposite of the WFOCS boolean!
Corrected returning A and B axis in End2 per Danny Ball
Jim Radcliffe}

{8/12/96
Initial: Fanuc 6M (FW) B001.12.07
Created: Fanuc 6M (FW) B001.12.08
Develop: ComPost2 68k, Catalyst68K v3.04.10.C
Comment: Corrected output of WFOStuff & Simplified WFO subs.
Deleted the use of NeedWFO1 boolean
Added Flag #2 to control output of WFOStuff.
Jim Radcliffe}

{10/2/96,
Initial: Fanuc 6M (FW) B001.12.08
Created: Fanuc 6M (FW) B001.14
Simplified Toolpath Linefeat by the addition of CkCRC and CkCRCNum subs.
MPK}

{10/2/96,
Initial: Fanuc 6M (FW) B001.14
Created: Fanuc 6M (PW) C001.14
modified for partial WFO output, MPK}

{11/22/96
Versions: Catalyst v3.23C/Compost 4.21.37/v1.0b1
.14 Additions:
Deleted Flag(2) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}

{2/25/97
Modified: Fanuc 6M (FW) C001.14
Created: Fanuc 6M (FW) C001.15
For: Gibbs & Associates
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Corrected problem with StrtPos for MultipleParts OneToolAllParts ExitClearancePlane.
Only concerns WFOCS and G52 style programs.
Post was not outputting good position in Main Program Output for FirstOperation only.
Problem was corrected by doing ClearCSOffset prior to StrtPos.
Rewrote code at following subs:
Added ClearCSOffset at CSG52 sub.
Rewrote logic at G52Stuff sub.
Corrected problem with CS related stuff not being output.
Caused by only testing AAxisAvail.
Added BAxisAvail test at DoCSComment sub.
Added AAxisAvail test at DoCSWFOComment sub.
Added BAxisAvail test at DoCSWFOComment sub.
Changed name of OffsetComments sub to CSComments and rewrote logic.
Modified handling of G52 style output for MultipleParts WorkFixtureOffsets.
Only concerns AllToolsOnePart and OneToolAllParts FullUp situations.
Reduces length of file by eliminating redundancy of G52 blocks.
Moves G52 blocks from Main Program to Sub Programs.
Extra unnecesary sub programs are combined into fewer subs.
Returns to old M001 style of handling MultipleParts WorkFixtureOffsets.
New style only needed for WFOCS style programs.
Rewrote logic at DoCSG52Ops sub.
Rewrote logic at OpenMP sub.
Rewrote logic at DoCSWFOOps sub.
Rewrote logic at CloseMP sub.
Changed IF WorkFixtureOffsets? to IF WFOCS? at SubCSMP sub.
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
NOTE: I believe there is a bug with ToolChanges.
For WFOCS and G52 style programs, FirstHome command at End2 sub is outputting absolute,
unshifted CS#1 value regardless of final CSGroup.
Should be shifted value corresponding with active CSGroup consistant with NewToolOp2 sub.
For MultiplePart EquallySpacedOffsets programs, Home command at NewToolOp2 sub and FirstHome
command at End2 sub are outputting shifted values corresponding with active CSGroup.
Should be absolute, unshifted CS#1 value.
These bugs have not been verified and are only my observations while testing the Tutorial Part.
DWB}

{4/16/97
Initial: Fanuc 6M (PW) C001.15
Created: Fanuc 6M [UPE] CY71.15
ForUser: CIM Solutions / Umisys Plymouth Engineering
Control: Fanuc 6M
Machine: Shizouka Matchmaker ( Custom machine from Scottland )
Develop: ComPost2 68K 1.0b11, CatalystPPC v3.33C
Comment: New processor per marked up readout and conversation with Jerry Lee
Jim Radcliffe}

{4Jun98
Original: Fanuc 6M [UPE] CY71.15
Created: Anilam 1400 [UPE] CU05.15
For: Unisys Plymouth Engineering
Changes made per: Jerry Lee
New Post Per FAX and conversation with Jerry Lee
Changed all comments to start with '*'
Added GearRange commands
Changed WFOs to 'G53 0#' style
Added Literal 'G53 00' at the start of NewToolOp1 to cancel fixture Offsets
Changed M30 to M2 in MachSpec
Deleted all references to G49 and G28, OfstOff
Added Untool at End2
Added ' G0 G91 X10. Y-2. Z-2.' at End2
Changed End of Line From ASCII(59) to ASCII (13) in MachSpec
Charles Winston}

{10Jun98
Original: Anilam 1400 [UPE] CU05.15
Created: Anilam 1400 [UPE] CU05.15.1
For: Unisys Plymouth Engineering
Changes made per: Jerry Lee
Deleted StartPos for all Drilling. StartPos must come after the cycle is called.
Modified Drilling Cycles:
Changed Peck label from Q to I in MachSpec
Added P value for Clearance Plane.
Added D value forDwell.
Deleted FromCP in Cycle.
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '####0.0##'
#3 = '*####0.0##'
#4 = '###0.0###;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(Peck#,4)
FORMAT(Dwell#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(CSSubID#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

CSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

CSWFO:
' G53 O' CSPartNum#
RETURN

WFO:
' G53 O' PartNum#
RETURN

WFOStuff:
IF Flag?('2')
IF NOT SameTool?
IF WFOCS?
CSWFO
ELSE
WFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
END
END
SetFlagF('2')
RETURN

CSG52:
IF FirstOperation? OR NewTool? OR ChangeCS?
SeqC ' G52 X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# EOL
END
ClearCSOffset
RETURN

G52Stuff:
IF AAxisAvail? OR BAxisAvail?
IF NOT WFOCS?
IF MultipleParts?
IF WorkFixtureOffsets?
CSG52
END
ELSE
CSG52
END
END
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'* SUB NUMBER: ' Program# EOL
END
RETURN

DoCSComment:
IF AAxisAvail? OR BAxisAvail?
'* CS#' CS# ' - ' CSComment$ EOL
END
RETURN

DoCSWFOComment:
IF AAxisAvail? OR BAxisAvail?
IF FirstOperation? OR NewTool? OR ChangeCS?
'* ' CSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# EOL
END
ClearCSOffset
END
RETURN

CSComments:
IF WFOCS?
IF MultipleParts?
IF OneToolAllParts? AND ExitClearancePlane?
ClearCSOffset { Necessary for correct StrtPos in Main }
END
ELSE
DoCSComment
DoCSWFOComment
END
ELSE
DoCSComment
END
RETURN

DoToolComment:
IF ToolComment?
' * ' ToolComment$
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF ToolTypeComment?
'* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF OperationIDComment?
'* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'* ' OperationComment$ EOL
END
IF WorkGroupComment?
'* ' WorkGroupComment$ EOL
END
RestoreScale
END
CSComments
RETURN

CSAngleA:
IF AAxisAvail?
' A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
' B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

DoCSG52Ops:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC ' G53 O' SetWFO EOL
END
SeqC SubCall CallLab RepLab OnePart EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSG52Ops
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSG52Ops
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
StartSub
END
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSComment
DoCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC CSWFO EOL
END
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
END
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle ZDepth RLevel
IF Dwell?
' D' Dwell#
END
IF Peck?
Peck
END
Retract
IF RetractToCP1?
' P' ClearancePlane1#
ELSE
' P' ClearancePlane2#
END
FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid ' G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('4500')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('6')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'* Not enough Work Fixture Offsets to handle this part. ' EOL
'* Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] ' EOL
'* exceeds the machine limit. Switching to G52 style output. ' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('6') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'* Not enough Work Fixture Offsets to handle this part. ' EOL
'* Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. ' EOL
'* Switching to G52 style output. ' EOL
END
END
END
RETURN

InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'* PROGRAM: ' ProgramName$
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'* ' ProgramComment$ EOL
END
IF FormatNameComment?
'* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'* FIRST TOOL NOT IN SPINDLE ' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqC Plane CRCOff ' G70' DrillOff AbsOrInc EOL
SeqC ' T' Tool# DoToolComment EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
G52Stuff
SeqC GearRange EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC WFOStuff EOL
SeqC Rapid Plane AbsOrInc
IF NOT Drilling?
StrtPos
END
CSAngleA CSAngleB EOL
RETURN

FirstOp3:
SeqC OfstOn CoolOn EOL
RETURN

NewToolOp1:
SeqC CoolOff EOL
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
SeqC ' G53 O0' EOL
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqC OpToolID ToolChng EOL
SeqC ' N' Tool# DoToolComment EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
G52Stuff
SeqC GearRange EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC WFOStuff EOL
SeqC Rapid Plane AbsOrInc
IF NOT Drilling?
StrtPos
END
CSAngleA CSAngleB EOL
RETURN

NewToolOp5:
SeqC OfstOn CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
SeqC DoToolComment EOL
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
G52Stuff
IF LAST ProgStop?
SeqC WFOStuff EOL
IF NewGear?
SeqC GearRange EOL
END
SeqC Speed SpinOn EOL
SeqC Rapid PlaneC AbsOrInc
IF NOT Drilling?
StrtPos
END
CSAngleA CSAngleB EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
SeqC WFOStuff EOL
IF NewGear?
SeqC GearRange EOL
END
SeqC Rapid PlaneC AbsOrInc
IF NOT Drilling?
StrtPos
END
CSAngleA CSAngleB SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC CoolOff EOL
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
SeqC ' G53 O0' EOL
IF Equal? CSOffsetA# Num#('0') AND Equal? CSOffsetB# Num#('0')
ELSE
SeqC
IF AAxisAvail?
CSAngleA
END
IF BAxisAvail?
CSAngleB
END
EOL
SeqC Preset
IF AAxisAvail?
' A0'
END
IF BAxisAvail?
' B0'
END
EOL
END
IF ProgStop?
SeqC ' M0' EOL
END
IF NOT FirstTool?
SeqC UnTool ToolChng EOL
END
SeqC ' G0 G91 X10. Y-2. Z-2.' EOL
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS ' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET ' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS ' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END