{Change Comments ***********************************************************}

{9/23/88
Copied & Modified: Heidenhain TNC 145C M082.53
For: Galaxy Die & Engineering.
Machine:
Control: Heidenhain TNC 145C
Modified to have only 1 space between codes.
Added L address before Z moves.
Use Speed from ncCam.
Modified SpinOn to be M13 [CW] and M14 [CCW].
Added first and last lines.
Added M6 after tool call.
Deleted CoolOn and CoolOff commands.
Jim Radcliffe}

{11/15/88
Updated: Heid TNC151 Bridgeport M139.55
For: Galaxy Die & Engineering.
Changed all RapidF to 'F3999'.
Deleted LBL 1 thru LBL 0 lines, toolchange subroutine, from beginning of prog.
Moved HomePos & CP1 after M06 in FirstOp & NewTool.
Changed M05 to M25 for spindle up.
Added missing FORMAT for ZDepth#.
Changed ClearancePlane2# in Milling to ZCP2.
Added FORMAT #9 for cycle defs SETUP & PECKG that require a negative sign which is literal.
Deleted ZDepth# preceding IncValue and following AbsOrInc.
Changed ZDepth# in PECKG to ZDepthInc#, using FORMAT #9.
Changed FORMAT for ClearancePlane2# to FORMAT #9.
Changed FORMAT for Peck# to FORMAT #9.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{11/29/90
Copied & Modified: Heid TNC151 Bridgeport M139.58
For: Phoenix Machine & Design
Machine: Interact 412
Control: Heidenhain TNC 151B/151Q
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
Customer requests:
Added SaveProgNum2 and replaced ProgID1 with Program# at beginning and end becuase decimal point
is not allowed in opening statement.
Add ASCII('3') at end to cause DNC to stop sending.
Form changes:
Modified Rapid FeedRate (XXXX^X) from 0 to 3999
Modified 'F' default format from '00^0' to '###^0'
Prog changes:
Cleaned up FORMATs for better readability.
Added SPZ#, EPX#, EPY#, EPZ#, ArcI# and ArcJ# and FORMATs for same, for AutoCycle output
which requires literal 'I' before each axis address to indicate incremental moves.
Added FORMATs for RepeatX#, RepeatY#, RepeatZ#, OriginUnShiftRX#, OriginUnShiftRY# and
OriginUnShiftRZ# for correct output.
Added TLDia#, TLLength# and TLNum# and FORMATs for same, for Tool Definition Loop at beginning.
Added RapidF# and FORMAT for same, and replaced all literal 'F3999' to RapidF for ease of
future conversions.
DWB}

{6/19/92
Updated: Heid TNC 151 BP M139.76.1 to .81 format
Other changes for simplicity and ease of future updates or modifications.
Changed HomeX# & HomeY# to Home
Changed StartPosX# & StartPosY# to StrtPos
Changed all literal L to use the sub DoL
Changed all literal R0 to use the sub DoR0
Jim Radcliffe}

{6/19/92
Copied & modified: Heid TNC 151 BP M139.81
For: Belden Wire & Cable
Machine: Bridgeport Series 1 Interact
Control: Heidenhain TNC 151A
Summary of major changed per customer requests:
Added an asterisk before comments.
Deleted the Tool List from the beginning of program.
Modified layout of output at beginning and ending of operations.
Modified repeats of subs.
Do a ' STOP' before ' Tool Call'.
Jim Radcliffe}

{7/6/95
Initial: Heid TNC 151A BP S1 M508.81
Created: Heid TNC 151 [FMI] M815.81
ForUser: Murtuagh / FM Industries
Comment: Changed Rapid Feed Rate in Macg Spec Numbers from 3999 to 6298
Jim Radcliffe}

{8/29/95
Initial: Heid TNC 151 [FMI] M815.81
Created: Heid TNC 2500 [FMI] M815.81.1
ForUser: Murtuagh / FM Industries
Control: Heidenhain TNC 2500
Machine: Bridgeport 720 VMC
Develop: ComPost 4.21.32, Virtual v.2.20
Comment: Modifications per marked up readout and conversation with Alex Hoffman
Jim Radcliffe}

