{
MILL=T
LATHE=F
ADV_MILL=F
ROTARY_MILL=F
SIMPLE_ROT_POS=F
MILLTURN_Y-AXIS=F
MILLTURN_POLAR-SEG=F
SUBS=T
METRIC=F
}
{Change Comments ***********************************************************}

{1/3/89
Copied & modified Fanuc 10M M008.54 for R.C.H. Eng.
Machine is a Mazak VQC 20/40A with Mazatrol M-2 control.
Calling the OpToolID cancels the offset & sends Z home &
puts the tool in the spindle & calls the length offset.
Replaced OfstOff with OpToolID or UnTool at end of prog
so first tool is in spindle at prog start.
Added GearRange. Deleted tool changes & length offset calls.
Deleted Home & SpinOff commands
Put ZCP1 and CoolOn on StrtPos line.
Changed sequence numbers to 3 fixed places.
Jim Radcliffe}

{3/6/89
Modified; Mazatrol M2 Mazak M162.55, for RCH Eng.
Add 'G92Z0.' to end of Prog.
Jim Radcliffe}

{5/23/90, corrected tool call for for multiple parts full up, see above notes, JR}
{5/23/90, Updated: Mazatrol M2 Mazak M162.56 to .72.1 format, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{12/12/90, Updated: Mazatrol M2 Mazak M162.73 to .76.1 format, JR}

{12/12/90
Copied & modified: Mazatrol M2 Mazak M162.76.1
For: Precision Machine
Control: Mazatrol M-32
Move ProgramComment & TimeComment to Before EOR code at beginning of prog.
Add AbsOrInc to beginning of prog.
Move WFOStuff to StrtPos line.
First tool not in spindle format.
Deleted GearRange.
Deleted ZCP1 from StrtPos line & added OfstOn.
Move coolant to OfstOn line.
Changed length offset cancel to typical stuff.
Put CRCOff on line by itself after Z move unless AutoCycle.
Add tool change positions 'G28X0Y0'.
Delete UnTool from end of prog.
Added PreTool.
Changed Tapping feed to IPR.
Jim Radcliffe}

{4/3/91
Modified: Mazatrol M-32 Mazak M368.76
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{6/3/91
Modified: Mazatrol M-32 Mazak M368.79
For: Precision Machine
Changed EOR at beginning of program to '='.
Suppress custom ProgramComment & TimeComment before '=' when UseComments? is false.
Modified Saftey Start & Tool Change blocks at beginning of each tool.
Jim Radcliffe}

{10/31/91
Modified: Mazatrol M-32 Mazak M368.79.1
For: Precision Machine
Added ResetCRCNum at beginning of Toolpath to correctly set cutter comp number.
Kim Michelman}

{1/3/92
Modified: Mazatrol M-32 Mazak M368.79.2
For: Precision Machine
Deleted date and time line prior to the ProgID1 per customer request.
Kim Michelman}

{12/22/94
Updated: Mazatrol M-32 Mazak M368.79.3
For: Gibbs & Associates/ASKO
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Corrected FORMAT5 from '########;0' to '#######0'.
Corrected FORMAT6 for Dwell# from '####^###;' to '####^##0'.
Added RestoreScale Sub per 4-Axis Post Processor.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added FIFO? at FinishSub1, AutoCycCutSub2, ZonlyRepAutoCycle subs and end of IF Milling.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to output CRCOnC in OneFeat ToolPath.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at ToolPath.
Outputs G40 at all ZMoveOnly Feature Retract blocks.
Deleted CRCOnC and CRCOffsetC from ToolPath ArcFeat.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
DWB}

{9/27/95, Updated Mazatrol M32 Mazak M368.81.2 to .85 format per Fanuc 6M M001.85.01.03, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{1/15/97
Copied & Modified: Mazatrol M32 Mazak M368.89
Created: Mazatrol M32 Mazak NM MZ20.89.1
For: National Machinery
Versions: Catalyst v3.25C/Compost 4.21.37/v1.0b4
Changes made per Ken Hoffman of National Machinery
Added support of FIStopOffWallRO Drill Cycle.
Post outputs 'G76' for Cycle.
Post outputs 'Q' Retract# for Amount of relief on the XYPlane.
Post outputs 'P' Dwell#
Added support of FIStopRO Drill Cycle.
Post outputs 'G86' for Cycle.
Post outputs 'P' Dwell#
Added support of M7, Mist Coolant.
Added support of M50, Air Blast Coolant.
Post uses Pulse Boolean to test.
Added support of M51, ThruSpin Coolant.
NOTE: Special Drilling Cycles and Coolants require 2D4C_VM3.mch MDD.
NOTE: LAST and NEXT modifiers have no effect on Coolant Booleans.
Wayne is currently working on this.
Deleted literal 'G28X0.Y0.' at NewTool and end of Prog.
Added support for standard Asynchronous Tapping Cycle.
Post was outputting Rigid Tap Cycle.
Standard Tap Cycle requires IPM FeedEnt and H0 parameter
Added support for G74, Left Hand Standard and Rigid Tap Cycles.
Deleted literal 'G92Z0.' at end of Prog.
Deleted literal 'T0' to replace PreTool for LastTool at NewTool.
Added ToolChng 'T0' to unload Spindle at end of Prog.
Added 'G30X0.Y0.P3' at end of Prog.
Updated for Catalyst v3.25C per Fanuc 6M M001.89a Format
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Deleted version comments.
Added ckCRC and ckCRCNum subs.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}

{4/3/97
Updated & Modified: Mazatrol M32 Mazak NM MZ20.89.1
Created: Mazatrol M32 Mazak NM MZ20.89.2
For: National Machinery
Versions: Catalyst v3.32C/ComPost2 MSL 68K
Changes made per Ken Hoffman of National Machinery
Updated for Catalyst v3.32C per Fanuc 6M M001.89b Format
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
Changed PreTool to 'T' NextTool# at FirstOperation and NewTool.
Added IncValue to 'G30X0.Y0.P3' block at end of Prog.
Added AbsValue condition to MultipleParts AND AllToolsOnePart at end of Prog.
DWB}

{22Jun97
Original: Mazatrol M32 Mazak NM MZ20.89.2
Created: Mazatrol M32 Mazak NM MZ20.89.3
For: National Machinery
Changes made per: Ken Hoffman
Changed Seq to SeqLab and SeqC to SeqLabC throughout the Prog
Changed Sequence Label from 'N" to 'N?' in MachSpec
Added Literals '/2N?G91G30Z0' and '/2N?Y0' EOL in FirstOpearatin and NewTool
Added ReTag at end of Prog
Charles Winston}

{17Jul97
Original: Mazatrol M32 Mazak NM MZ20.89.3
Created: Mazatrol M32 Mazak NM MZ20.89.4
For: National Machinery
Changes made per: Ken Hoffman
Added 'G30' to Literal '/2N?G30Y0' and '/2N?Y0' EOL in FirstOpearation and NewTool
Replaced SeqLabC with Literal '/1N?' in Newtool and End of Prog
Added Literals '/2N?G91G30Z0' and '/2N?G30Y0' at End of Prog
Charles Winston}

{7/15/98,
Initial : Mazatrol M32 Mazak NM MX55.89.4
Created: Mazatrol M32 Mazak NM MX55.89.5
Customer: National Machinery, Ken Hoffman 419/447-5211

Changes to "Prog":

1. Changed SetMaxSeparateSubCalls from 50 to 500.
JHE}

{08/11/98,
Initial: Mazatrol M32 Mazak NM MX55.89.5
Created: Mazatrol M32 Mazak NM MX55.89.6
For: National Machinery

NOTE: This post now allows CRC calls on Rapid and Line Features with a
Z component. The customers' control can handle this.

Changes to Prog:
1) ckCRC - Deleted logic prohibiting CRC on a Z move.
2) ckCRCNum - Deleted logic prohibiting CRC on a Z move.
CDH}

{1/11/99,
Initial : Mazatrol M32 Mzk NM MX55.89.6
Created: Mazatrol M32 Mz [NM] MX55.89.7
Customer: National Machinery, Ken Hoffman 419/447-5211
ComPost2: v1.7b14

Changes to "Form":

1. Under Arcs, changed I-J Max Arc Radius to 200.

Changes to "Prog":

1. Added Post Header Comment.
2. Added doRangeCode sub and calls to output M37 & M38 before SpinOn.
JHE}

{Prog Numeric Format Definitions **************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'
#7 = '####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Retract#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NextTool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(FeedEntIPR#,7)

{Prog Subroutines **********************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
'G' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

doRangeCode:
IF GreaterThan? SpeedRPM# NUM#('970')
'M38' {High Range}
ELSE
'M37' {Low Range}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
SeqLabC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC SetWFO EOL
END
SeqLabC SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqLabC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
CloseSub
SeqLabC WFO1 EOL
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
CRCOnC
END
RETURN

ckCRCNum:
IF NOT LastFeat?
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC ckCRC FormatArc ArcFeedC ckCRCNum EOL
DecelMove2
END
SeqLabC ckCRC FormatArc DecelFeed ckCRCNum EOL
ELSE
SeqLabC ckCRC FormatArc ArcFeedC ckCRCNum EOL
END
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL
END
END
SeqLabC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetCoolOn:
IF NOT CoolOff?
IF Mist?
'M7'
ELSE
IF ThruSpin?
'M51'
ELSE
IF Pulse? { Air Blast }
'M50'
ELSE
CoolOn
END
END
END
END
RETURN

CkCoolOn:
IF Mist? AND LAST NOT Mist?
GetCoolOn
ELSE
IF ThruSpin? AND LAST NOT ThruSpin?
GetCoolOn
ELSE
IF Pulse? AND LAST NOT Pulse?
GetCoolOn
END
END
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('500') {Changed from 50 - JHE}
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF MultipleParts?
IF AllToolsOnePart?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied OneToolAllParts?}
IF FullUp?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied ExitClearancePlane?}
SetFlag('2') { WFOStuff }
END
END
ELSE
SetFlag('2') { WFOStuff }
END
IF FirstOperation?
'=' EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab Plane CRCOff DrillOff AbsOrInc Rapid 'M19' OpToolID EOL
'/2N?G91G30Z0' EOL
'/2N?G30Y0' EOL
SeqLabC ToolChng EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLabC doRangeCode EOL {Added - JHE 1/11}
SeqLabC Speed SpinOn EOL
CheckPass
SeqLabC AbsOrInc WFOStuff Rapid StrtPos
IF NOT LastTool?
'T' NextTool#
END
EOL
SeqLabC OfstOn GetCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC doRangeCode EOL {Added - JHE 1/11}
SeqLabC Speed SpinOn EOL
SeqLabC AbsOrInc WFOStuff Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
IF AbsoluteMoves?
'/1N?' IncValue OfstOff EOL
'/2N?G91G30Z0' EOL
'/2N?G30Y0' EOL
SeqLabC AbsValue EOL
ELSE
'/1N?' OfstOff EOL
'/2N?G91G30Z0' EOL
'/2N?G30Y0' EOL
END
SeqLabC 'G49' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
SeqLab Plane CRCOff DrillOff AbsOrInc Rapid 'M19' OpToolID EOL
SeqLabC ToolChng EOL
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLabC doRangeCode EOL {Added - JHE 1/11}
SeqLabC Speed SpinOn EOL
CheckPass
SeqLabC AbsOrInc WFOStuff Rapid StrtPos
IF LastTool?
'T0'
ELSE
'T' NextTool#
END
EOL
SeqLabC OfstOn GetCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC doRangeCode EOL {Added - JHE 1/11}
SeqLabC Speed SpinOn EOL
SeqLabC AbsOrInc WFOStuff Rapid StrtPos EOL
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqLabC CoolOff EOL
IF AbsoluteMoves?
IncValue
END
SeqLabC OfstOff EOL
SeqLabC 'G49' EOL
DoEndOpPS
SeqLabC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC doRangeCode EOL {Added - JHE 1/11}
SeqLabC SpeedC SpinOn EOL
SeqLabC PlaneC AbsOrInc WFOStuff Rapid StrtPos EOL
SeqLabC OfstOn GetCoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
IF AbsoluteMoves?
IncValue
END
SeqLabC OfstOff EOL
SeqLabC 'G49' EOL
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqLabC SpeedC EOL
SeqLabC PlaneC AbsOrInc WFOStuff Rapid StrtPos EOL
SeqLabC OfstOn
IF NOT CoolOff? AND LAST CoolOff?
GetCoolOn
ELSE
CkCoolOn
END
EOL
ELSE
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqLabC SpeedC EOL
SeqLabC PlaneC AbsOrInc WFOStuff Rapid StrtPos EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC GetCoolOn EOL
ELSE
SeqLabC CkCoolOn EOL
END
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
SeqLabC CRCOffC EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
IF FIStopOffWallRO?
SeqLabC 'G76' FromCP StrtPos ZDepth RLevel 'Q' Retract# 'P' Dwell# FeedEnt EOL
ELSE
IF FIStopRO?
SeqLabC 'G86' FromCP StrtPos ZDepth RLevel 'P' Dwell# FeedEnt EOL
ELSE
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
SeqLabC FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF Tap?
IF RigidTap?
'F' FeedEntIPR#
ELSE
FeedEnt 'H0'
END
ELSE
FeedEnt
END
EOL
END
END
IF CallMasterOp?
SeqLabC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC SubCall CallLab EOL
StartSub
ToolPath
SeqLabC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC 'G80' EOL
SeqLabC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
SeqLabC RapidC ZCP3C EOL
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
IF AbsoluteMoves?
'/1N?' IncValue OfstOff EOL
'/2N?G91G30Z0' EOL
'/2N?G30Y0' EOL
SeqLabC AbsValue EOL
ELSE
'/1N?' OfstOff EOL
'/2N?G91G30Z0' EOL
'/2N?G30Y0' EOL
END
SeqLabC 'G49' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC ToolChng 'T0' EOL
SeqLabC IncValue 'G30X0.Y0.P3' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
IF AbsoluteMoves? AND EquallySpacedOffsets?
SeqLabC AbsValue EOL
END
CloseMP
END
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
ReTag