{Change Comments ***********************************************************}

{7/5/91
Copied & modified: Tosnuc 500MX BMC-6B M436.79
For: Tool Sales & Service
Control: Tosnuc 500MX
Machine: Toshiba VMC-4 (Vertical)
Modified Rotate sub, no M10's & M11's, and formats, trailing zero's suppressed.
Modified G73 move to machine coordinate values.
JR}

{6/10/93
Modified: Tosnuc 500MX VMC-4 M437.80
For: Tool Sales & Service
Changes made per Don Wright at Tool Sales & Service
Updated to Version 4.1 per LongHand M001.81.3 Format.
Changed all colons in Comments to dashes for DNC purposes.
Added Axis Tracking for Helical Arcs at FormatArc.
Added CkThreadHob sub to output G40 on NextToLastFeat.
Moved ResetCRCNum from common point for all operations to ToolPath.
Customer wants to see CRCOffset with all G41/G42 blocks.
Modified CRCOff to support 4.2 exit move, deleted LastFeatExtend.
Added 'G73X350000Y50000Z470000' SpinOff prior to ToolChng at FirstOperation.
Changed literal 'Y50000' to 'Y350000' at EndPartSub.
DWB}

{9/14/93
Modified: Tosnuc 500MX VMC-4 M437.81.2
For: Tool Sales & Service
Moved the program stop, M0, to the beginning of the operation specified in ncCAM.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#^00'
#2 = '##0^###'
#3 = '*##0^###'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '##^#0'
#7 = '#;'
#8 = '####^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Tag#,5)
FORMAT(Recall#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(HelixPitch#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' - ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' - ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

Rotate:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'B' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'B' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'A' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'A' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

GetConnect:
IF FeedConnect?
FeedC
ELSE
RapidC
END
RETURN

ExitMove:
IF NOT FeedConnect?
SeqC
IF FIFO? { .81 }
FeedC
ELSE
IF NOT AutoCycle?
RapidC
END
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
EOL
END
RETURN

ExitMove2:
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY
ELSE
IF XZPlane?
MoveX MoveZ
ELSE
MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
IF XYPlane? AND ZMove?
'K' HelixPitch#
ELSE
IF XZPlane? AND YMove?
'J' HelixPitch#
ELSE
IF YZPlane? AND XMove?
'I' HelixPitch#
END
END
END
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF AutoCycle?
SetInc
ELSE
SetAbsOrInc
END
RETURN

CkThreadHob:
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF NEXT NOT XMove? AND NEXT NOT YMove?
CRCOffC
END
TrackXNO# SPX#
TrackYNO# SPY#
TrackZNO# SPZ#
SetInc
RETURN

CkCRC:
IF LastFeat?
CRCOffC
ELSE
IF AutoCycle? AND NEXT LastFeat?
CkThreadHob
ELSE
CRCOnC
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CkCRC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath:
ResetCRCNum { Do not move, customer wants offset on all G41/G42 blocks. }
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL {.80.01}
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('6') SUB# EPX# CurOriginPosX#
Save# Num#('7') SUB# EPY# CurOriginPosY#
SetInc
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
IF NOT SameTool?
IF WorkFixtureOffsets?
SeqC 'G57H' Recall# Num#('9') EOL
END
END
ELSE
SeqC 'G57H' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF MultipleParts? AND WorkFixtureOffsets?
SeqC 'G57H' Recall# Num#('9') EOL
ELSE
IF NeedWFO1?
SeqC 'G57H' NewWFO# EOL
END
END
END
END
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
EachRep
IF NOT FirstCycle?
SeqC GetConnect StrtPosC EOL
END
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
IF ZshiftOnly?
EntryMove
END
ELSE
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
DoCycleComment
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
SetAbs
Save# Num#('4') SPX#
Save# Num#('5') SPY#
SetInc
AutoCycCutSub1
DoCycleComment
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('4') Recall# Num#('6')
TrackYNO# ADD# Recall# Num#('5') Recall# Num#('7')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF FirstCycle?
DoCycleComment
EntryMove
ELSE
IF NOT FeedConnect?
ExitMove
END
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
DoCycleComment
IF NOT FeedConnect?
EntryMove
END
END
ToolPath
NextRep
AutoCycCutSub2
ReSetPass2 {restore for positioning moves}
NEXTFeat
RETURN

DrillStuff:
SeqC DrillCP EOL
GetCycle
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
SeqC FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoPartCycleComment
DoOpComments
DoPostScript
Rotate
WFOStuff
CheckPass
RETURN

MasterSub:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE
IF ToolChangeAtHome?
SetHome
END
Seq Plane DrillOff CRCOff EOL
SeqC 'G53' EOL { cancel WFO }
SeqC 'G73' 'X350000' 'Y50000' 'Z470000' SpinOff EOL
SeqC OpToolID ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
Rotate
WFOStuff
IF ProgStop?
SeqC 'M0' EOL
END
CheckPass
SeqC AbsOrInc Rapid StrtPos Speed SpinOn
IF NOT LastTool?
PreTool
END
EOL
SeqC OfstOn CoolOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE

{Finish off last Operation}

SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND WorkFixtureOffsets?
IF WorkFixtureOffsets?
SeqC 'G57H' Recall# Num#('8') EOL
END
END
SeqC OfstOff EOL
SeqC 'G73' 'X350000' 'Y50000' 'Z470000' SpinOff EOL
DoEndOpPS
Rotate
SeqC ProgStop ASCII('13') EOL

{Start new Operation}

Seq OpToolID ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
Rotate
WFOStuff
IF ProgStop?
SeqC 'M0' EOL
END
CheckPass
SeqC AbsOrInc Plane Rapid StrtPos Speed SpinOn PreTool EOL
SeqC OfstOn CoolOn EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF ProgStop?
SeqC CoolOff EOL
SeqC OfstOff EOL
SeqC 'G73' 'Z470000' SpinOff EOL
Rotate

{Start new Operation}

GetStartOfSameTool
SeqC 'M0' EOL
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff EOL
SeqC 'G73' 'Z470000' EOL
Rotate

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
IF Rotate?
SeqC OfstOff EOL
SeqC 'G73' 'Z470000' EOL
Rotate

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

{GetStartOfSameTool}
DoPartCycleComment
DoOpComments
DoPostScript
IF Rotate?
SeqC OfstOff EOL
SeqC 'G73' 'Z470000' EOL
Rotate
WFOStuff
CheckPass
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
IF NewWFO?
SeqC OfstOff EOL
SeqC WFOStuff EOL
CheckPass
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
SeqC WFOStuff EOL
CheckPass
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
END
END
END
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZshiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
SeqC RapidC ZCP3C EOL
END
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND WorkFixtureOffsets?
IF WorkFixtureOffsets?
SeqC 'G57H' Recall# Num#('8') EOL
END
END
SeqC OfstOff EOL
SeqC 'G73' 'X350000' 'Y350000' 'Z470000' SpinOff EOL
DoEndOpPS
Rotate
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop ASCII('13') EOL
END
RETURN

MPLoop:
TagInit
IF AllToolsOnePart?
Save# Num#('9') Recall# Num#('8') { NewWFO# }
EachPart
TagInc
EachOp
MasterSub
NextOp
EndPartSub
Save# Num#('9') ADD# Recall# Num#('9') Num#('1') { NewWFO# }
NextPart
ELSE { OneToolAllParts }
Save# Num#('2') Recall# Num#('1')
IF LTEqual? Recall# Num#('1') Recall# Num#('3')
EachOp
IF Equal? Operation# Recall# Num#('2')
Save# Num#('2') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('1') Recall# Num#('3')
Save# Num#('2') Operation#
ELSE
IF NotEqual? Recall# Num#('1') SUB# Recall# Num#('2') Num#('1')
Save# Num#('2') SUB# Operation# Num#('1')
END
END
END
END
NextOp
EachPart
TagInc
EachOp
IF GTEqual? Operation# Recall# Num#('1')
IF LTEqual? Operation# Recall# Num#('2')
IF Equal? Operation# Recall# Num#('1')
IF FirstPart?
Save# Num#('9') Recall# Num#('8') { NewWFO# }
ELSE
Save# Num#('9') ADD# Recall# Num#('9') Num#('1') { NewWFO# }

{Finish off last Operation}

IF FullUp?
SeqC CoolOff EOL
SeqC OfstOff EOL
SeqC 'G73' 'Z470000' EOL
END
{DoEndOpPS}

{Start new Operation}

{GetStartOfSameTool}
DoPartCycleComment
DoOpComments
DoPostScript
IF Rotate? AND NOT FullUp?
SeqC OfstOff EOL
SeqC 'G73' 'Z470000' EOL
END
Rotate
WFOStuff
CheckPass
SeqC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
IF FullUp?
SeqC OfstOn CoolOn EOL
ELSE
IF Rotate?
SeqC OfstOn EOL
END
END
END
END
MasterSub
END
END
NextOp
NextPart
Save# Num#('1') ADD# Recall# Num#('2') Num#('1')
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('3150')
SetMaxFeed('500')
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + A move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
END
EOR EOL
'E' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM - ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT - ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED - ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts?
Save# Num#('1') Num#('1')
Save# Num#('8') NewWFO#
EachOp
IF LastOp?
Save# Num#('3') Operation#
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
ELSE
IF WorkFixtureOffsets?
SeqC 'G57H' Recall# Num#('8') EOL
END
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
SeqC EOP EOL
SeqC 'E99' EOL
EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END