{Change Comments ***********************************************************}

{6/1/94
Copied & modified: Fanuc 6M NoNest M001.81.4
For: Walker Machine
Control: Mazatrol M32
Machine: Mazak Vertical AJV-25/405
Using Variables for MultipleParts G92 shifts and Work Fixture Offsets.
Variables are stored in and called by the program.
NewWFO PostScript command is not supported with variables.
Variables are not used for Repeats, which will be handled with the standard use of G92 shifts.
This is due to that each operation can have different shift values, which would make
the use of variables quite extensive, but possible!? I am developing this processor
for Virtual wich currently does not have repeated operations on XY. Z Repeats
could be avoided or set up to use separate sub calls. This is a mute point if
we are outputting multiple parts as this processor does not nest subs. The customer
expresses that he mainly will be doing multiple parts.
Requested that all preset calls be made with the machine at program zero!
Using LoadFeat to make a karate move to program zero before doing a preset call.
Z is not moved to program zero, this would be too dangerous. Added a warning for doing
a Z shift with the Exit Clearance Plane selection. It should be OK with the Full Up
selection as we do not need to make a move to Z program zero it is done at Machine Z zero.
Again, using this format for MultipleParts only, Repeats done in the standard way!
All tool changes forced to take place at machine home.
CRCOff on last line feature in ToolPath.
So, if the last feat is not a line feat the CRCOff is called same as usuall.
Added drill cycles G74 & G89.
Added spaces between codes.
Changed formats do that zero is output "0" instead of "0."
Deleted WFO1 from CloseMP
Jim Radcliffe}

{6/7/94
Modified: Mazatrol M32 Mxxx.81.4
Moved ToolComment$ to OpToolID line in FirstOperation and NewTool.
Added OperationComment$ to beginning of subprogram.
Moved ProgramName$ off the ProgID1 line.
Jim Radcliffe}

{8/4/94
Modified: Mazatrol M32 M663.81.5
For: Walker
Moved CoolOn.
Added OperationIDComment to begining of sub.
Added block delete to all Multiple Parts sub calls after the first one.
Jim Radcliffe}

{8/17/94
Modified: Mazatrol M32 M663.81.6
For: Walker
Moved DoEndOpPS call.
Deleted Tool Change at end of program.
Added DoToolComment call to StartSub sub.
Jim Radcliffe}

