{Change Comments ***********************************************************}

{7/7/95, Updated for Catalyst v2.20 per Fanuc 6M M001.10 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{7/12/96
Modified: Fanuc 6M M001.12
Created: Fanuc 6M M001.13.1
For: Gibbs & Associates
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Updated to .13 version.
DWB}

{10/2/96, updated to .14 format per Fanuc 6M (FW) B001.14, MPK}

{11/22/96
Versions: Catalyst v3.23C/Compost 4.21.37/v1.0b1
.14 Additions:
Deleted Flag(2) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}

{2/25/97
Modified: Fanuc 6M M001.14m
Created: Fanuc 6M M001.15m
For: Gibbs & Associates
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
DWB}

{5/13/97
Copied: Fanuc 6M M001.15m
Created: Dekel Maho VMC 600 MY97.15mż1
For: Indramat
Machine: Dekel Maho VMC 600
Control: MT-CNC/MTC-200
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Ken Cottrell of Indramat, manual, faxes and phone conversation.
FORM Changes:
Changed Use Absolute Arc Centers to TRUE in Compost Arcs Dialog.
Changed I-J Maximum Arc Radius from 99.99990 to 100.00000 in Compost Arcs Dialog.
Changed Start Comment Label from ( to ; in Compost Comments Dialog.
Deleted ) from End Comment Label in Compost Comments Dialog.
Changed Tool Length Offset Enable from G43 to G48 in Compost Tool Offsets Dialog.
Changed Tool Length Offset Cancel from G28 to G47 in Compost Tool Offsets Dialog.
Changed FORMAT for Address F from '###.##;0.' to '#####.##;0.' in Compost Default Formats Dialog.
PROG Changes:
Changed FORMAT#6 from '####^##0' to '###.#;0.' at Prog Numeric Format Definitions.
Added FORMAT#7, '#' at Prog Numeric Format Definitions.
Added Recall# to FORMAT#4 at Prog Numeric Format Definitions.
Added ADD# to FORMAT#4 at Prog Numeric Format Definitions.
Added RapidF# to FORMAT#7 at Prog Numeric Format Definitions.
Changed all Comments from parentheses to semi-colon, i.e. from () to ;.
Modified handling of SubPrograms.
Changed SubID to '.SUB' Program# at StartSub.
Changed SubCall CallLab RepLab RepCycs to 'BSR.SUB' Program# at StdSub.
Sandwiched between EachRep/NextRep Loop.
Changed SubCall CallLab RepLab OnePart to 'BSR.SUB' Program# at OpenMP.
Changed SubCall CallLab RepLab Parts to 'BSR.SUB' Program# at OpenMP.
Sandwiched between EachPart/NextPart Loop.
Changed SubCall CallLab to 'BSR.SUB' Program# at ToolPath PointFeat AutoCycle,
ZonlyRepAutoCycle, and ZonlyRep.
Changed EndSub to 'RTS' at FinishSubG92, two places at CloseMP, AutoCycCutSub2,
ZonlyRepAutoCycle, and ZonlyRep.
Changed Canned Drill Cycles to Manual Drill Cycles.
Deleted contents of DoDrillAbsOrInc.
Added DoPeck sub.
Added DrillFeature sub.
Replaced contents of ToolPath PointFeat Drilling with call to DrillFeature sub.
Deleted CallMasterOp in IF Drilling at OpGuts.
Deleted MasterOp in IF Drilling at OpGuts.
Added Var(8) for Manual Peck Cycle at ProgStart.
Deleted literal 'G80' from SafeStart block at FirstOp1.
Deleted contents of ckCRCNum.
Deleted ProgID1 at FirstOperation.
Deleted ToolChng at FirstOp1 and NewToolOp3.
Changed OfstOn to 'G48' ZCP1 at FirstOp3, NewToolOp5 and two places at SameToolOp3.
Changed OfstOff to 'G47' LAST ZCP1C at NewToolOp1 and two places at SameToolOp1.
Deleted SafeStart block at NewToolOp3.
Added PlaneC to WFOStuff block at NewToolOp4.
Changed OfstOff to 'G47' ZCP1C at End1.
DWB}

{5/22/97
Modified: Deckel Maho Indramat MY97.15m
Created: Deckel Maho Indramat MY97.15.1m
For: Indramat
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Ken Cottrell and Karl Rapp of Indramat.
Rules require that integer coordinate values do not require a decimal point.
Rules require that if Decimal is output, one decimal place to the right must be stated.
FORM Changes:
Changed Address F from #####.##;0. to #####.0#;0 in Compost Default Formats.
Changed Addresses A, B, C, I, J, K, Q, R, X, Y and Z from #####.###;0. to #####.0##;0 in Compost
Default Formats.
Added Address Spaces in all relevant Compost Dialogs.
Changed First Work Fixture Offset from G54 to G0 in Compost Origins and Values Dialog.
PROG Changes:
Changed FORMAT#2 from #####.###;0. to ###.0##;0 at Prog Numeric Format Definitions.
Changed FORMAT#3 from *#####.###;0. to *###.0##;0 at Prog Numeric Format Definitions.
Changed FORMAT#4 from #####.###;0. to #####.0##;0 at Prog Numeric Format Definitions.
Changed FORMAT#6 from ###.#;0. to ###.0#;0 at Prog Numeric Format Definitions.
Added FORMAT#8, ####.0###;0 at Prog Numeric Format Definitions.
Added MUL# to FORMAT#5 at Prog Numeric Format Definitions.
Deleted CallMasterNum# from FORMAT#5 at Prog Numeric Format Definitions.
Added FeedTapIPR# to FORMAT#8 at Prog Numeric Format Definitions.
Added Address Spaces to all relevant Prog Literals.
Control supports standard G54 to G59 WorkFixtureOffsets, but each one has a sub WFO from O0 to O9.
for a total of 60 WFOs.
Sub WFO must be output on separate block.
Form contains range from G0 to G59.
Added formulas to extract both G54 to G59 and O0 to O9 parameters from this range.
Basically, the number is divided by 10 and then the integer is extracted and added to 54 to come
up with the G54 to G59 range.
The decimal portion is them multiplied by 10 to come up with the O0 to O9 range.
Example:
55 � 10 = 5.5
5 + 54 = 59
.5 * 10 = 5
Result is G59 O5
Added Var(9) to store G54 to G59 range.
Added Var(10) to store O0 to O9 range.
Added GetWFONum sub to handle output for all types of programs.
Added WFONum# and ModWFONum# subs to handle formulas for normal WFO programs.
Added MPWFONum#, ModMPWFONum# and MPWFONum subs to handle formulas for MultiplePart WFO programs.
Changed WFO1 to literal ' G59' at WFOStuff and CloseMP subs.
Changed '.SUB' Program# to SeqC ' .SUB_' Program# at StartSub sub.
Changed 'BSR.SUB' Program# to SeqC ' BSR .SUB_' Program# at StdSub, two places at OpenMP, ToolPath
PointFeat AutoCycle, ZonlyRepAutoCycle and ZonlyRep subs.
Added support of G63/G64 Rigid Tap and G65 Floating Tap Cycles.
Rigid Tap outputs G63 on InFeed block and G64 on OutFeed block.
G63 causes spindle to stop at end of move.
G64 leaves spindle turning at end of move.
FeedRate is expressed in distance per revolution.
Output of Speed and SpinOn is output on G63/G64 block.
Speed SpinOn is suppressed at normal FirstOperation, NewTool and SameTool occurances.
Added GetSpeed and ckSpeed subs to handle this.
GetSpeed is called from ckSpeed sub.
ckSpeed is called from FirstOp2, NewToolOp4 and two places at SameToolOp3 subs.
Deleted RapidF# from ToolPath PointFeat Dwell condition.
Dwell Feed is a non-modal, one shot command that does not affect the modal FeedRate.
Added support of G61, Exact Stop Before NC-block Transition with Lag Finishing command at ToolPath.
Forces Tool to catch up to control at a corner prior to processing the next feature.
Creates sharp corners.
Added support of G62, Block Transition with Lag Present command at end of ToolPath.
Cancels G61.
Deleted EOR EOL at InitOp and End3 subs.
Changed commented out ProgID1 to literal 'NC-PROGRAM # ' Program# at InitOp sub.
Rules state that SubRoutine and SubProgram IDs be in the range from 1 to 99.
Added SetProgNum('0') at InitOp sub.
Added ToolChng back in at FirstOp1 and NewToolOp3 subs.
Deleted literal 'G48', OfstOn command at FirstOp3, NewToolOp5 and SameToolOp3 subs.
Deleted literal 'G47', OfstOff command at NewToolOp1, SameToolOp1 and End1 subs.
Deleted support of NewToolOffset? boolean at SameToolOp1 and SameToolOp3 subs.
DWB}

{28/05/97 Changed the header and program name, also changed the end statment}

{6/6/97
Copied: Deckel Maho Indramat MY97.15.1m
Created: Deckel Maho Indramat MY97.15.2m
For: Indramat
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Al Martins.
Notes of changes made on 5/28/97:
Added following Header blocks at InitOp.
'%NPG:0:00:0:000' EOL
'!01.00' EOL
'#' EOL
'$' EOL
Changed 'NC-PROGRAM # ' Program# EOL to '*' ProgramName$ EOL at InitOp.
Deleted contents of IF UseComments? AND ProgramNameComment? condition at InitOp.
Deleted IF ProgramComment? condition at InitOp.
Combined OpToolID and ToolChng on one block at FirstOp1 and NewToolOp3.
Added following condition at FirstOp1 and NewToolOp3:
IF LastTool?
SeqC ' MFP' EOL
ELSE
SeqC PreTool ' MTP' EOL
END
Deleted SpinOff only output for NOT ToolChangeAtHome condition at NewToolOp2.
Added ` at NewToolOp3.
Deleted SpinOff only output for LAST ProgStop condition at SameToolOp1.
Changed SpinOff only block to SeqC ' T0 M6' EOL for NOT FIRST ToolChangeAtHome condition at End2.
Added SeqC ' PROGRAMMENDE' EOL block at End3.
Notes on changes made due to results of tests performed on changes made on 5/28/97:
Deleted empty IF UseComments? AND ProgramNameComment? condition at InitOp.
Deleted ELSE and SeqC EOL at NewToolOp2.
Deleted SeqC EOL at SameToolOp1.
Deleted ` at NewToolOp3.
This is the character created by the `~ key next to the 1 key on the keyboard.
The compiler did not catch this but should have because it was not a literal.
DWB}

{6/25/97
Modified: Deckel Maho Indramat MY97.15.2m
Created: Deckel Maho Indramat MY97.15.3m
For: Indramat
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Ken Cottrell of Indramat.
Customer requested Sequence Line Numbers that do not get reset to beginning value at start of
SubPrograms, and to have leading zero FORMAT.
Changed Sequence Label from N to N? in Compost General Info Dialog.
Changed FORMAT for Address N from ###0 to 0000 in Compost Default Formats Dialog.
Changed Seq/SeqC to SeqLab/SeqLabC throughout Prog.
Added Retag at end of Prog.
Moved SeqLabC ' PROGRAMMENDE' EOL block from after SeqLab EOP EOL to after Post2 command.
DWB}

{7/1/97
Modified: Deckel Maho Indramat MY97.15.3m
Created: Deckel Maho Indramat MY97.15.4m
For: Indramat
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Ken Cottrell of Indramat.
Moved SeqLabC ' PROGRAMMENDE' EOL block from after File Length Comments at End3.
Needed to add additional ReOpen and Close commands.
Moved Retag to be final command at End3.
DWB}

{05/13/98,
Initial: Deckel Maho Indramat MY97.15.4m
Created: Deckel Maho Indramat MY97.15.5m
For: Indramat

Changes to Prog:
1) End3 - Added SeqLabC to PROGRAMMENDE. Moved Retag to after this command.
CDH}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.0##;0'
#3 = '*###.0##;0'
#4 = '#####.0##;0'
#5 = '#######0'
#6 = '###.0#;0'
#7 = '#'
#8 = '####.0###;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Recall#,4)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(MUL#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)
FORMAT(FeedTapIPR#,8)

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

GetWFONum:
FORMAT(Recall#,5)
' G' Recall# Num#('9')
IF NotEqual? Num#('0') Recall# Num#('10')
EOL
SeqLabC ' O' Recall# Num#('10')
END
FORMAT(Recall#,4)
RETURN

WFONum#:
DIV# NewWFO# Num#('10')
RETURN

ModWFONum#:
SUB# WFONum# TRUNC# WFONum#
RETURN

WFONum:
Save# Num#('9') ADD# Num#('54') TRUNC# WFONum#
Save# Num#('10') MUL# Num#('10') ModWFONum#
GetWFONum
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
' G54' {WFO1}
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLabC ' .SUB_' Program# EOL { SubID }
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
SeqLabC ' BSR .SUB_' Program# EOL { SubCall }
NextRep
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC ' RTS' EOL { EndSub }
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

MPWFONum#:
DIV# SUB# PartNum# Num#('1') Num#('10')
RETURN

ModMPWFONum#:
SUB# MPWFONum# TRUNC# MPWFONum#
RETURN

MPWFONum:
Save# Num#('9') ADD# Num#('54') TRUNC# MPWFONum#
Save# Num#('10') MUL# Num#('10') ModMPWFONum#
GetWFONum
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC MPWFONum EOL { SetWFO }
END
SeqLabC ' BSR .SUB_' Program# EOL { SubCall }
IncWFO
NextWFO {simple NextPart}
ELSE
EachPart
SeqLabC ' BSR .SUB_' Program# EOL { SubCall }
NextPart
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC ' RTS' EOL { EndSub }
CloseSub
SeqLabC ' G54' EOL { WFO1 }
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC ' RTS' EOL { EndSub }
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
{ Not Supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('8') Peck# SPZ# { IF OldZ - Peck# > Depth }
Save# Num#('8') SUB# Recall# Num#('8') Peck# { Save#8 NewZ }
SeqLabC Feed ' Z' Recall# Num#('8') FeedEntC EOL { Move to NewZ }
Rapid
IF PeckFullRetract?
SeqLabC ZCP2 EOL { Retract Tool Full Out }
END
SeqLabC ' Z' ADD# Recall# Num#('8') Retract# EOL { Move to Retract Pos }
TrackZNO# ADD# Recall# Num#('8') Retract# { Update Status Register }
END
RETURN

DrillFeature:
SeqLabC RapidC MoveSXYC EOL
SeqLabC ZCP2C EOL
IF Peck?
Save# Num#('8') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
END
IF Tap?
IF RigidTap?
SeqLabC ' G63' MoveSZC ' F' FeedTapIPR#('1') Speed SpinOn EOL
SeqLabC ' G64' ZCP2C ' F' FeedTapIPR#('1') Speed InverseSpinOn EOL
ELSE
SeqLabC SpinOff EOL
SeqLabC ' G65' ' F' FeedTapIPR#('1') EOL
SeqLabC Speed SpinOn EOL
SeqLabC MoveSZC EOL
SeqLabC ZCP2C Speed InverseSpinOn EOL
SeqLabC ' G95' EOL
END
IF RetractToCP1?
SeqLabC Rapid ZCP1C EOL
ELSE
IF NOT LastFeat?
Rapid
END
END
ELSE
SeqLabC FeedC MoveSZC FeedEntC EOL
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
IF FIFO?
SeqLabC FeedC ZCP2C EOL
IF RetractToCP1?
SeqLabC RapidC ZCP1C EOL
END
ELSE
IF RetractToCP1?
SeqLabC RapidC ZCP1C EOL
ELSE
SeqLabC RapidC ZCP2C EOL
END
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC ' BSR .SUB_' Program# EOL { SubCall }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
DrillFeature
END
ELSE
IF FirstFeat?
SeqLabC ' G61' EOL { Exact Stop Before NC-block Transition with Lag Finishing }
END
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF LastFeat?
SeqLabC ' G62' EOL { Block Transition with Lag Present, cancels G61 }
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC ' RTS' EOL { EndSub }
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC ' BSR .SUB_' Program# EOL { SubCall }
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC ' RTS' EOL { EndSub }
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL
END
END
SeqLabC ' BSR .SUB_' Program# EOL { SubCall }
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC ' RTS' EOL { EndSub }
CloseSub
RETURN

GetSpeed:
IF FirstOperation? OR NewTool?
Speed SpinOn
ELSE
SpeedC
IF LAST ProgStop?
SpinOn
END
END
RETURN

ckSpeed:
IF Drilling?
GetCycle
IF NOT Tap?
GetSpeed
END
ELSE
GetSpeed
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
RapidF# { Forces FeedEntC }
ToolPath
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqLabC RapidC ZCP3C EOL
END
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('2540')
ELSE
SetMaxFeed('100')
END
Save# Num#('8') Num#('0') { PeckCycle }
Save# Num#('9') Num#('0') { G54 - G59 WFO value }
Save# Num#('10') Num#('0') { G54 - G59 O Address value }
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
'%NPG:0:00:0:000' EOL
'!01.00' EOL
'#' EOL
'$' EOL
'*' ProgramName$ EOL
'%NPG' EOL
SetProgNum('0')
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ ' MILLIMETERS' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqLab Plane CRCOff EOL
SeqLabC OpToolID ToolChng EOL
IF Lasttool?
SeqLabC ' MFP' EOL
ELSE
SeqLabC PreTool ' MTP' EOL
END
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqLabC WFOStuff EOL
SeqLabC ckSpeed EOL
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
RETURN

FirstOp3:
SeqLabC ZCP1 EOL { OfstOn }
SeqLabC CoolOn EOL
RETURN

NewToolOp1:
SeqLabC CoolOff EOL
SeqLabC LAST ZCP1C EOL { OfstOff }
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC Rapid Home SpinOff EOL
END
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqLab OpToolID ToolChng EOL
IF LastTool?
SeqLabC ' MFP' EOL
ELSE
SeqLabC PreTool ' MTP' EOL
END
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqLabC PlaneC WFOStuff EOL
SeqLabC ckSpeed EOL
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
RETURN

NewToolOp5:
SeqLabC ZCP1 EOL { OfstOn }
SeqLabC CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC LAST ZCP1C EOL { OfstOff }
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqLabC WFOStuff EOL
IF LAST ProgStop?
SeqLabC PlaneC AbsOrInc Rapid StrtPos ckSpeed EOL
SeqLabC ZCP1 EOL { OfstOn }
SeqLabC CoolOn EOL
ELSE
SeqLabC PlaneC AbsOrInc Rapid StrtPos ckSpeed EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
SeqLabC CoolOff EOL
SeqLabC ZCP1C EOL { OfstOff }
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqLabC Rapid FirstHome SpinOff EOL
ELSE
SeqLabC ' T0 M6' EOL
END
IF ProgStop?
SeqLabC ' M0' EOL
END
RETURN

End3:
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END
Reopen
SeqLabC ' PROGRAMMENDE' EOL
Close
Retag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END