{Change Comments ***********************************************************}

{2/21/90, Updated: Fanuc 10T MS [+] L004.53 to .69.3 format, JR}
{7/18/90, Updated: Fanuc 10T MS [+] L004.69 to .69.7 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/28/91
Modified: Fanuc 10T MS [+] L004.71.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{08/05/91
Updated: Fanuc 10T MS [+] L004.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{7/11/95, Updated Fanuc 10T MS [+] L004.82 to .85 format, JR}

{10/10/95
Changed name to Centurian V
TH}

{16Apr98
Original: Centurion V L386.85
Created: Centurion 5T [WM] Lxxx.85
For: Weaver Manufacturing
Changes made per: Taylor Jenkins
New Post _FIRST DRAFT_ per customers Manual
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added FORMAT# 8 in Prog Numeric Format Definitions
Added Formatting for CycleStartXDia#, CycleStartZ#, ATAN#, DIV#, FeedTapIPR#,
SpringPasses#, Taper#, LastCutXRadius#, RunInX#, RunOutX#, RunInZ#, RunOutZ#
Deleted Formatting for FeedIPR#
Moved ToolTypeComment to NewTool
Moved OpToolID LatheOffset CoolOn from AppMove to FirstOp and NewTool
Changed FormatArc to output I,J Arcs with MoveXC MoveZC on the same line
Changed SeqLab to SeqLabC in ToolPath to avoid forcing a Line number when CannedCycle? is TRUE
Rewrote FirstOp and NewTool per customers Manual
Added Custom G71 and G72 Canned Cycles
Added Custom G81, G82 and G83 Drill Cycles
Added Custom G84 Tap Cycle
Added Custom G76 Thread Cycle
Deleted IF Drilling? AND Tap? Booleans in ToolPath and at the End of the Common Point
Moved DrillOff to the end of IF Drilling?
Deleted Untool at End of Prog
Deleted OpToolID '00' at End of Prog
Moved SpinOff to a seperate line at End of Prog
Charles Winston}

{27Apr98
Original: Centurion V L386.85
Created: Centurion 5T [WM] L721.85
For: Weaver Manufacturing
Changes made per: Taylor Jenkins
Added Literal 'U0.W0.' element to RoughContour Canned Cycle as X and Z "FinishStock",
I and K are used for X and Z "RoughStock". Gibbs system may have been able to, but
I dont believe Virtual can supply seperate Rough and Finish stock values.
Charles Winston}

{4/27/98,

Changes to "Form":

1. Under Turn Rough - OD/ID, changed Depth of Cut (D) format to ####.####;0.
and checked Rad. to X Stock Left (I).
2. Under Turn Rough - Face, changed Depth of Cut (D) format to ####.####;0.
and checked Rad. to X Stock Left (I).
3. Under Lathe Drill Cycles for G81 & G82, changed ;0 to ;0. at format.
4. Under Lathe Drill Cycles, added Bore same as FI-RO but G85.
Added Peck Full Retract same as Peck Partial Retract.

Changes to "Prog":

1. Added FORMAT to SPX# and SPZ#.
2. Added FORMAT #9 and changed ATAN# and DIV# to be #9.
3. Under canned cycles Threading, added a check to avoid division by 0 and changed
Q to be 360 div by number of starts.
4. Under canned cycles Drilling, made few changes.
5. Removed the motion to StrtPos before RoughPatternShift & RoughContour cycles.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '##'
#9 = '###.###;0.' {Added - JHE}

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(FirstMoveEPZ#,2)
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(ATAN#,9) {Changed from 2 - JHE}
FORMAT(DIV#,9) {Changed from 2 - JHE}
FORMAT(FeedTapIPR#,2)
FORMAT(Taper#,2)
FORMAT(LastCutXRadius#,2)
FORMAT(CycleStartX#,2)
FORMAT(RunInX#,2)
FORMAT(RunOutX#,2)
FORMAT(RunInZ#,2)
FORMAT(RunOutZ#,2)
FORMAT(SPX#,2) {Added - JHE}
FORMAT(SPZ#,2) {Added - JHE}
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(CalcEPRPM#,6)
FORMAT(SpringPasses#,6)
FORMAT(Tag#,6)
FORMAT(RapidF#,7)
FORMAT(Tool#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF ArcIJFormat?
ArcIJC MoveXC MoveZC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
ELSE
IF CannedCycle?
SeqLabC
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
SeqLab OpToolID LatheOffset EOL
SeqLabC 'G98' EOL
SeqLabC Preset Home MaxRPM EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
EOL
SeqLabC SpinOn EOL
SeqLabC CoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC NewHome EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLabC 'G40G501G550G569G80' SpinOff CoolOff EOL
SeqLabC 'P268=' Tool# EOL
SeqLabC ToolChng
IF ToolTypeComment?
' ( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )'
END
EOL
SeqLab OpToolID LatheOffset EOL
SeqLabC 'G98' EOL
SeqLabC Preset Home MaxRPM EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
EOL
SeqLabC SpinOn EOL
SeqLabC CoolOn EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC 'P117=0' EOL
{SeqLabC Rapid StrtPos EOL} {Removed - JHE}
SeqLabC LCycle 'U0.W0.' XStkLeft ZStkLeft CutDepth 'R0.' 'PÅ‚' Tag# 'Q²' Tag# EOL
'>' Tag# EOL
SeqLab ' ' EOL
SeqLabC StepMove StrtPos EOL {Added - JHE}
{IF ApproachFace? {Removed next 7 lines - JHE}
SeqLabC StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLabC StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END }
ELSE
IF RoughPatternShift?
{SeqLabC Rapid StrtPos EOL} {Removed - JHE}
SeqLabC LCycle XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate 'PÅ‚' Tag# 'Q²' Tag# EOL
'>' Tag# EOL
SeqLab ' ' EOL
SeqLabC Rapid StrtPos EOL
END
END
ToolPath
SeqLab ' ' EOL
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqLabC 'P103=' RunOutZ# EOL
{Added this check to avoid division by 0 - JHE}
IF Equal? RunOutX# Num#('0')
SeqLabC 'P104=90.' EOL
ELSE
SeqLabC 'P104=' ATAN# DIV# RunOutZ# RunOutX# EOL
END
SeqLabC 'P130=' LastCutXRadius# EOL
SeqLabC 'P131=' SpringPasses# EOL
SeqLabC Rapid StrtPos EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdLead
'Q' DIV# Num#('360') ThreadStarts# {Added this line - JHE}
CutDepth ToolAngle CutMethod ThrdHeight EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC 'G99' EOL { Set Feed Per Rev }
SeqLabC LCycle 'F' FeedTapIPR#('1') 'G38R' CycleStartZ# ZDepth EOL
ELSE
IF Peck?
SeqLabC LCycle FeedRate 'G38R' CycleStartZ# ZDepth Peck Retract EOL
ELSE
SeqLabC LCycle FeedRate 'G38R' CycleStartZ# ZDepth Dwell EOL
END
END
SeqLabC DrillOff EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC FirstHome EOL
SeqLabC SpinOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END