{12/14/94
Modified: Mazatrol M32 M663.81.7
For: Walker
All output is output as MultipleParts ExitClearancePlane WorkFixtureOffsets.
Added logic to handle if MultipleParts was not selected.
Corrected NoNest checks so everything else is output long hand.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(Retract#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Recall#,5)
FORMAT(Tag#,5)
FORMAT(PartsLess1#,5)
FORMAT(Recall#,5)
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoToolComment:
IF UseComments?
IF ToolComment?
'( ' ToolComment$ ' )'
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF SameTool? { it is called on OpToolID line for FirstOperation and NewTool }
DoToolComment EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
ASCII('13') EOL
SubID EOL
DoToolComment EOL
DoSubComment
IF UseComments? { output the operation comments of the first operation used in the sub }
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
END
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets? OR NOT MultipleParts?
NewWFO
EachWFO
SeqC SetWFO SubCall CallLab EOL
IncWFO
SetLineStrtChr('/')
NextWFO
SetLineStrtChr('')
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets? OR NOT MultipleParts?
SeqC EndSub EOL
CloseSub
ELSE
SetAbs
LoadFeat Num#('0') Num#('0') Num#('0')
SetAbsOrInc
SeqC AbsOrInc Rapid MoveXY EOL
SeqC Preset ' X[-1*#100] Y[-1*#101] Z[-1*#102]' EOL
SeqC EndSub EOL
CloseSub
SeqC Preset ' X[' PartsLess1# '*#100]' ' Y[' PartsLess1# '*#101]' ' Z[' PartsLess1# '*#102]' EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {NoNesting} {.72.1, this is for AutoCycles only}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
Seq IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
ELSE
EntryMove
ToolPath2
END
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
CutAutoCycle {NoNesting}
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
' G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
' G' NewWFO#
END
END
END
RETURN

Milling:
IF AutoCycle?
ToolPath {NoNesting}
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub: {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect? {.72.1, minor changes to entry}
SeqC FeedC StrtPosC EOL
SeqC ZInC FeedEntC EOL
ELSE
SeqC RapidC StrtPosC EOL
SeqC ZCP2C EOL
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
END
END
ToolPath
FinishSub1
END
NextRep
RETURN

ZonlyRepAutoCycle: {NoNesting}
ToolPath
RETURN

ZonlyRep: {NoNesting}
NewProg
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
NextCycle
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

SetTagValue:
TagInit
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { flag for output of G92s in program }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1 EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqC AbsOrInc DrillOff CRCOff Rapid EOL

{ Output Variable Comments }

IF MultipleParts? AND EquallySpacedOffsets?
'(*** Presets ***)' EOL
'(#100 = Preset X distance )' EOL
'(#101 = Preset Y distance )' EOL
IF NotEqual? PartShiftZ# Num#('0') AND OneToolAllParts? AND ExitClearancePlane?
'*** Warning *** Do not use a Z shift with Exit Clearance Plane selection' EOL
ELSE
'(#102 = Preset Z distance )' EOL
END
END
'(*** Work Offsets ***)' EOL
IF MultipleParts? AND WorkFixtureOffsets?
SetTagValue
NewWFO
EachWFO
TagInc '(#' Tag# ' = ' SetWFO ' X Work Offset )' EOL
TagInc '(#' Tag# ' = ' SetWFO ' Y Work Offset )' EOL
TagInc '(#' Tag# ' = ' SetWFO ' Z Work Offset )' EOL
IncWFO
NextWFO
ELSE
'(#103 = G54 X Work Offset )' EOL
'(#104 = G54 Y Work Offset )' EOL
'(#105 = G54 Z Work Offset )' EOL
END

{ Output Variables }

IF MultipleParts? AND EquallySpacedOffsets?
SeqC ' #100 = ' PartShiftX# EOL
SeqC ' #101 = ' PartShiftY# EOL
IF NotEqual? PartShiftZ# Num#('0') AND OneToolAllParts? AND ExitClearancePlane?
'*** Warning *** Do not use a Z shift with Exit Clearance Plane selection' EOL
ELSE
SeqC ' #102 = ' PartShiftZ# EOL
END
END
IF MultipleParts? AND WorkFixtureOffsets?
SetTagValue
NewWFO
EachWFO
SeqC TagInc ' #' Tag# ' = 0' EOL
SeqC TagInc ' #' Tag# ' = 0' EOL
SeqC TagInc ' #' Tag# ' = 0' EOL
IncWFO
NextWFO
ELSE
SeqC ' #103 = 0' EOL
SeqC ' #104 = 0' EOL
SeqC ' #105 = 0' EOL
END

{ Load Work Fixture Offsets }

IF MultipleParts? AND WorkFixtureOffsets?
SetTagValue
Save# Num#('1') Num#('1')
NewWFO
EachWFO
SeqC ' G10 L2 P' Recall# Num#('1') TagInc ' X#' Tag# TagInc ' Y#' Tag# TagInc ' Z#' Tag# EOL
Save# Num#('1') ADD# Recall# Num#('1') Num#('1')
IncWFO
NextWFO
ELSE
SeqC ' G10 L2 P1 X#103 Y#104 Z#105' EOL
END

IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq AbsOrInc DrillOff CRCOff Plane Rapid EOL
SeqC OpToolID DoToolComment EOL
SeqC ToolChng EOL
SeqC CoolOn EOL
DoOpComments
DoPostScript
SeqC WFOStuff StrtPos Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
CheckPass
SeqC OfstOn PreTool EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
IF NOT MultipleParts? { output all tools in a subtoutine }
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}

IF NOT MultipleParts? { output all tools in a subtoutine }
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC IncValue OfstOff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EOL
CloseMP
SeqC
END
SpinOff EOL
SeqC IncValue ' G28 X0 Y0' CoolOff EOL
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq AbsOrInc DrillOff CRCOff Plane Rapid EOL
SeqC OpToolID DoToolComment EOL
SeqC ToolChng EOL
SeqC CoolOn EOL
DoOpComments
DoPostScript
SeqC WFOStuff StrtPos Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
CheckPass
SeqC OfstOn PreTool EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
IF NOT MultipleParts? { output all tools in a subtoutine }
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue OfstOff SpinOff EOL
DoEndOpPS
SeqC ' M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue OfstOff EOL
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats? {NoNesting}
EachRep
SeqC AbsOrInc Rapid StrtPos EOL
END
GetCycle
SeqC
IF Tap? AND NOT CWSpindle?
' G74'
ELSE
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
END
FromCP StrtPos ZDepth RLevel Dwell Peck
IF PeckChipBreaker?
' D' Retract#
END
FeedEnt EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff ZCP3 EOL
IF Repeats? {NoNesting}
NextRep
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF NOT MultipleParts? { output all tools in a subtoutine }
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC IncValue OfstOff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EOL
CloseMP
SeqC
END
SpinOff EOL
SeqC IncValue ' G28 X0 Y0' CoolOff EOL
DoEndOpPS
IF ProgStop?
SeqC ' M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END