{Change Comments ***********************************************************}

{8/11/89
Copied & modified; Fanuc OT [-] L031.55 for, Indarg.
Machine is a Mori Sieki AL20 with Fanuc OT Mate control.
Use 'G30X0.Z0.' for home position.
Add GearRange.
Delete FromCP & RLevel from drilling, changed K to U for Peck value,
and deleted G80.
Jim Radcliffe}

{3/27/90, Updated: Fanuc 0T Mate MS (-) L031.56 to .69.3 foramt, JR}

{3/27/90
Copied & modified: Fanuc 0T Mate MS (-) L031.69.3
For: Indarg
Positive side lathe. R format arcs.
2 line theading.
Jim Radcliffe}

{5/30/90
Modified: Fanuc OT Mate MS L031.69.3
Added R value to 1st Rough Contour Cycle line.
Updated to .69.5
Jim Radcliffe}

{7/23/90
Modified: Fanuc OT Mate MS L031.69.5
Deleted ReverseXZArcs
Changed StrtPos to StrtPosC in RoughContour & RoughPatternShift.
Updated to .69.7 format
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/3/90, Updated: Fanuc OT Mate MS L031.70 to .71 format, JR}
{9/12/90, added MovesComment, SeqLabC in for PostScript, JR}

{9/12/90
Copied & modifed: Fanuc OT Mate MS L031.71.1
For: GE
Control: General Numeric OTA
Machine: Custom Made
Deleted Coolant.
Using Special G Code Group.
Deleted UnTool from end of prog.
Jim Radcliffe}

{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}
{10/19/93, Updated Fanuc 0TA T-Mate L175.71.2 per Fanuc 10T MS [-] L001.82ż, JR}

{10/20/93 thru 11/9/93
Copied & modified: Fanuc 0TA T-Mate L175.82
For: Dynamic Systems Engineering
Control: GE Fanuc 0T-B
Machine: Hardinge Conquest 42 Chucker
Added M98P1, safe start index position sub, before all indexes.
No Preset Home.
Tool geo offsets are stored in offset file caled with tool call.
Added M98P1 or M98P2 at end of tool depending on approach.
Added G10 line to beginning of program for turret position offset.
Deleted G95, AbsOrInc, GearRange
Modified comments placement in output.
Added DoSpinOn sub to handle SpinOn and CoolOn.
Minor modifications to Canned Cycles.
Added a blank line between tools.
Changed XStkLeft to output radius values.
Sequence numbers set to operation number times 100 at beginning of each operation.
Moved SameTools DoOpComments to CheckOffset, that is where we actually
"Start New Operation" for SameTool after "Finish off last Operation" stuff is done.
I would suggest this be changed in ALL lathe processors.
Jim Radcliffe}

