{Change Comments ***********************************************************}

{2/11/93
Updated: Heid TNC 155 M281.81.2m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Added Program2# to Format#5.
Added SaveProgNum2 to setup and initializations.
Changed ProgramName$ to Program# at FirstOperation.
Deleted literal 'Z' from 'BLK FORM 0.1' at FirstOperation.
Added 6 blocks of Tool Change sub at FirstOperation.
Added call to Tool Change sub at NewTool and end of Prog.
Deleted ToolChangeAtHome output at end of Prog.
Changed literal ' STOP M02' to ' L R F M02' at end of Prog.
Changed ProgramName$ to Program2# at end of Prog.
Added Flag(1) to output ArcFeat as LineFeat IF LTEqual? ArcR# Num#(.002mm) at ToolPath.
DWB}

{2/23/93
Updated: Heid TNC 155 [PB] M550.81.2m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Deleted SpeedRPM# from FORMAT Definitions.
Added IF UseComments? at SubWarning.
Changed SetMaxRPM from 10000 to 3000 at setup and initializations.
Added SetProgNum('1') at setup and initializations.
Changed Program# to Program2# at FirstOperation.
Added literal 'Z' to 'BLK FORM 0.1' at FirstOperation.
This was deleted per Mikaels instructions of 2/11/93, he admitted his mistake.
Deleted literal 'R F' on block following CoolOff at FirstOperation.
Changed all occurances of TABLE(4001,SpeedRPM#,1) to Speed.
Deleted Table from Form Resources.
Added literal 'ETX', End of Transmission at end of Prog.
DWB}

{3/2/93
Updated: Heid TNC 155 [PB] M550.81.3m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Changed IF LTEqual? ArcR# Num#('.002') to IF LessThan? ArcR# Num#('.02') at ToolPath ArcFeat.
Changed literal 'ETX' to ASCII('3') at end of Prog.
DWB}

{3/2/93
Updated: Heid TNC 155 [PB] M550.81.4m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Changed FORMAT for ClearancePlane2# from Ä…####0.000 to Ä…*####0.000.
DWB}

{12/3/93
Modified: Heid TNC 155 [PB] M550.81.5m
To: Heid TNC 155 [PB] M550.81.6m
Fixed the RestoreScale function to work with both english and metric parts. Also removed
unneeded setscale commands and replaced them with math ( number ) commands.
Forced all drilling parameter values ( depth, clearance, peck, etc. ) to be
negative.
[cwh]}

{4/4/96
Updated: Heid TNC 155 [PB] M550.81.6m
For: Fructus/Pharmacia Biosensors
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.07/Compost 4.21.34.1/1.0a
Changes made per Mikael Bagge of Fructus.
Updated for Catalyst v3.0 per Fanuc 6M M001.89m Format.
This post was updated using Heid TNC 155 [EMC] M612.85m.
DWB}

{4/4/96
Copied: Heid TNC 155 [PB] M550.89m
Created: Heid TNC 425 [HPM] M972.89m
For: Fructus/HP Mekaniska
Machine: BridgePort VMC 760
Control: Heidenhain 425
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.07/Compost 4.21.34.1/1.0a
Changes made per Mikael Bagge of Fructus.
Changed FORMAT for Address M from 00 to #0 in Mach Spec Default Formats Dialog.
Changed FORMAT for Address S from ####.###;0. to ###0 in Mach Spec Default Formats Dialog.
Deleted space following Address S for Spindle Speed Address in Mach Spec Strings 2 Dialog.
Added M6 to Change Tool in Mach Spec Commands 4 Dialog.
Changed #7 from ###0 to +###0 at Prog Numeric Format Definitions.
Changed ABS# from FORMAT#6 to FORMAT#4 at Prog Numeric Format Definitions.
Changed ClearancePlane2# from FORMAT#6 to FORMAT#4 at Prog Numeric Format Definitions.
Changed Peck# from FORMAT#4 to FORMAT#6 at Prog Numeric Format Definitions.
Added NextTool# to FORMAT#5 at Prog Numeric Format Definitions.
Changed literal ' F9999' to ' F MAX' at RF sub.
Added CYCL7 sub.
This sub is called three times at FirstOperation.
Added SetProgNumTo10 sub.
This sub increments Program# to 10.
Customer requested that all subs output starting with 11.
Commented out OpenSub at StartSub.
Commented out CloseSub at at FinishSubG92, CloseMP, AutoCycCutSub2, ZonlyRepAutoCycle, ZonlyRep
and IF Drilling.
Customer requested that SubPrograms be included as part of main program.
Made numerous changes to beginning of output at FirstOperation and NewTool.
Replaced EachTool/NextTool loop with three calls to CYCL7 and one call to SetProgNumTo10.
Deleted 'LBL 1' block at FirstOperation and NewTool.
Deleted 'TOOL CALL 0' block at FirstOperation.
Deleted SpinOff block at FirstOperation.
Deleted CoolOff block at FirstOperation.
Deleted 'M92' block at FirstOperation.
Deleted 'LBL 0' block at FirstOperation.
Added literal ' L M26', Chip Conveyor On Code at FirstOperation.
Moved 'TOOL CALL' block up at FirstOperation and NewTool.
Added ToolChng block at FirstOperation and NewTool.
Added PreTool Def block at FirstOperation and NewTool.
Deleted 'CALL LBL 1 REP' block at NewTool.
Added CYCL DEF 17.x blocks for RigidTap Cycle at IF Drilling.
Deleted ABS# from ClearancePlane2# block at IF Drilling.
Deleted ABS# from ZDepth# block at IF Drilling.
Deleted ABS# from Peck# block at IF Drilling.
Added 'L X-400. Y+160. R0' block at end of Prog.
Added 'TOOL CALL' FIRST Tool# block at end of Prog.
Added ToolChng block at end of Prog.
DWB}

{5/21/96
Updated:
Modified:
Copied: Heid TNC 425 [HPM] M972.89m
Created: Heid TNC 425 [HPM] M053.89m
For: Fructus/Pharmacia Biosensor
Machine:
Control:
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Changes made per Mikael Bagge of Fructus.
Customer requested Coordinate FORMAT changes.
Changed FORMAT#1 from '####0.000' to '####0.###;0' at Prog Numeric Format Definitions.
Changed FORMAT#2 from '###.###;0.' to '##0.###;0' at Prog Numeric Format Definitions.
Changed FORMAT#3 from '*###.###;0.' to '*##0.###;0' at Prog Numeric Format Definitions.
Changed FORMAT#4 from 'Ä…####0.000' to 'Ä…####0.###;+0' at Prog Numeric Format Definitions.
Changed FORMAT#6 from 'Ä…*####0.000' to 'Ä…*####0.###;+0' at Prog Numeric Format Definitions.
Modified literal at ckCRCOff, StartSub, StdSub, FinishSubG92, OpenMP, CloseMP, FormatArc,
ToolPath, AutoCycCutSub2 and ZonlyRep subs, and FirstOperation and NewTool.
Customer requested deletion of padded spaces.
Modified DoL, Space, XYZSpace, DoR0 and DoM subs.
Customer requested deletion of CYCL7 sub.
Deleted sub and 3 calls to same at FirstOperation.
Deleted SetProgNumTo10 sub.
Replaced with SetProgNum command at setup and initializations
Customer requested Tool Comment at Tool Call block.
Added ToolTypeComments sub, called from FirstOperation and NewTool.
Deleted ToolChng block at FirstOperation and NewTool.
Deleted PreTool at FirstOperation and NewTool.
Changed Drill Cycle Labels at IF Drilling.
Changed output blocks at end of Prog.
Including ASCII(3)
DWB}

{7/16/96
Initial: Heid TNC 425 [PB] M053.89m
Created: Heidenhain 407 SHW Mxxx.89
ForUser: Rampf Molds Industries, Inc.
Control: Heidenhain 407
Machine: SHW
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New processor per notes and marked up readout from Josef Ott
Deleted sequence from BEGIN PGM line at beginning of program.
Changed Program2# to ProgramName$ on BEGIN PGM line at beginning of program.
Changed Program2# to '*' on END PGM line at end of program.
Changed comments to begin with semicolon instead of wraped in parentheses.
Changed MovesComment to read MILLIMETERS instead of METERS.
Added tool definition list to beginning of program.
Deleted TOOL CALL 0 from end of program.
Modified Drill Parameters:
x.1 describes the surface to be drilled incrementaly from current position.
Changed ClearancePlane2# to CalcCP2FmSurf#
x.2 describes the depth to be drilled incrementaly from the surface.
Changed ZDepth# to CalcZFmSurf#
x.3 describes the incremental peck depth incrementaly from the surface.
Changed SetInc ZDepth# SetAbs to CalcZFmSurf#
Feeding begins from the current position, to retract to ZCP1 we need to:
1. position Z to ZCP1 without M
2. Position XY
3. Position Z to ZCP2 with M99 to execute cycle
Disabled multiple drill depths!
ZMoves in drilling would output as a steps instead of differing drill depths as rendered!
Jim Radcliffe}

{9/18/96
Initial: Heidenhain 407 SHW M060.89
Created: Heidenhain 407 SHW M060.89.1m
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Modified per fax from Josef Ott
Added ToolChng at New Tool.
Jim Radcliffe}

{7/3/97
Initial: Heidenhain 407 SHW M060.89.1m
Created: Heidenhain 415 BR Mxxx.89m
ForUser: Scott Technology
Control: Heidenhain 415 BR
Machine: ????
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: Modified per email from Keith McIver
Deleted TOOL DEF tool list from beginning of program.
Added ToolChng to first operaion.
Moved ToolChng in NewTool to after TOOL CALL line.
Jim Radcliffe}

{7/25/97,
Initial: Heidenhain 415 BR MX50.89m
Made: Heidenhain TNC 415 [ST] Mxxx.89m
For: Scott Tool
made output of FeedRates modal,
deleted output of Program Name Comment,
MPK }

{Prog Numeric Format Definitions *******************************************}

#1 = '####0.###;0'
#2 = '##0.###;0'
#3 = '*##0.###;0'
#4 = 'Ä…####0.###;+0'
#5 = '#######0'
#6 = 'Ä…*####0.###;+0'
#7 = '+###0'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,1) {.72}
FORMAT(ABS#,4)
FORMAT(XStockMin#,4)
FORMAT(XStockMax#,4)
FORMAT(YStockMin#,4)
FORMAT(YStockMax#,4)
FORMAT(ZStockMin#,4)
FORMAT(ZStockMax#,4)
FORMAT(HomeX#,4)
FORMAT(HomeY#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(CalcZFmSurf#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnShiftPX#,4)
FORMAT(OriginUnShiftPY#,4)
FORMAT(OriginUnShiftPZ#,4)
FORMAT(OriginUnShiftRX#,4)
FORMAT(OriginUnShiftRY#,4)
FORMAT(OriginUnShiftRZ#,4)
FORMAT(DIV#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(TLDia#,4)
FORMAT(TLLength#,4)
FORMAT(TLNum#,5)
FORMAT(TrackZNO#,4)
FORMAT(CallMasterNum#,5)
FORMAT(Program2#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NextTool#,5)
FORMAT(Parts#,5) {.72}
FORMAT(Peck#,6)
FORMAT(CalcCP2FmSurf#,6)
FORMAT(FeedEntry#,7)
FORMAT(RapidF#,8)

{Special Subs **************************************************************}

DoL:
' L'
RETURN

DoZL:
DoL
RETURN

Space: { 10 Spaces }
{' '}
RETURN

XYZSpace:
{' '} Space
RETURN

XYSpace:
Space Space
RETURN

ZSpace:
Space Space Space
RETURN

IXYZSpace:
Space
RETURN

IXYSpace:
Space Space
RETURN

IZSpace:
Space Space Space
RETURN

DoR0:
IF NOT Flag?('3') { ArcFeat }
{' '}
END
IF Flag?('2') { CutterRadiusCompensation }
IF CRCleft?
' RL'
ELSE
' RR'
END
ELSE
' R0'
END
RETURN

RF: { RapidF }
RapidF# ' F MAX'
RETURN

DoM:
{' M'}
RETURN

ckCRCOff:
IF Flag?('2') { CRCOn }
SetFlagF('2')
SeqLab DoL ' IX+0 IY+0' IXYSpace DoR0 RF DoM EOL
END
RETURN

CheckCoolOn:
IF CoolOff?
DoM
ELSE
CoolOn
END
RETURN

CheckCoolOff:
IF CoolOff?
DoM
ELSE
CoolOff
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? { CAM file is in English, tools and tool path }
SetScale('25.4') { change to Metric, this is a Metric post }
ELSE
SetScale('1')
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

ToolTypeComments:
IF ToolTypeComment?
SetScale('1')
' ; ' ToolType$ ' ' ToolDiameter# EOL
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
SeqLab DoZL
IF AutoCycle? {implies incremental}
' IZ' SPZ# IZSpace
ELSE
ZIn ZSpace
END
DoR0
IF FeedEntry?
FeedEnt
ELSE
RF
END
DoM EOL
RETURN

StartSub:
{OpenSub}
DoSubComment
SeqLab ' LBL ' Program# EOL
RETURN

SubWarning:
IF UseComments?
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# ' REP ' Repeats# ' / ' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
END
DoM EOL
END
ckCRCOff
RETURN

FinishSubG92: {part 2}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' RepeatX# EOL
SeqLab ' CYCL DEF 7.2 IY' RepeatY# EOL
SeqLab ' CYCL DEF 7.3 IZ' RepeatZ# EOL
SeqLab ' LBL 0' EOL
{CloseSub}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftRX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftRY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftRZ#('0') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# ' REP ' Parts# ' / ' Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftY# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftZ# EOL
SeqLab ' LBL 0' EOL
{CloseSub}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPZ#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XMove? OR YMove? OR ArcFeat?
' IX' EPX# ' IY' EPY#
IF ZMove?
' IZ' EPZ# IXYZSpace
ELSE
IXYSpace
END
ELSE
IF ZMove?
' IZ' EPZ# IZSpace
END
END
ELSE
IF XMove? OR YMove? OR ArcFeat?
MoveX MoveY
IF ZMove?
MoveZC XYZSpace
ELSE
XYSpace
END
ELSE
IF ZMove?
MoveZC ZSpace
END
END
END
RETURN

FormatArc:
DoAbsOrInc
SeqLab ' CC'
IF AutoCycle? OR NOT AbsValue? {implies incremental}
' IX' ArcI# ' IY' ArcJ#
ELSE
ArcIJ
END
EOL
SeqLab ' C' CheckMove
IF ArcCW?
' DR-' CWArc {no output}
ELSE
' DR+' CCWArc {no output}
END
SetFlag('3')
DoR0
SetFlagF('3')
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF LastFeat?
SetFlagF('2') { CRCOff }
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOn }
END
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

FormatLine:
IF ZMove? AND NOT XMove? AND NOT YMove?
DoZL
ELSE
DoL
END
DoAbsOrInc CkCRC CheckMove DoR0
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF FirstFeat?
SeqLab ' CYCL CALL' XYZSpace ZSpace DoM EOL
ELSE
Rapid {no output}
IF AutoCycle?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF ' M99' EOL
ELSE
IF RetractToCP1?
SeqLab DoZL ZCP1 ZSpace DoR0 RF DoM EOL
SeqLab DoZL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
SeqLab DoZL ZCP2 ZSpace DoR0 RF ' M99' EOL
ELSE
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF ' M99' EOL
END
END
END
IF AutoCycle?
SeqLab ' CALL LBL ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
Rapid {no output}
IF XMove? OR YMove? OR ZMove?
SeqLab FormatLine RF DoM EOL
END
ELSE
IF LineFeat?
Feed {no output}
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRateC DoM EOL
DecelMove2
END
SeqLab FormatLine DecelFeed DoM EOL
ELSE
SeqLab FormatLine FeedRateC DoM EOL
END
END
ELSE
IF ArcFeat?
SetStatusOff
IF Metric? AND LessThan? ArcR# Num#('.02')
SetFlag('4')
ELSE
IF NOT Metric? AND LessThan? ArcR# Num#('.0007874015748031') { .02 Ö 25.4 }
SetFlag('4')
END
END
SetStatusOn
IF Flag?('4')
SeqLab FormatLine FeedRateC DoM EOL { StdLine }
ELSE
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeedC DoM EOL
DecelMove2
END
FormatArc DecelFeed DoM EOL
ELSE
FormatArc ArcFeedC DoM EOL
END
NEXTQuadrant
END
SetFlagF('4')
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
{CloseSub}
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
FeedEnt
ELSE
RF
END
DoM EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle: {.86}
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed {no output}
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# IXYSpace DoR0 FeedEnt DoM EOL
SetAbs
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEntC DoM EOL
ELSE
IF NOT FirstCycle?
Rapid {no output}
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# IXYSpace DoR0 FeedEnt DoM EOL
SetAbs
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
ELSE
IF FeedEntry?
IF NOT FirstCycle?
Rapid {no output}
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
END
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
ELSE
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' CALL LBL ' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
Rapid {no output}
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
DoM EOL {.69}
END {.69}
SeqLab ' LBL 0' EOL
{CloseSub}
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
FeedEnt
ELSE
RF
END
DoM EOL
END
IF FeedConnect?
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEntC DoM EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
Rapid {no output}
SeqLab DoZL ZCP2PlusIncC ZSpace DoR0 RF DoM EOL
END
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
SeqLab ' CALL LBL ' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
{CloseSub}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3000')
SaveProgNum2
SetProgNum('10')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOff }
SetFlagF('3') { ArcFeat }
SetFlagF('4') { OutPut ArcFeat as StdLine when ArcR# LessThan Num#('.02mm') }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts? AND WorkFixtureOffsets?
'; *** WARNING ***' EOL
'; THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS.' EOL
'; PLEASE SELECT EQUALLY SPACED OFFSETS.' EOL
'; *** WARNING ***' EOL
END

EachOp {Start of post processing *********************}
IF FirstOperation?
'BEGIN PGM ' ProgramName$ ' MM' EOL
IF ToolChangeAtHome?
SetHome
END
SeqLab ' BLK FORM 0.1 Z X' XStockMin# ' Y' YStockMin# ' Z' ZStockMin# EOL
SeqLab ' BLK FORM 0.2 X' XStockMax# ' Y' YStockMax# ' Z' ZStockMax# EOL
IF UseComments?
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ABSOLUTE MILLIMETERS' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE' EOL
END
END
SetAbs
Plane {no output}
OpenSub
RestoreScale
SeqLab ' TOOL CALL ' Tool# ' Z ' Speed ToolTypeComments EOL
SeqLab DoL ToolChng EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab DoL StrtPos ' ' DoR0 RF DoM EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab DoL ZCP1 ZSpace DoR0 RF SpinOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END

{Start new Operation}

SetAbs
Plane {no output}
DoOpComments
DoPostScript
SeqLab ' TOOL CALL ' Tool# ' Z ' Speed ToolTypeComments EOL
SeqLab DoL ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab DoL StrtPos ' ' DoR0 RF DoM EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END

{Start new Operation}

GetStartOfSameTool
SetAbs
Plane {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
END
END {common point for all operations}
IF Milling?
SeqLab DoZL ZCP2 ZSpace DoR0 RF CheckCoolOn EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO? {.81}
FeedEnt
ELSE
RF
END
END
CheckCoolOff EOL
END
ckCRCOff
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
SeqLab DoZL ZCP2 ZSpace DoR0 RF CheckCoolOn EOL
GetCycle
IF RigidTap?
SeqLab ' CYCL DEF 17.0 FAST GAENGNING' EOL
SeqLab ' CYCL DEF 17.1 AVST ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 17.2 DJUP ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 17.3 V.TID 0' EOL
ELSE
IF Tap?
SeqLab ' CYCL DEF 2.0 G€NGBORRNING' EOL
SeqLab ' CYCL DEF 2.1 AVST ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DJUP ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 2.3 V.TID 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SET UP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
Peck#
ELSE
CalcZFmSurf#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
END
IF CallMasterOp? AND NOT RetractToCP1?
SeqLab ' CALL LBL ' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp? AND NOT RetractToCP1?
NewMasterProg
SeqLab ' CALL LBL ' Program# EOL
StartSub
ToolPath
SeqLab ' LBL 0' EOL
{CloseSub}
ELSE
ToolPath
END
END
{SetDrillEndOpZ}
Rapid {no output}
SeqLab DoZL ZCP3 ZSpace DoR0 RF CheckCoolOff EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab ' L' SpinOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
Rapid {no output}
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
Post
SeqLab ' L M2' EOL
SeqLab ' END PGM ' '*' ' MM' EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END