{Change Comments ***********************************************************}

{8/31/89
Modified: Monarch VMC-75 M087.54
For: BGA International
Control: Monarch VMC 1050
Turned UseSeparateSubCalls on.
Added Comments to alert user regarding 'G89' Canned Boring Cycle.
If no Dwell value was entered, Control won't accept 'G89', user will need to change it to 'G85'.
Added Comments to alert user regarding seperate WorkFixtureOffsets for XY axes and Z axis.
Manual states that XY axes uses one WFO, and Z axis uses another. User will need to edit Z WFO if
he/she needs it.
Outputting TABLE(2,SpeedRPM#,1) for Tap, and TABLE(1,SpeedRPM#,1) for all other operations.
The user will have to be satisfied with RPM output for every operation, SpeedC is not used.
NOTE: This post processor requires utility program modifier application.
This application modifies FORMATting of CutterRadiusCompensation.
NOTE: A potential problem exists if user requests 10 or more MultipleParts and/or Repeats.
I couldn't get PartsLess1 and RepsLess1 to output leading zeros, so I had to force a literal zero.
Offset values range from 0 to 99. 10 or more would cause output to be 010 to 099 which is
unacceptable to Control.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/3/91
Modified: Monarch VMC 1050 MC M237.62
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{10/21/91
Modified: Monarch VMC 1050 MC M237.79
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 6M M001.81 Format.
Corrected bug in SubID FORMAT.
Added logic to output 'G85' for FIFO Drilling Cycle with Dwell, 'G89' without Dwell.
This fixes bug noted on 8/31/89.
Added logic to suppress RPM if no change for SameTool.
This fixes bug noted on 8/31/89.
Added FormatCRCOn sub to output necessary data for CutterRadiusCompensation.
This sub replaces utility program modifier application.
Changed RepsLess1 to RepsLess1# and PartsLess1 to PartsLess1#.
This fixes bug noted on 8/31/89.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '###.####;0'
#7 = '#0'
#8 = '00'
#20 = 'ą#bbb.bbbb#; 0' { For FormatCRCOn Report }

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(Recall#,6)
FORMAT(ClearancePlane1#,6)
FORMAT(ClearancePlane2#,6)
FORMAT(ClearancePlane3#,6)
FORMAT(Program#,7) {.72}
FORMAT(RepsLess1#,8)
FORMAT(PartsLess1#,8)
FORMAT(NewWFO#,8) {.72}

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC EOL
ELSE
SeqC RapidC EOL
END
FindAnyZMoves
SeqC
IF NoZMoves?
'G86'
ELSE
'G87'
END
'R' ClearancePlane2# ZIn
IF FeedEntry?
FeedEnt
END
EOL
RETURN

StartSub:
OpenSub
SeqC 'G25' SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepsLess1# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF FIFO? {.81}
SeqC FeedC EOL
ELSE
SeqC RapidC EOL
END
SeqC CRCOffC EOL
IF NOT FeedConnect?
SeqC 'G87R' ClearancePlane3# ZCP3
IF NOT AutoCycle?
IF FIFO? {.81}
FeedRateC
END
END
EOL
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab '00' EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab PartsLess1# EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC ArcIJC
RETURN

FormatCRCOn:
IF NOT Flag?('1')
IF XMove? OR YMove?
IF CutterRadiusCompensation?
IF AutoCycle?
SetAbs
ELSE
SeqC IncValue EOL
END
Save# Num#('1') SPX#
Save# Num#('2') EPX#
Save# Num#('3') SPY#
Save# Num#('4') EPY#
Save# Num#('5') SUB# EPX# SPX# { XDist }
Save# Num#('6') SUB# EPY# SPY# { YDist }
Save# Num#('7') Num#('3.1416') { Pi }
Save# Num#('8') DIV# Num#('180') Recall# Num#('7') { Radians = 180Ą/Pi }
IF Equal? Recall# Num#('5') Num#('0')
Save# Num#('9') Num#('90') { Angle }
Save# Num#('10') Num#('0') { Cosine }
Save# Num#('11') Num#('1') { Sine }
IF LessThan? Recall# Num#('6') Num#('0')
SeqC Feed 'XY-' EOL
ELSE
IF GreaterThan? Recall# Num#('6') Num#('0')
SeqC Feed 'XY' EOL
END
END
ELSE
IF Equal? Recall# Num#('6') Num#('0')
Save# Num#('9') Num#('0') { Angle }
Save# Num#('10') Num#('1') { Cosine }
Save# Num#('11') Num#('0') { Sine }
IF LessThan? Recall# Num#('5') Num#('0')
SeqC Feed 'X-Y' EOL
ELSE
IF GreaterThan? Recall# Num#('5') Num#('0')
SeqC Feed 'XY' EOL
END
END
ELSE
Save# Num#('9') ATAN# DIV# ABS# Recall# Num#('6') ABS# Recall# Num#('5') { Angle }
Save# Num#('10') COS# Recall# Num#('9') { Cosine }
Save# Num#('11') SIN# Recall# Num#('9') { Sine }
IF LessThan? Recall# Num#('5') Num#('0')
IF LessThan? Recall# Num#('6') Num#('0')
SeqC Feed 'X-Y-' EOL
ELSE
IF GreaterThan? Recall# Num#('6') Num#('0')
SeqC Feed 'X-Y' EOL
END
END
ELSE
IF GreaterThan? Recall# Num#('5') Num#('0')
IF LessThan? Recall# Num#('6') Num#('0')
SeqC Feed 'XY-' EOL
ELSE
IF GreaterThan? Recall# Num#('6') Num#('0')
SeqC Feed 'XY' EOL
END
END
END
END
END
END
SeqC CRCOnC 'I' Recall# Num#('10') 'J' Recall# Num#('11') CRCOfst EOL

{FORMAT(Recall#,20)
' ' EOL
' SPX# = ' Recall# Num#('1') EOL
' EPX# = ' Recall# Num#('2') EOL
' SPY# = ' Recall# Num#('3') EOL
' EPY# = ' Recall# Num#('4') EOL
' XDist# = ' Recall# Num#('5') EOL
' YDist# = ' Recall# Num#('6') EOL
' Pi# = ' Recall# Num#('7') EOL
' Radians# = ' Recall# Num#('8') EOL
' Angle# = ' Recall# Num#('9') EOL
' Cosine = ' Recall# Num#('10') EOL
' Sine = ' Recall# Num#('11') EOL
' ' EOL
FORMAT(Recall#,6)}

IF AutoCycle?
SetInc
ELSE
SeqC AbsOrInc EOL
END
Feed
SetFlag('1')
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
FormatCRCOn
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab '00' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC RapidC EOL
SeqC CRCOffC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC FeedC EOL
SeqC CRCOffC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
SetFlagF('1')
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'E' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqC 'E' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc EOL
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqC FeedC EOL
SeqC 'G87R' ClearancePlane2# ZCP2 FeedRateC EOL
ELSE
SeqC RapidC EOL
SeqC 'G87R' ClearancePlane2# ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqC Feed EOL
SeqC 'G87R' PRIME ClearancePlane2# ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid EOL {.69 added Rapid, reads better}
SeqC 'G87R' PRIME ClearancePlane2# ZCP2PlusInc EOL {can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed EOL
SeqC 'G87R' PRIME ClearancePlane2# ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid EOL {.69 added Rapid, reads better}
SeqC 'G87R' PRIME ClearancePlane2# ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab '00' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed EOL
SeqC 'G87R' ClearancePlane2# ZCP2 FeedRate EOL {.69}
ELSE
SeqC Rapid EOL
SeqC 'G87R' ClearancePlane2# ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC EOL {.71.2, changed to FeedC}
SeqC 'G87R' PRIME ClearancePlane2# ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
SeqC 'G87R' PRIME ClearancePlane2# ZCP2PlusIncC EOL {can't call for cycle =1}
END
SeqC Feed EOL
SeqC 'G87R' PRIME ClearancePlane2# ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
SeqC 'G87R' PRIME ClearancePlane2# ZInPlusInc EOL {can't call for cycle =1}
END
END
SeqC SubCall CallLab '00' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
SeqC PlaneC EOL
SeqC AbsOrInc EOL
RETURN

SpeedCode:
IF Drilling? AND Tap?
TABLE(2,SpeedRPM#,1)
ELSE
TABLE(1,SpeedRPM#,1)
END
RETURN

CheckSpeedCode: { Called from SameTool }
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SpeedCode
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('99')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
IF UseComments?
'Deselect Use Comments in ncPost to suppress this and the following comment from the output.' EOL
' ' EOL
'NOTE: Regarding Work Fixture Offsets.' EOL
' Currently this Post Processor outputs Work Fixture Offsets on the Block that outputs' EOL
' the StartPoint Position. The Manual states that this is for the X and/or Y Axes only.' EOL
' If you need an Offset for the Z Axis, the Control requires a seperate Offset Number.' EOL
' This Post Processor does not output the Offset for the Z Axis, so you will need to' EOL
' edit this output if you want an Offset for the Z Axis.' EOL
' ' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
SetProgNum('19') { TO START SUBS AT #20 }
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Plane EOL
SeqC CRCOff EOL
DoOpComments
DoPostScript
SeqC AbsOrInc SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC AbsOrInc EOL
END
SeqC Rapid StrtPos OpToolID SpeedCode ToolChng WFOStuff EOL
SeqC 'G86R' ClearancePlane1# ZCP1 ToolOfst CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC 'G86R' LAST ClearancePlane1# LAST ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

' ' EOL
Seq Plane EOL
SeqC CRCOff EOL
DoOpComments
DoPostScript
SeqC AbsOrInc SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC AbsOrInc EOL
END
SeqC Rapid StrtPos OpToolID SpeedCode ToolChng WFOStuff EOL
SeqC 'G86R' ClearancePlane1# ZCP1 ToolOfst CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC 'G86R' LAST ClearancePlane1# LAST ZCP1 EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos CheckSpeedCode WFOStuff EOL
SeqC 'G86R' ClearancePlane1# ZCP1 ToolOfst CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC 'G86R' LAST ClearancePlane1# LAST ZCP1 EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos CheckSpeedCode WFOStuff EOL
SeqC 'G86R' ClearancePlane1# ZCP1 ToolOfst EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos CheckSpeedCode WFOStuff EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC 'G86R' ClearancePlane2# ZCP2 EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF FIFO? {.81}
SeqC FeedC EOL
ELSE
SeqC RapidC EOL
END
SeqC CRCOffC EOL
SeqC 'G87R' ClearancePlane3# ZCP3
IF NOT AutoCycle?
IF FIFO? {.81}
FeedRateC
END
END
EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
GetCycle
IF PeckChipBreaker?
' ' EOL
' ( NOTE This Program does not support a Peck, Chip-Breaking Cycle. )' EOL
' ( The output for this Operation will be a Peck, Full-Out Cycle. )' EOL
' ' EOL
END
SeqC
IF FIFO? AND NOT Dwell?
'G85'
ELSE
Cycle
END
'R'
IF RetractToCP1?
ClearancePlane1#
ELSE
ClearancePlane2#
END
ZDepth Dwell Peck ToolOfst
IF Tap?
'M10'
ELSE
FeedEnt
END
EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
IF Repeats?
FinishSubG92
END
SeqC 'G87R' ClearancePlane3# ZCP3 EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC 'G86R' ClearancePlane1# ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC AbsOrInc SpinOn EOL
SeqC Rapid
IF ToolChangeAtHome?
Home
ELSE
'X0Y0'
END
PreTool ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END