{Change Comments ***********************************************************}

{8/31/89
Copied & modified: Japax M026.53.
For: Hi-Stat.
Changed MachSpec Numbers I-J Max Arc Radius from 0 to 999.9999.
This will give us the needed ArcIJ output.
Changed Strings 1 Arc Center Labels to I and J.
JR}

{6/29/90
Modified: Fanuc Series O Elox M234.55
For: Hi-Stat.
Added ProgID1
Changed to standard Fanuc subs.
Deleted CRCOffsetC from ToolPath.
Added Last FeatExtend for CRCOff.
Changed to SeqC & deleted ReTag.
Added Home commands.
No decimal points, using 5 trailing places.
Updated to .72.1 where applicable.
Misc other minor changes per Dan & Rick requests
JR}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{10/11/90, Added SkipZ to beginning of output because this is for an EDM machine, DWB}

{4/3/91
Modified: Fanuc Series O Elox M234.73.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/15/91
Modified: Fanuc Series O Elox M234.79
For: Hi-Stat
Added a Progstop.
Changed Default Format for 'L' and 'O'.
KM}

{4/14/92
Modified: Fanuc Series O Elox M234.79.1
For: Hi-Stat
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Moved CRCOn to First Approach Move for non-AutoCycle type Operations.
Added literal 'M00' before and after ToolPath for wire-cutting and re-threading.
DWB}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^##0'
#3 = '*###^##0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftR EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
SeqC SubCall CallLab RepLab Parts EOL
StartSub
RETURN

CloseMP:
SeqC Preset ShiftP EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshiftP EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
{ Not Supported }
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC RapidC CRCOffC MoveXYC EOL
ELSE
IF XMove? OR YMove?
SeqC RapidC CRCOnC MoveXYC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC FeedC CRCOffC MoveXYC EOL
ELSE
IF XMove? OR YMove?
SeqC FeedC CRCOnC MoveXYC EOL
END
END
ELSE
IF ArcFeat?
SeqC FormatArc EOL
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SeqC MoveSXYC EOL
SeqC 'M00' EOL { For Wire-Cutting and Re-Threading }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc EOL
SeqC 'M00' EOL { For Wire-Cutting and Re-Threading }
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
IF AutoCycle?
EACHFeat
AutoCycCutSub1
AutoCycCutSub2
NEXTFeat
ELSE
ToolPath
END
RETURN

G92Sub:
StdSub
IF AutoCycle?
SeqC AbsOrInc Connect StrtPos EOL
Milling
ELSE
SeqC AbsOrInc Connect CRCOnC StrtPos EOL
SeqC 'M00' EOL { For Wire-Cutting and Re-Threading }
Milling
IF CutterRadiusCompensation?
SeqC FeedC CRCOffC LastFeatExtend EOL
END
SeqC 'M00' EOL { For Wire-Cutting and Re-Threading }
END
FinishSubG92
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SkipZ
{UseSeparateSubCalls}
{SetMaxSeparateSubCalls ('50')}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqC Preset Home EOL
IF MultipleParts?
OpenMP
END
ELSE
DoEndOpPS
END {common point for all operations}
IF Milling?
Plane { No Output }
DoOpComments
DoPostScript
CheckPass
IF Repeats?
Seq AbsOrInc Rapid StrtPos EOL
NewProg
G92Sub
ELSE
IF AutoCycle?
Seq AbsOrInc Rapid StrtPos EOL
Milling
ELSE
Seq AbsOrInc Rapid CRCOnC StrtPos EOL
SeqC 'M00' EOL { For Wire-Cutting and Re-Threading }
Milling
IF CutterRadiusCompensation?
SeqC FeedC CRCOffC LastFeatExtend EOL
END
SeqC 'M00' EOL { For Wire-Cutting and Re-Threading }
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF MultipleParts?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Reopen
EOR EOL
Close