{Change Comments ***********************************************************}

{11/2/90
Modified: Dynapath 10M M078.76.1
For: Chevron Oil Field Research Company
NOTE: This Post Processor doesn't support incremental output.
Control requires that first line of program have Prog# in parentheses.
Deleted all Z axis output and added SkipZ at InitProg.
Added comment notifying user that this Post Processor does not support Drilling Cycles.
DWB}

{4/16/91
Copied & modified: Dynapath 10M [CO] M356.76.2
For: Gibbs & Associates
Machine:
Control: Dynapath 10M
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Made major modifications per conversation with Dale Bachman at Dynapath Systems, Inc.
This processor is totally conversational.
NOTE: This Post Processor does not support WorkFixtureOffsets.
Added Flag('2') to check if FeedRate needs to be output.
Added Flag('1') to check if CRCOn (C1) has been output.
CutterRadiusCompensation rules:
CRCOn (C1) must only be activated when Feed (1) or CWArc/CCWArc (2) are active.
Control requires CRCOff (C0) DummyMove on line preceeding CRCOn (C1).
Added logic to output SPX# SPY# CRCOff (C0) in TurnOnCRC Sub.
Rapid (0) must NOT be output while CRCOn (C1) is active.
When RapidFeat, CutterRadiusCompensation and Flag('1') are TRUE:
Added logic to output FeedC (1) MoveXYZC RapidFC (F199.1) in ToolPath.
RapidFC set to output F199.1 in Mach Spec.
Control requires CRCOff (C0) DummyMove when cancelling CRCOn (C1).
Added logic to output MoveXY CRCOff (C0) in TurnOffCRC Sub.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '###.#;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

Get$:
IF NOT EmptyLine?
'$'
END
RETURN

DoSubComment:
NewProg
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Program# Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

ZStop:
SeqLab '(9)M0' Get$ EOL
RETURN

EntryMove:
{ No Z moves supported in this processor. }
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
{ No Z moves supported in this processor. }
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
{ No Z moves supported in this processor. }
RETURN

FinishSubG92: {part 2}
IF NOT ZshiftOnly?
SeqLab '(0)' ShiftRC Preset Get$ EOL
END
'<' Tag# EOL
TagDown
CloseSub
IF NOT ZshiftOnly?
SeqLab '(0)' UnshftRC Preset Get$ EOL
END
RETURN

OpenMP:
TagUp TagInc
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
StartSub
RETURN

CloseMP:
SeqLab '(0)' ShiftPC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF AutoCycle?
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
ELSE
MoveXYC
END
RETURN

FormatArc:
GetPlane CheckMove
IF AutoCycle?
ArcI '/' ArcJ '/'
ELSE
ArcIJ
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

CheckFeedRate: {enables CRC on first call, .70}
IF NOT Flag?('2')
SetFlag('2')
IF LineFeat?
FeedRate
ELSE
IF ArcFeat?
ArcFeed
END
END
END
RETURN

TurnOnCRC:
IF CutterRadiusCompensation? AND NOT Flag?('1')
SetFlag('1')
SeqLab '(1)'
IF AutoCycle?
'X' SPX# '/Y' SPY# '/'
ELSE
'X' SPX# 'Y' SPY#
END
CRCOff Get$ EOL
END
RETURN

TurnOffCRC:
IF CutterRadiusCompensation? AND Flag?('1')
SeqLab '(1)'
IF AutoCycle?
MoveX '/' MoveY '/'
ELSE
MoveXY
END
CRCOff Get$ EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
TurnOnCRC
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' GetPlane CheckMove CRCOnC DecelFeed Get$ EOL
ELSE
IF XMove? OR YMove?
SeqLab '(1)' GetPlane CheckMove CRCOnC CheckFeedRate FeedRateC Get$ EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
IF NOT PointFeat?
ZStop
END
EACHFeat
IF PointFeat?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
IF AutoCycle?
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF CutterRadiusCompensation? AND Flag?('1')
IF XMove? OR YMove?
SeqLab '(1)' GetPlane CheckMove CRCOnC RapidFC Get$ EOL
END
ELSE
IF XMove? OR YMove?
SeqLab '(0)' GetPlane CheckMove Get$ EOL
END
END
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc CRCOnC ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc CRCOnC DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc CRCOnC CheckFeedRate ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat?
TurnOffCRC
ZStop
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor doesn't support incremental output. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
SeqLab '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
SeqLab '(1)' StrtPos Get$ EOL
ELSE
SeqLab '(0)' StrtPos Get$ EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect? {.71.2, added Connect}
SeqLab '(1)' StrtPos Get$ EOL
ELSE
SeqLab '(0)' StrtPos Get$ EOL
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
ToolPath
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

CheckCoolantOn: { For SameTool only }
IF NOT CoolOff? AND LAST CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
RETURN

CheckRapid:
IF NOT AutoCycle?
IF Repeats?
IF FeedConnect?
Rapid
END
ELSE
Rapid
END
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SkipZ
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetAbs
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
SetFlagF('1') { Flag to set-up CutterRadiusCompensation }
SetFlagF('2') { Flag to suppress FeedRate output }
Plane { no output }
IF FirstOperation?
'(' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
SeqLab '(T) ' ProgramComment$ Get$ EOL
END
IF FormatNameComment?
SeqLab '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqLab '(T) FIRST TOOL IN SPINDLE' Get$ EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab '(9)' GearRange Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos Rapid Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
SeqLab '(9)' ProgStop Get$ EOL
END
END

{Start new Operation}

SeqLab '(9)' ToolChng Get$ EOL
IF NewGear?
SeqLab '(9)' GearRange Get$ EOL
END
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos Rapid Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

GetStartOfSameTool
IF NewGear?
SeqLab '(9)' GearRange Get$ EOL
END
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
SeqLab '(9)' SpinOn Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab '(9)' CoolOff Get$ EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
IF NewGear?
SeqLab '(9)' GearRange Get$ EOL
CheckCoolantOn
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
ELSE
CheckCoolantOn
SeqLab '(9)' ToolOfst Speed Get$ EOL
END
SeqLab '(0)' StrtPos Rapid Get$ EOL
ELSE

{Start new Operation}

GetStartOfSameTool
IF NewGear?
SeqLab '(9)' GearRange Get$ EOL
CheckCoolantOn
SeqLab '(9)' SpinOn Speed Get$ EOL
ELSE
CheckCoolantOn
SeqLab '(9)' Speed Get$ EOL
END
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
END
END
END
END {common point for all operations}
IF Milling?
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
ELSE
IF Drilling?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) ***** NOTE *****' Get$ EOL
SeqLab '(T) THIS POST PROCESSOR' Get$ EOL
SeqLab '(T) DOES NOT SUPPORT' Get$ EOL
SeqLab '(T) DRILLING CYCLES!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' ToolChng Get$ EOL
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab '(0)' FirstHome Get$ EOL
END
IF ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
SeqLab '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
'END' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END