{Change Comments ***********************************************************}

{6/5/89, changed tool path to force feed on first TP move after a tool change,added Metric, WFG}
{.62,1/24/90, added OP clearances for v3.2, WFG}

{1/29/90
Modified: Fanuc 10T MS [-] L001.69
Deleted ClearancePlane1# & FirstMoveEPX# prog format, they are not being used.
Deleted extra 4 lines not needed from fall thru if not canned cycle.
Added SetHome command, enables incremental ouput.
Deleted ZeroPosReg command, has no effect.
Jim Radcliffe}

{2/16/90
Modified: Fanuc 10T MS [-] L001.69.1
Added Feedrate to Approach sub.
Deleted FirstFeed sub & changed FirstFeed command to Feedrate in ToolPath.
Jim Radcliffe}

{2/20/90
Modified: Fanuc 10T MS [-] L001.69.2
Deleted extra StockOnNoCan command from Approach sub.
Added missing CheckOffset commands to Sametool.
Added FeedrateC commands to SameTool Feed lines.
Jim Radcliffe}

{5/10/90
Modified: Fanuc 10T MS [-] L001.69.3
Added missing CSS stuff for same tool where the last operation was not CSS.
Jim Radcliffe}

{5/30/90
Modified: Fanuc 10T MS [-] L001.69.4
Changed 1st axis moves in Approach to unconditional moves.
Jim Radcliffe}

{6/4/90
Modified: Fanuc 10T MS [-] L001.69.5
Commented out Feedrate in Approach & FeedrateC in SameTool, rapid to start point.
Jim Radcliffe}

{6/21/90
Modified: Fanuc 10T MS [-] L001.69.6
Commented out Feed in Approach & in SameTool, see last note.
Put back the FirstFeed sub and calls in ToolPath that was deleted earlier.
Jim Radcliffe}

{7/3/90
Modified: Fanuc 10T MS [-] L001.69.7
Modified Approach sub and Approach handling for SameTool.
Moved all ConstantSurfaceFeed output to common point of all operations.
Modified the FirstFeed sub to output Feedrate on FirstFeat of each operation.
Added comment restricting use of modifiers during EACHQuadrant/NEXTQuadrant loop.
DWB}

{.71, Added PSComments, minor fixes, 8/1/90, JR}

{8/7/90 thru 8/29/90
Copied & modified: Fanuc 10T MS [-] L001.71
For: Teton Machine
Control: Fanuc 2T
PosSideLathe
6 place F also used for ThredLead
2 digit T code, 1st is tool#, 2nd is offset#.
RoughSimple only roughing cycle.
Dual Turret, G68 for mirror image.
Note the Headstock is on the right hand side and it moves with Z commands.
Misc other stuff for this new processor.
Jim Radcliffe}

{10/2/90, Added StockOff globally at FirstOperation, DWB}

{11/10/97,
Initial: Fanuc 2T Star JNC-16 L174.71.1
Created: Fanuc 2T Star JNC-16 L174.85
Updated to .85 version.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '########;0'
#4 = '###^##0'
#5 = '0'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ToolLess20#,5)
FORMAT(ToolOffsetLess20#,5)
FORMAT(RapidF#,6)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
ProgStopF {reset ProgStop?}
CoolOffF {reset CoolOff?}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

approachSP:
IF ApproachFace?
SeqLabC stockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
stockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC Feed ZSPC FeedRate EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC stockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
stockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC FeedRate EOL
END
END
RETURN

appMove:
ThisOpEntryZCP
IF ToolOver20?
'T' ToolLess20# ToolOffsetLess20#
ELSE
OpToolID LatheOffset
END
RETURN

Approach: { NOT FOR TAILSTOCK, .69.8 }
SeqC Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP Appmove
ELSE
IF ApproachID?
XOpCD appmove
ELSE {ApproachFace}
StockOnNoCan XSP Appmove StockOff
END
END
EOL
approachSP
RETURN

CheckOffset:
DoEndOpPS
IF NewToolOffset?
IF ToolOver20?
SeqC 'T' ToolLess20# '0' EOL
SeqC 'T' ToolLess20# ToolOffsetLess20# EOL
ELSE
SeqC OpToolID '0' EOL
SeqC OpToolID LatheOffset EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling? AND Dwell?
SeqC 'G04P' Dwell# EOL
END
IF CannedCycle?
Seq
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL { force Feedrate on FirstFeat, even if Rapid }
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc EOL {force Feedrate on FirstFeat, even if Arc}
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G32' MoveXC MoveZC XTapAtZ ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
NegateZ
PosSideLathe
ReverseXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' ProgramStop, PS' - EOL
' Outputs an M00 at the end of the tool.' EOL
' CoolantOff, COff -' EOL
' suppress coolant on command for current operation' EOL
END
EachOp {Start of post processing *********************}
TagInc
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF ToolOver20?
Seq 'G68' EOL
ELSE
Seq 'G69' EOL
END
SeqC 'S01' SpinOn EOL
SeqC 'M11' EOL { chuck open }
SeqC Rapid 'Z0T0' EOL
SeqC 'M20' EOL
SeqC 'M10' EOL { chuck close }
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ToolOver20?
SeqC NewHome 'T' LAST ToolLess20# '0' EOL
ELSE
SeqC NewHome LOfstOff '0' EOL
END
IF ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Plane
IF ToolOver20?
Seq 'G68' EOL
ELSE
Seq 'G69' EOL
END
SeqC 'S01' SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
CheckRapid
IF LAST StraightConnect?
CheckOffset
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
checkRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
checkOffset
approachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqC LCycle XatFinZ 'Z' FirstMoveEPZ# XTapAtZ FeedRate EOL
ELSE
SeqC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
IF RoughContour?
StockOn
SetPass1
ToolPath
IF AutoFinish?
SetPass2
ToolPath
END
ELSE
IF RoughPatternShift?
StockOn
SetPass1
ToolPath
IF AutoFinish?
SetPass2
ToolPath
END
END
END
END
ELSE
IF Threading?
SeqC LCycle 'X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
IF AutoFinish?
SeqC XatFinZ EOL
END
ELSE
IF Drilling?
SetPass1
ToolPath
ELSE
IF Grooving?
Seq StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
Seq RapidC StrtPos EOL
ToolPath
END
END
END
IF ApproachID? {.62}
SeqC RapidC XOpCDC EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CheckRapid
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
IF ToolOver20?
SeqC FirstHome 'T' ToolLess20# '0' EOL
ELSE
SeqC FirstHome OpToolID '0' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END