{04Jun97
Original: Heid TNC 2500 [FMI] M815.81.1
Created: Heid TNC 2500 [FMI] M815.15
For: Seagate Technologies
Updated to .89 Format per Heid TNC 2500 [ESS] M979.89.1
Updated to .15 Format per Heid TNC 155 [ESS] M980.15
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####0.000'
#7 = '###0.0000'
#8 = '###^0'
#9 = '*###0.0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(SPZ#,7)
FORMAT(EPX#,7)
FORMAT(EPY#,7)
FORMAT(EPZ#,7)
FORMAT(ArcI#,7)
FORMAT(ArcJ#,7)
FORMAT(RepeatX#,7)
FORMAT(RepeatY#,7)
FORMAT(RepeatZ#,7)
FORMAT(PartShiftX#,7)
FORMAT(PartShiftY#,7)
FORMAT(PartShiftZ#,7)
FORMAT(OriginUnShiftPX#,7)
FORMAT(OriginUnShiftPY#,7)
FORMAT(OriginUnShiftPZ#,7)
FORMAT(OriginUnShiftRX#,7)
FORMAT(OriginUnShiftRY#,7)
FORMAT(OriginUnShiftRZ#,7)
FORMAT(ToolLength#,7)
FORMAT(DIV#,7)
FORMAT(CalcZFmSurf#,7)
FORMAT(FeedEntry#,8)
FORMAT(Peck#,9)
FORMAT(CalcCP2FmSurf#,9)

{Special Command Subroutines ***********************************************}

DoL:
' L'
RETURN

DoZL:
' L'
RETURN

DoM:
' M'
RETURN

DoR0:
IF NOT Flag?('3') { ArcFeat }
''
END
IF Flag?('2') { CutterRadiusCompensation }
IF CRCleft?
' RL'
ELSE
' RR'
END
ELSE
' R0'
END
RETURN


DoR:
' R'
RETURN

DoF:
' F'
RETURN

ckCRCOff:
IF Flag?('2') { CRCOn }
SetFlagF('2')
SeqLab DoL ' IX+0 IY+0' DoR0 RapidF DoM EOL
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? { CAM file is in Metric, tools and tool path }
SetScale('.03937007874') { change to English, this is an English post }
ELSE
SetScale('1')
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'*( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'*( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'*( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'*( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'*( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'*( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
SeqLab DoL
IF AutoCycle? {implies incremental}
' IZ' SPZ#
ELSE
ZIn
END
DoR0
IF FeedEntry?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RapidF
END
DoM EOL
RETURN

StartSub:
OpenSub
SeqLab ' LBL ' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'*( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoZL ZCP3
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RapidF
ELSE
IF FIFO? {.81}
Feed {no output}
FeedEnt
ELSE
RapidF
END
END
DoM EOL
END
ckCRCOff
RETURN

FinishSubG92: {part 2}
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' RepeatX# EOL
SeqLab ' CYCL DEF 7.2 IY' RepeatY# EOL
SeqLab ' CYCL DEF 7.3 IZ' RepeatZ# EOL
SeqLab ' CALL LBL 'Program# ' REP ' RepsLess1 '/ ' RepsLess1 EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftRX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftRY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftRZ#('0') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# EOL
StartSub
ELSE
'*( NOTE: This post processor does not support work fixture offsets!!! )' EOL
'*( Reprocess using Equally Spaced Offsets!!! )' EOL
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftY# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftZ# EOL
SeqLab ' CALL LBL ' Program# ' REP ' PartsLess1 ' / ' PartsLess1 EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPZ#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

DoHelix:
SetAbs
'P IPA'
IF ArcCW?
'-'
ELSE
'+'
END
IF Equal? EPMoveAngle# SPMoveAngle# { Full Circle }
'360.000'
ELSE
IF ArcCW? AND LessThan? SPMoveAngle# EPMoveAngle#
SUB# NUM#('360') ABS# SUB# EPMoveAngle# SPMoveAngle#
ELSE
ABS# SUB# EPMoveAngle# SPMoveAngle#
END
END
SetInc
IF XYPlane?
' IZ' EPZ#
ELSE
IF XZPlane?
' IY' EPY#
ELSE { YZPlane }
' IX' EPX#
END
END
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF AutoCycle?
SetInc
ELSE
SetAbsOrInc
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XYPlane?
IF XMove? OR YMove? OR ArcFeat?
' IX' EPX# ' IY' EPY#
IF ZMove?
' IZ' EPZ#
END
ELSE
IF ZMove?
' IZ' EPZ#
END
END
ELSE
IF XZPlane?
IF XMove? OR ZMove? OR ArcFeat?
IF YMove?
' IX' EPX# ' IY' EPY# ' IZ' EPZ#
ELSE
' IX' EPX# ' IZ' EPZ#
END
ELSE
IF YMove?
' IY' EPY#
END
END
ELSE { YZPlane }
IF YMove? OR ZMove? OR ArcFeat?
IF XMove?
' IX' EPX# ' IY' EPY# ' IZ' EPZ#
ELSE
' IY' EPY# ' IZ' EPZ#
END
ELSE
IF XMove?
' IX' EPX#
END
END
END
END
ELSE
IF XYPlane?
IF XMove? OR YMove? OR ArcFeat?
MoveX MoveY
IF ZMove?
MoveZC
END
ELSE
IF ZMove?
MoveZC
END
END
ELSE
IF XZPlane?
IF XMove? OR ZMove? OR ArcFeat?
IF YMove?
MoveX MoveY MoveZ
ELSE
MoveX MoveZ
END
ELSE
IF YMove?
MoveY
END
END
ELSE { YZPlane }
IF YMove? OR ZMove? OR ArcFeat?
IF XMove?
MoveX MoveY MoveZ
ELSE
MoveY MoveZ
END
ELSE
IF XMove?
MoveX
END
END
END
END
END
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF LastFeat?
SetFlagF('2') { CRCOff }
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOn }
END
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

FormatArc:
DoAbsOrInc
SeqLab ' CC'
IF AutoCycle? OR NOT AbsValue? {implies incremental}
' IX' ArcI# ' IY' ArcJ#
ELSE
ArcIJ
END
EOL
SeqLab ' C'
IF XYPlane? AND ZMove?
DoHelix
ELSE
IF XZPlane? AND YMove?
DoHelix
ELSE
IF YZPlane? AND XMove?
DoHelix
ELSE
CheckMove
END
END
END
IF ArcCW?
' DR-' CWArc {no output}
ELSE
' DR+' CCWArc {no output}
END
SetFlag('3')
DoR0
SetFlagF('3')
RETURN

FormatLine:
IF ZMove? AND NOT XMove? AND NOT YMove?
DoZL
ELSE
DoL
END
DoAbsOrInc CheckMove CkCRC DoR0
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF NOT FirstFeat?
Rapid {no output}
IF AutoCycle?
SeqLab DoL MoveSX MoveSY DoR0 RapidF DoM EOL
ELSE
SeqLab DoL DoDrillAbsOrInc
IF AbsValue?
MoveSX MoveSY
IF SPZMove?
MoveSZ
END
ELSE
' IX' SPX# ' IY' SPY# ' IZ' SPZ#
END
DoR0 RapidF ' M99' EOL
END
END
IF AutoCycle?
SeqLab ' CALL LBL ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
Rapid {no output}
IF XMove? OR YMove? OR ZMove?
SeqLab FormatLine RapidF DoM EOL
END
ELSE
IF LineFeat?
Feed {no output}
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRate DoM EOL
DecelMove2
END
SeqLab FormatLine DecelFeed DoM EOL
ELSE
SeqLab FormatLine FeedRate DoM EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeed DoM EOL
DecelMove2
END
FormatArc DecelFeed DoM EOL
ELSE
FormatArc ArcFeed DoM EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
IncValue {no output}
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLab DoZL ZCP2 DoR0
IF FIFO? {.81}
FeedEnt
ELSE
RapidF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
SeqLab DoL StrtPos DoR0
IF FeedConnect?
FeedEnt
ELSE
RapidF
END
DoM EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# DoR0 FeedRate DoM EOL
AbsOrInc
END
END
SeqLab DoZL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# DoR0 RapidF DoM EOL
AbsOrInc
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc DoR0 RapidF DoM EOL
SeqLab DoZL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoZL ZInPlusInc DoR0 RapidF DoM EOL
END
ELSE
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc DoR0 RapidF DoM EOL
SeqLab DoZL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoZL ZInPlusInc DoR0 RapidF DoM EOL
END
END
ELSE
IF FeedEntry?
SeqLab DoZL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
SeqLab DoZL ZInPlusInc DoR0 RapidF DoM EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' CALL LBL ' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
Feed {no output}
SeqLab DoL ZCP2 DoR0 FeedEnt DoM EOL {.69}
ELSE
Rapid {no output}
SeqLab DoL ZCP2 DoR0 RapidF DoM EOL {.69}
END
END {.69}
SeqLab ' LBL 0' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos DoR0
IF Rapid?
RapidF
ELSE
FeedRate
END
DoM EOL
END
IF FeedConnect?
FeedC {no output}
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE {we have an entry/exit connect}
IF FeedEntry?
IF NOT FirstCycle?
RapidC {no output}
SeqLab DoL ZCP2PlusIncC DoR0 RapidF DoM EOL
END
FeedC {no output}
SeqLab DoL ZInPlusInc DoR0 FeedEnt DoM EOL
ELSE
RapidC {no output}
SeqLab DoL ZInPlusInc DoR0 RapidF DoM EOL
END
END
SeqLab ' CALL LBL ' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLab DoL ZCP2 DoR0 RapidF DoM EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
Rapid {no output}
SeqLab DoL ZCP3 DoR0 RapidF DoM EOL
ELSE
IF FIFO? {.81}
FeedC {no output}
SeqLab DoL ZCP3 DoR0 FeedEnt DoM EOL
ELSE
Rapid {no output}
SeqLab DoL ZCP3 DoR0 RapidF DoM EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab DoL StrtPos DoR0 RapidF DoM EOL
END
SeqLab DoL ZCP2 DoR0 RapidF DoM EOL
IF Tap?
SeqLab ' CYCL DEF 2.0 TAPPING' EOL
SeqLab ' CYCL DEF 2.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 2.3 DWELL 0' EOL
SeqLab ' CYCL DEF 2.4 F' FeedEntry# EOL
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
Peck# EOL
ELSE
CalcZFmSurf# EOL
END
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell# EOL
ELSE
'0' EOL
END
SeqLab ' CYCL DEF 1.5 F' FeedEntry# EOL
END
IF CallMasterOp?
SeqLab ' CALL LBL ' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab ' CALL LBL ' Program# EOL
StartSub
SeqLab DoL StrtPos DoR0 RapidF ' M99' EOL
ToolPath
SeqLab ' LBL 0' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
SeqLab DoL StrtPos DoR0 RapidF ' M99' EOL
ToolPath
END
END
{SetDrillEndOpZ}
Rapid {no output}
SeqLab DoL ZCP3 DoR0 RapidF DoM EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SaveProgNum2
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOff }
SetFlagF('3') { ArcFeat }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts? AND WorkFixtureOffsets?
SeqLab ' ; *** WARNING *** ' EOL
SeqLab ' ; THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS. ' EOL
SeqLab ' ; PLEASE SELECT EQUALLY SPACED OFFSETS. ' EOL
SeqLab ' ; *** WARNING *** ' EOL
END
RETURN

InitOp:
SeqLab ' BEGIN PGM ' Program# ' INCH' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'*( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'*( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'*( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'*( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'*( OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF PartsComment?
'*( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'*( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
RestoreScale
OpenSub
RETURN

FirstOp1:
SeqLab DoL ' Z0' DoR RapidF ' M91' EOL
IF ToolChangeAtHome?
SeqLab DoL Home DoR0 RapidF DoM EOL
END
Plane {no output}
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqLab ' TOOL DEF ' Tool# ' L' ToolLength# ' R' DIV# ToolDiameter# NUM#('2') EOL
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL
SeqLab DoR DoF ToolChng EOL
CheckPass
AbsValue Rapid {no output}
SeqLab DoL StrtPos DoR0 RapidF SpinOn EOL
SeqLab DoL ZCP1 DoR0 RapidF DoM EOL
RETURN

FirstOp3:
RETURN

NewToolOp1:
DoEndOpPS
SeqLab DoL ' Z0' DoR RapidF ' M91' EOL
IF ToolChangeAtHome?
SeqLab DoL Home DoR0 RapidF DoM EOL
END
IF LAST ProgStop?
SeqLab ' STOP M0' EOL
END
RETURN

NewToolOp2:
Plane {no output}
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
SeqLab ' TOOL DEF ' Tool# ' L' ToolLength# ' R' DIV# ToolDiameter# NUM#('2') EOL
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL
SeqLab DoR DoF ToolChng EOL
RETURN

NewToolOp4:
CheckPass
AbsValue Rapid {no output}
SeqLab DoL StrtPos DoR0 RapidF SpinOn EOL
SeqLab DoL ZCP1 DoR0 RapidF DoM EOL
RETURN

NewToolOp5:
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLab DoL ' Z0' DoR RapidF ' M91' EOL
SeqLab DoR DoF ' M0' EOL
END
RETURN

SameToolOp2: {Start new Operation}
Plane {no output}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
AbsValue Rapid {no output}
SeqLab DoL StrtPos DoR0 RapidF
IF LAST ProgStop?
SpinOn EOL
SeqLab DoL ZCP1 DoR0 RapidF DoM EOL
ELSE
DoM EOL
END
RETURN

End1:
DoEndOpPS
SeqLab DoL ' Z0' DoR RapidF ' M91' EOL
RETURN

End2:
SeqLab DoL ' X-15. Y0' DoR0 DoF ' M91' EOL
SeqLab ' STOP M2' EOL
RETURN

End3:
CloseSub
Post2 {organize Subs into one program}
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'*( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'*( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'*( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
SeqLab ' END PGM ' Program2# ' INCH' EOL
ASCII('3') EOL
Close
Retag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END