{3/10/94
Copied: Fanuc 0TB Hardinge L295.82.1
Created: Fanuc 0TB Hard [BN] L297.82.1
For: Bentley-Nevada
Control: GE Fanuc 0T-B
Machine: Hardinge Conquest 42 Chucker
Versions: ncCad 4.32.03/ncCAM 4.32.03/ncPost 4.32.03/Compost 4.21.20
Changes made per Gene Sorem of Bentley-Nevada.
Changed FORMATs to output zero values without decimal point in Form and Prog.
Added FORMAT#8 '0000' for Program#.
Added FORMAT#9 '00' for Recall#.
Deleted SeqLabC from all Comments.
Deleted condition to output ToolComment for SameTool Operations only at DoOpComments.
Added support of Parts Catcher.
Activated when processor encounters OptionalCycle1 PostScript Command.
Added OptCyc1F for Parts Catcher at PSInit.
Will output literal 'M26', Parts Catcher In at ODApproachSP sub.
Moved call to DoEndOpPS to before clearance moves at end of prog.
This checks for OptCyc1 for purpose of outputting literal 'M25', Parts Catcher Out, on move to
XCPC block.
Added PostScript comments explaining usage of OptionalCycle1 command.
Modified Manual Tap Cycle.
Will output literal 'M49' for start at FaceApproachSP.
Testing for GreaterThan ZopCP# ZStockMax# at AppMove.
Added Flag(1) for correct LoadFeat Move at end of Operation.
Will not output Dwell prior to LastFeat block.
On ToolPath LastFeat, will output InverseSpinOn with MoveZC block.
Will output SpinOff instead of CoolOff at NewTool and end of prog.
Will output literal 'M48' for end at NewTool and end of prog.
Added CoolOn to AppMove.
Deleted DoSpinOn sub.
Changed all calls to SpinOn.
Deleted DoInverseSpinOn sub.
Changed all calls to InverseSpinOn.
Deleted 'Åš' Operation# '00' at CheckOffset, FirstOperation and NewTool.
Changed ArcJC ArcIC to ArcIJC at FormatArc.
Added GetSeqLab sub.
Outputs 'N' Tool# instead of SeqLab.
Called from FirstOperation and NewTool.
Added Var(1) to Var(12) for each Tool to keep track of NewTool Opertaions.
If a Tool is called more than once, GetSeqLab sub will output 'N' Tool# Recall# Tool# to allow
for correct callup of Operations.
Added InitVar sub to initialize Var(1) to Var(12) prior to FirstOperation.
Added StandardXZArcs at setup and initializations.
Clears any previous ReverseXZArcs during consecutive post processes.
Changed ProgID1 to ':' Program# at FirstOperation.
Modified StartUp code at FirstOperation and NewTool.
Added literal 'G96G99' to 'G20' block for ConstantSurfaceFeed Operations.
Activating CSF at Home, Deleted activation at common point.
Added literal 'G97G99' to 'G20' block for Non-ConstantSurfaceFeed Operations.
Deleted literal 'G10P0Z-8.'.
Deleted literal 'M98P1', Safe Start Sub call at CheckOffset, NewTool and end of Prog.
Deleted literal 'G4' and ToolComment block.
Moved OpToolID LatheOffset to Approach sub.
Added NewHome CoolOff at NewTool.
Added 'T' LAST Tool# '00' to cancel Offset at NewTool.
Deleted ' ' EOL for separating Operations at NewTool
Added FirstHome CoolOff at end of prog.
Added 'T' Tool# '00' to cancel Offset at end of prog.
Added 'T' FIRST Tool# '00' to index Turret at end of prog.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '##.####;0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0'
#6 = '##^###0'
#7 = '#'
#8 = '0000'
#9 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ToolDiameter#,2)
FORMAT(Peck#,2)
FORMAT(MUL#,2) { To get decimal point output on CutDeth for Canned Roughing }
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CutDepth#,6)
FORMAT(RapidF#,7)
FORMAT(Program#,8)
FORMAT(Recall#,9) { For Tool# SeqLab Variables at GetSeqLab sub }

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
OptCyc1F { For Parts Catcher }
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
SeqLabC
IF NotEqual? CycleStartX# XOpCD#
FeedNoCan XSPC FeedRateNoCan
END
IF OptCyc1?
IF LastOp? OR NEXT LastOp?
'M26' { Parts Catcher In }
END
END
EOL
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC 'M49' EOL
END
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff
IF Drilling? AND Tap? AND GreaterThan? ZOpCP# ZStockMax#
ZOpCP
SetFlag('1') { For Correct LoadFeat Positioning at end of Operation }
ELSE
ZCP
END
CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
OpToolID LatheOffset
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset: {without gear ranges}
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
InverseSpinOn { Output on current MoveZC block }
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

GetSeqLab:
Save# Tool# ADD# Recall# Tool# Num#('1')
'N' Tool#
IF GreaterThan? Recall# Tool# Num#('1')
Recall# Tool#
END
RETURN

InitVar: { Tool# SeqLab Variables }
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
Save# Num#('4') Num#('0')
Save# Num#('5') Num#('0')
Save# Num#('6') Num#('0')
Save# Num#('7') Num#('0')
Save# Num#('8') Num#('0')
Save# Num#('9') Num#('0')
Save# Num#('10') Num#('0')
Save# Num#('11') Num#('0')
Save# Num#('12') Num#('0')
SetFlagF('1') { See AppMove sub, Drilling AND Tap AND GreaterThan ZOpCP# ZStockMax# }
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('600') { thats 600 inches per minute on Z, X axis is 472 IPM max }
InitVar { Tool# SeqLab Variables }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' OptionalCycle1, OptCyc1 -' EOL
' Parts Catcher activation.' EOL
' When processor encounters this command for OD Approach at LastOp, or Next to LastOp,' EOL
' will output M26 for Parts Catcher In, on move to X StartPosition block.' EOL
' When processor encounters this command following ENDOP command for OD Approach at' EOL
' LastOp, will output M25 for Parts Catcher Out, on move to X Stock Exit block.' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
':' Program#
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF ConstantSurfaceFeed?
GetSeqLab CSSOn 'G20G96G99' EOL
SeqLabC Preset MaxRPM EOL
ELSE
GetSeqLab CSSOff 'G20G97G99' EOL
END
SeqLabC Rapid OpToolID '00' Speed SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
IF Flag?('1')
{ See AppMove sub, we are already clear in Z }
{ LAST Drilling AND LAST Tap AND GreaterThan LAST ZOpCP# ZStockMax# }
SetFlagF('1')
LoadFeat ZStockMax# Num#('0')
IF ZMove?
IF GreaterThan? EPZ# SPZ#
SeqLabC MoveZC EOL
END
END
ELSE
SeqLabC ZCPC EOL
END
DoEndOpPS
IF LAST Drilling? AND LAST Tap? AND LAST NOT CannedCycle?
SeqLabC NewHome SpinOff EOL
SeqLabC 'M48' EOL
ELSE
SeqLabC NewHome CoolOff EOL
END
SeqLabC 'T' LAST Tool# '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
GetSeqLab CSSOn 'G20G96G99' EOL
SeqLabC Preset MaxRPM EOL
ELSE
GetSeqLab CSSOff 'G20G97G99' EOL
END
SeqLabC Rapid OpToolID '00' Speed SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF Flag?('1')
{ See AppMove sub }
{ LAST Drilling AND LAST Tap AND GreaterThan LAST ZOpCP# ZStockMax# }
SetFlagF('1')
END
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R' MUL# Num#('1') CutDepth# EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPosC EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPosC EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {2 finish passes}
ELSE
'01'
END
IF Chamfer?
'10' {1 thread lead distance for chamfer}
ELSE
'00'
END
IF SingleEdgeCut?
'55' {using 55 degrees for tool angle, need ToolAngle# command}
ELSE
'00'
END
'Q'
IF ConstantVolumeCut?
'15' {.0015 minimum cut depth}
ELSE
CutDepth# {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
END
'R0' {using zero for no finish stock allowance, need XStckLeft# command}
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'F' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC LCycle ZSP 'F' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle Retract EOL
SeqLabC LCycle ZDepth Peck FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
ELSE
IF PeckFullRetract?
SeqLabC LCycle 'P9135' RLevel ZDepth Peck FeedRate 'H' ToolDiameter# 'C' Peck# Dwell EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC Rapid ZSP EOL
END
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
END
SeqLabC StockOff StrtPosC EOL
ToolPath
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
DoEndOpPS { Need to check for ENDOP OptCyc1 now }
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC
IF OptCyc1?
'M25' { Parts Catcher Out }
END
EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
IF Flag?('1')
{ See AppMove sub, we are already clear in Z }
{ Drilling AND Tap AND GreaterThan ZOpCP# ZStockMax# }
SetFlagF('1')
LoadFeat ZStockMax# Num#('0')
IF ZMove?
IF GreaterThan? EPZ# SPZ#
SeqLabC MoveZC EOL
END
END
ELSE
SeqLabC ZCPC EOL
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC FirstHome SpinOff EOL
SeqLabC 'M48' EOL
ELSE
SeqLabC FirstHome CoolOff EOL
END
SeqLabC OpToolID '00' EOL
SeqLabC 'T' FIRST Tool# '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END