{4/11/89
Copied & modified; Dynapath 5M Excello M091.55, for National Research.
Modified per marked-up read-out.
Jim Radcliffe}

{7/12/89
Modified; Dyna 5M Exc (NRC) M189.55. For: National Research.
Changed CRCOffsetC to CRCOfst if FirstFeat.
Add ' E02' to Home line.
Jim Radcliffe}

{9/8/89, add PostScript, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{16Jul97
Original: Dynapath 5M (NRC) M190.62
Created: Dynapath 5M [NRC] M190.15
For: National Research Council
Changes made per: Serge Bouchard
Updated to .15 format per Fanuc 6M M001.15
Subs restricted because a Sub being executed cannot call another Sub
Added ZonlyRepAutoCycle_LH, AutoCycCutSub1_LH & AutoCycCutSub2_LH
to output longhand subs with ZonlyRepAutoCycle_LH
Changed Return from Sub to M2 in MachSpec
Charles Winston}

{21Aug97
Original: Dynapath 5M (NRC) M190.15
Created: Dynapath 5M [NRC] M190.15.1
For: National Research Council
Changes made per: Serge Bouchard
Added FORMAT#7 and Changed NewWFO# from #5
Changed Literal in WFONum to ' E'
Changed SubID to '( DFS, ' Program# ' )' in StartSub
Added SetFlag('9') in StartSub to signal that subs are being used
Added SetFlagF('9') at initProg
Deleted Rapid before cancelling the Drill Cycle in IF Drilling
Moved CoolOn from FirstOp3 to the same line as WFOStuff in FirstOp2
Deleted IncValue in NewToolOp1, SameToolOp1 and End1
Put AbsOrInc onto a seperate line in NewToolOp2 and SameToolOp3,
Note: Only one G-code is allowed per line
Added Boolean for IF AbsoluteMoves in NewToolOp1 , SameToolOp1 and End1
Added a leading space to Literals ' M0' and ' E02' in NewToolOp2 and SameToolOp1
Added Boolean in End3 to check for Sub Calls
Charles Winston}

{8Sep97
Original: Dynapath 5M [NRC] M190.15.1
Created: Dynapath 5M [NRC] M190.15.2
For: National Research Council
Changes made per: Serge Bouchard
Changed literal 'M00' to 'M02' in End3
Changed StartSub line to '(DFS,' Program# ')' (no Spaces)
Also updated metric Dynapath 5M [NRC] M190.15.2m
Charles Winston}

{4/21/98
Updated & Modified: Dynapath 5M [NRC] M190.15.2
Created: Dynapath 5M [NRC] M190.15.3
For: National Research Council
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Serge Bouchard of National Research Council.
Customer reported that ' E02' must be output with an XYMove.
Moved literal ' E02' from ProgStop to Home block at NewToolOp2 and End2_MPAT1P.
Added CheckPass call two places at MP1ToollAllPfu.
For output of Correct StrtPos SetWFO at OpenMP WorkFixtureOffsets.
Customer requested modification of EOP in SubProgram Output.
M02 causes control to stop reading prior to FIRST SubProgram.
Requested that M00 be output at end of Main, and M02 output after last SubProgram.
Modified ProgStop at End2 and End2_MPAT1P.
Changed literal ' M02' to ' M00' for Flag(9) at End3.
Added literal ' M02' block to follow Post2 command for Flag(9) at End3.
Customer reported Problem with RetractToCP1.
Cycle must be cancelled with move to ZCP1, Position to MoveSXYC, re-define Cycle.
Modified at ToolPath PointFeat.
Modified to NOT output Drill Subs at OpGuts IF Drilling.
Customer has been informed.
Updated for Catalyst v3.35C per Fanuc 6M M001.15 Format.
Cleanup modifications:
Deleted unused ExitMove Sub.
Added StrtPos to SetWFO block at OpenMP.
Combined Rapid StrtPos and WFOStuff CoolOn onto one block at FirstOp2 and NewToolOp4.
Moved WFOStuff to StrtPos block at SameToolOp3.
Moved AbvsOrInc and StrtPos blocks to top of SameToolOp3.
Added missing Close command at End3.
Need to close the whole shebang!
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '######00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(NewWFO#,7)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
' E' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( *MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF ToolTypeComment? AND NOT SameTool?
'(*MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment? AND NOT SameTool?
'(*MSG, ' ToolComment$ ' )' EOL
END
IF OperationIDComment?
'(*MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'(*MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'(*MSG, ' WorkGroupComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'(DFS,' Program# ')' EOL
DoSubComment
SetFlag('9') { set to TRUE if sub are being used }
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(*MSG, WARNING Z CLEARANCE WILL CHANGE )' EOL
'(*MSG, WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC StrtPos SetWFO EOL
END
SeqC SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF FirstFeat? AND Equal? SPZ# EPZ#
CRCOfst
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF RetractToCP1?
IF NOT FirstFeat?
SeqC ' G80' ZCP1 EOL
SeqC MoveSXYC EOL
SeqC Cycle FromCP MoveSZC RLevel Dwell Peck Retract FeedEnt EOL
END
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc FeedC ckCRC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc FeedC ckCRC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc FeedC ckCRC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

AutoCycCutSub1_LH:
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2_LH:
SkipZ
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
UnSkipZ
RETURN

ZonlyRepAutoCycle_LH: { LongHand, No sub call in AutoCycCutSub2_LH }
AutoCycPat {write pattern moves and main calls}
StartSub
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
AutoCycCutSub1_LH
AutoCycCutSub2_LH
NextCycle
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
TrackZNO# ClearancePlane2# { Cycle always leaves tool at RLevel regardless of RetractToCP1. }
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle_LH
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF RetractToCP1?
TrackZNO# FIRST SPZ#
ToolPath
ELSE
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
END
SetDrillEndOpZ
SeqC ' G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetFlagF('9') { True if Subs have been used }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
DoOpComments
Seq Plane EOL
DoPostScript
RETURN

FirstOp2:
SeqC AbsOrInc SpinOn EOL
CheckPass
SeqC Rapid StrtPos WFOStuff CoolOn EOL
RETURN

FirstOp3:
SeqC OfstOn EOL
RETURN

NewToolOp1:
SeqC Rapid OfstOff CoolOff EOL
IF AbsoluteMoves?
SeqC AbsValue EOL
END
RETURN

NewToolOp2:
DoEndOpPS
DoOpComments
IF ToolChangeAtHome?
SeqC AbsOrInc EOL
SeqC Rapid Home SpinOff ' E02' EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
Seq PlaneC CRCOffC EOL
DoPostScript
RETURN

NewToolOp4:
SeqC AbsOrInc SpinOn EOL
CheckPass
SeqC Rapid StrtPos WFOStuff CoolOn EOL
RETURN

NewToolOp5:
SeqC OfstOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC OfstOff EOL
IF AbsoluteMoves?
SeqC AbsValue EOL
END
SeqC SpinOff EOL
SeqC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC PlaneC EOL
SeqC AbsOrInc EOL
SeqC Rapid StrtPos WFOStuff SpinOn EOL
IF LAST ProgStop?
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC Rapid OfstOff CoolOff EOL
IF AbsoluteMoves?
SeqC AbsValue EOL
END
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome?
FirstHome
END
SeqC ' E02' EOL
IF NOT Flag?('9') { no subs are being called }
IF ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
END
RETURN

End2_MPAT1P:
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC FirstHome ' E02' EOL
END
IF NOT Flag?('9') { no subs are being called }
IF ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
END
RETURN

End3:
IF Flag?('9') { subs are being called }
SeqC ' M00' EOL
ELSE
SeqC EOP EOL
END
CloseSub
Post2 {organize Subs into one program}
IF Flag?('9') { subs are being called }
SeqC ' M02' EOL
END
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(*MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(*MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(*MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2_MPAT1P
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
CheckPass
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
CheckPass
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END