{Change Comments ***********************************************************}

{8/29/95
Modified: Heid TNC 155 Hkrt-Z M614.81.3
Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format.
Changed all literal ' M09' to CoolOff Command 4 places at FirstOperation, NewTool, SameTool, end of
IF Milling and end of IF Drilling.
Changed literal ' M05' to SpinOff Command at NewTool.
DWB}

{12/12/95, M614.85, Updated for Catalyst v2.20 per Fanuc 6M M001.85.02 Format, DWB}

{5/24/96, Updated to .89 format, MPK}

{5/20/97, Created for Croatia from above, as per Sample Code Provided.}

{03Jun97
Original: Heid TNC 407 M614_89F
Created: Heid TNC 407 Mxxx.15
For: Croatia Machine
Changes made per: J Sare
Updated to .15 Format per Fanuc 6M M001.15
Charles Winston}

{03Jun97
Original: Heid TNC 407 Mxxx.15
Created: Heid TNC 407 DX19.15
For: Croatia Machine
Changes made per: J Sare
Updated to .D Style Advanced Mill post Porcessor per Fanuc 6M (NW) D001.15
Charles Winston}

{23Sep97
Original: Heid TNC 407 DX19.15
Created: Heid TNC 407 DX19.15.1
For: Croatia Machine
Changes made per: Larry
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Formatting for ADD # and SUB# at Prog Numeric Format Definitions
Changed Formatting for ClearancePlane2# from FORMAT#7 to FORMAT#4
Changed SetMaxSeparateSubCalls from 50 to 0 in ProgStart ( Sep subs not wanted)
Added support for a "Section Repeats" ( no subs ) style of output instead of G92 subs
supported by StartRepeat, StdRepeat and MillingRepeat subs
Deleted the contents of FinishSubG92: {part 2} sub.
Modified G92Sub to support Section Repeats
Added support in Drill subs to output moves to ClearancePlane1 or ClearancePlane2
supported by a modified MasterOp, CallMasterOp and ToolPath subs
Note: Customers control does not have built-in Commands to do this.
Added SetFlagF('4') in ProgStart
Modified CSAngleA and CSAngleB subs to not output rotational moves greater than 360Ą,
Charles Winston}

{4Nov97
Original: Heid TNC 407 DX19.15.1
Created: Heid TNC 407 DX19.15.2
For: Croatia Machine
Changes made per: Larry Acchione
Added DoZCP1 to replace all calls to ZCP1, Adds the CSOffsetZ# to ClearancePlane1
Made all B-axis rotations positive
Added Literal 'LBL 0' to FinishSubG92
Changed MillingRepeat Sub to output only incremental Z moves
Added moves to return the tool to the start position when doing section repeats
Modified FirstOP and SameTool to send the Tool FullUp when Indexing the B-axis
Added ' W0' literal at the start of OpGuts to cancel the W+19 (W+19 sends the tool full up)
Added a tool call in SameToolOp3 to recall the tool when indexing with SameTool
Charles Winston}

{18Nov97
Original: Heid TNC 407 DX19.15.2
Created: Heid TNC 407 DX19.15.3
For: Croatia Machine

***NOTE***
This post should NOT be used as the basis for other Advanced Mill HeidenHain Posts.
It has been modified to output INCREMENTAL SECTION REPEATS instead of Z-repeats.
In addition, the post does not output FeedConnect or EntryExit Connect moves when doing Section Repeats
***NOTE***

Changes made per: Larry Acchione
Changed FORMAT#3 from 'ą###.###;0.' to 'ą###.###;ą0.' in Prog Numeric Format Definitions
Added TrackXNO# SPX# TrackYNO# SPY# at G92Sub
Deleted FinishSub1 in G92Sub, Absolute Z-moves are not allowed inside a Section Repeat
Added a Boolean to output Literal ' W0' at the start of Opguts IF SameTool is true
Put Axis rotations onto a seperate line at FirstOp2, NewToolOp3 and SameToolOp3
Deleted Speed Table in FirstOp2, NewToolOp3 amd MachSpec (No Longer required)
Added Literal ' W0' after DoZCP1 in FirstOp2 and NewToolOp4
Added Literal 'TOOL CALL 0' in SameToolOp3
Charles Winston}

{2/6/98,
Initial : Heid TNC 407 DX19.15.3
Created: Heid TNC 407 DX19.15.4
Customer: Croatia Machine

Changes to "Prog":

1. Changed #3 format of zero output from ą to +.
2. Removed WARNING output.
3. Changed FeedRate to FeedRateC (3 times) and ArcFeed to ArcFeedC (2 times).
4. Added a block with StrtPos as the first block in a milling repeat sub.
5. Added ' W+0' to the second block in a milling repeat sub.
6. Removed the last 2 blocks in a milling repeat sub and changed the one precede them.
The changed block will move the W-axis the distance between Surface Z and Floor Z
(Repeats# times RepeatZ#).
7. Added IF AChange? OR BChange? in NewTool so the rotary be output only when move.
8. Added IF AChange? OR BChange? in SameTool3 so full retract will be only when rotary
moves. If not, added motion to CPZ3.
9. Added W+0 to the motion to CPZ2 for SameTool & Drilling.
10. Checked taht W+19 is being output after all CALL TOOL 0 and W+0 after all the others.
11. For drilling in OpGuts, added M99 to the X & Y block and removed the block that
position to Clearance Plane #2 (the tool is already there).
12. For drilling in ToolPath, added M99 to X & Y if retract to CPZ2 and removed the
block that position to Clearance Plane #2.
13. Changed ' Z' ClearancePlane #1 to DoZCP1 for drilling.
14. Added FORMAT #11 for MUL# in repeat cycles.
JHE}

{2/18/98,
Initial : Heid TNC 407 DX19.15.4
Created: Heid TNC 407 DX19.15.5
Customer: Croatia Machine

Changes to "Prog":

1. Changed CSAngleA & CSAngleB so that motions to rotary 0 location when the last
location was greater than 180 will be with +360 (was +0).
2. Added Save# Num#('2'), '3', & '4' to support the above.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = 'ą###.###;+0.' {Changed ą to + - JHE}
#4 = 'ą####0.####;+0'
#5 = '#######0'
#6 = '####0.000'
#7 = '+####0.0000'
#8 = '###^0'
#9 = 'ą*####0.###;+0'
#10 = 'ą####0.000#;+0'
#11 = '+####0.####;+0' {Added - JHE}


FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ABS#,2)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(DIV#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(XStockMin#,4)
FORMAT(XStockMax#,4)
FORMAT(YStockMin#,4)
FORMAT(YStockMax#,4)
FORMAT(ZStockMin#,4)
FORMAT(ZStockMax#,4)
FORMAT(ADD#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(ZDepth#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnShiftPX#,4)
FORMAT(OriginUnShiftPY#,4)
FORMAT(OriginUnShiftPZ#,4)
FORMAT(OriginUnShiftRX#,4)
FORMAT(OriginUnShiftRY#,4)
FORMAT(OriginUnShiftRZ#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TLDia#,4)
FORMAT(TLLength#,4)
FORMAT(TLNum#,5)
FORMAT(CallMasterNum#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(SUB#,5)
FORMAT(Program2#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(ZDepthInc#,7)
FORMAT(Peck#,9)
FORMAT(FeedEntry#,8)
FORMAT(RapidF#,8)
FORMAT(CalcCP2FmSurf#,9)
FORMAT(CalcZFmSurf#,4)
FORMAT(MUL#,11)


{Special Subs **************************************************************}

DoL:
' L'
RETURN

DoZL:
' L'
RETURN

Space: { 0 Spaces }
''
RETURN

XYZSpace:
'' Space
RETURN

XYSpace:
'' Space Space
RETURN

ZSpace:
'' Space Space Space
RETURN

IXYZSpace:
Space
RETURN

IXYSpace:
Space Space
RETURN

IZSpace:
Space Space Space
RETURN

DoR0:
IF NOT Flag?('3') { ArcFeat }
''
END
IF Flag?('2') { CutterRadiusCompensation }
IF CRCleft?
' RL'
ELSE
' RR'
END
ELSE
' R0'
END
RETURN

RF: { RapidF }
' F MAX'
RETURN

DoM:
{
' M'}
RETURN

ckCRCOff:
IF Flag?('2') { CRCOn }
SetFlagF('2')
SeqLab DoL ' IX+0 IY+0' IXYSpace DoR0 RF DoM EOL
END
RETURN

DoZCP1:
' Z' Add# ClearancePlane1# CSOffsetZ#
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? { CAM file is in Metric, tools and tool path }
SetScale('.03937007874') { change to English, this is an English post }
ELSE
SetScale('1')
END
RETURN

WFONum:
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN


DoSubComment:
IF UseComments? AND SubComment?
SeqLab ' LBL 0; SUB NUMBER: ' Program# EOL
END
RETURN

DoCSComment:
IF AAxisAvail? OR BAxisAvail?
SeqLab ' ; CS# ' CS# ' - ' CSComment$ EOL
END
RETURN

OffsetComments:
IF ChangeCS?
DoCSComment
ELSE
IF NOT SameTool?
DoCSComment
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab ' ; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
SeqLab ' ; ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab ' ; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
SeqLab ' ; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
SeqLab ' ; ' ToolComment$ EOL
END
RestoreScale
END
OffsetComments
RETURN

CSAngleA:
IF AAxisAvail? {output A from 0 thru 360}
' A'
Save# Num#('1') TRUNC# DIV# CSOffsetA# Num#('360')
{var#1 = number of full 360 deg rotations (an integer)}
Save# Num#('2') DIV# CSOffsetA# Num#('360')
{var#2 = number of rotations (360 deg = 1 rotation)}
{if var#1 = var#2 the rotary is at 0 location}
IF Equal? Recall# Num#('1') Recall# Num#('2') AND NOT FirstOperation?
IF GreaterThan? Recall# Num#('3') Num#('180')
'+360.'
ELSE
'+0.'
END
Save# Num#('3') Num#('0')
ELSE
IF LessThan? CSOffsetA# Num#('0') {rotary at '-' direction}
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
{for motions to the '-' direction, the output will be 360 minus
the location. i.e. the output for -90 will be 270.}
END
FORMAT(SUB#,3)
SUB# CSOffsetA# MUL# Recall# Num#('1') Num#('360')
FORMAT(SUB#,5)
Save# Num#('3') SUB# CSOffsetA# MUL# Recall# Num#('1') Num#('360')
{var#3 = the current A rotary location}
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail? {output B from 0 thru 360}
' B'
Save# Num#('1') TRUNC# DIV# CSOffsetB# Num#('360')
{var#1 = number of full 360 deg rotations (an integer)}
Save# Num#('2') DIV# CSOffsetB# Num#('360')
{var#2 = number of rotations (360 deg = 1 rotation)}
{if var#1 = var#2 the rotary is at 0 location}
IF Equal? Recall# Num#('1') Recall# Num#('2') AND NOT FirstOperation?
IF GreaterThan? Recall# Num#('4') Num#('180')
'+360.'
ELSE
'+0.'
END
Save# Num#('4') Num#('0')
ELSE
IF LessThan? CSOffsetB# Num#('0') {rotary at '-' direction}
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
{for motions to the '-' direction, the output will be 360 minus
the location. i.e. the output for -90 will be 270.}
END
FORMAT(SUB#,3)
SUB# CSOffsetB# MUL# Recall# Num#('1') Num#('360')
FORMAT(SUB#,5)
Save# Num#('4') SUB# CSOffsetB# MUL# Recall# Num#('1') Num#('360')
{var#4 = the current B rotary location}
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqLab DoZL
IF NOT AbsValue?
' IZ' SPZ# IZSpace
ELSE
ZIn ZSpace
END
DoR0
IF FeedEntry?
Feed {no output}
FeedEnt ''
ELSE
RF
END
DoM EOL
RETURN

StartSub:
OpenSub
DoSubComment
SeqLab ' LBL ' Program# EOL
RETURN

StartRepeat:
SeqLab ' LBL ' Program# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab ' ; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# ' REP ' Repeats# '/ ' Repeats# EOL
StartSub
RETURN

StdRepeat:
SeqLab ' CALL LBL ' Program# ' REP ' SUB# Repeats# NUM#('1') '/ ' SUB# Repeats# NUM#('1') EOL
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt ''
ELSE
RF
END
END
DoM EOL
END
ckCRCOff
RETURN

FinishSubG92: {part 2}
SeqLab ' LBL 0' EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# ' REP ' Parts# ' / ' Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftY# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftZ# EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPZ#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

DoHelix:
SetAbs
'P IPA'
IF ArcCW?
'-'
ELSE
'+'
END
IF Equal? EPMoveAngle# SPMoveAngle# { Full Circle }
'360.000'
ELSE
ABS# SUB# EPMoveAngle# SPMoveAngle#
END
SetInc
IF XYPlane?
' IZ' EPZ#
ELSE
IF XZPlane?
' IY' EPY#
ELSE { YZPlane }
' IX' EPX#
END
END
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF AutoCycle?
SetInc
ELSE
SetAbsOrInc
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XYPlane?
IF XMove? OR YMove? OR ArcFeat?
' IX' EPX# ' IY' EPY#
IF ZMove?
' IZ' EPZ# IXYZSpace
ELSE
IXYSpace
END
ELSE
IF ZMove?
' IZ' EPZ# IZSpace
TrackZNO# EPZ#
END
END
ELSE
IF XZPlane?
IF XMove? OR ZMove? OR ArcFeat?
IF YMove?
' IX' EPX# ' IY' EPY# ' IZ' EPZ# IXYZSpace
ELSE
' IX' EPX# ' IZ' EPZ# IXYSpace
END
ELSE
IF YMove?
' IY' EPY# IZSpace
END
END
ELSE { YZPlane }
IF YMove? OR ZMove? OR ArcFeat?
IF XMove?
' IX' EPX# ' IY' EPY# ' IZ' EPZ# IXYZSpace
ELSE
' IY' EPY# ' IZ' EPZ# IXYSpace
END
ELSE
IF XMove?
' IX' EPX# IZSpace
END
END
END
END
ELSE
IF XYPlane?
IF XMove? OR YMove? OR ArcFeat?
MoveX MoveY
IF ZMove?
MoveZC XYZSpace
ELSE
XYSpace
END
ELSE
IF ZMove?
MoveZC ZSpace
END
END
ELSE
IF XZPlane?
IF XMove? OR ZMove? OR ArcFeat?
IF YMove?
MoveX MoveY MoveZ XYZSpace
ELSE
MoveX MoveZ XYSpace
END
ELSE
IF YMove?
MoveY ZSpace
END
END
ELSE { YZPlane }
IF YMove? OR ZMove? OR ArcFeat?
IF XMove?
MoveX MoveY MoveZ XYZSpace
ELSE
MoveY MoveZ XYSpace
END
ELSE
IF XMove?
MoveX ZSpace
END
END
END
END
END
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF LastFeat?
SetFlagF('2') { CRCOff }
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOn }
END
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

FormatArc:
DoAbsOrInc
SeqLab ' CC'
IF AutoCycle? OR NOT AbsValue? {implies incremental}
' IX' ArcI# ' IY' ArcJ#
ELSE
ArcIJ
END
EOL
SeqLab ' C'
IF XYPlane? AND ZMove?
DoHelix
ELSE
IF XZPlane? AND YMove?
DoHelix
ELSE
IF YZPlane? AND XMove?
DoHelix
ELSE
CheckMove
END
END
END
IF ArcCW?
' DR-' CWArc {no output}
ELSE
' DR+' CCWArc {no output}
END
SetFlag('3')
DoR0
SetFlagF('3')
RETURN

FormatLine:
IF ZMove? AND NOT XMove? AND NOT YMove?
DoZL
ELSE
DoL
END
DoAbsOrInc CheckMove CkCRC DoR0
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF NOT FirstFeat?
Rapid {no output}
IF AutoCycle?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
ELSE
SeqLab DoL DoDrillAbsOrInc
IF AbsValue?
MoveSX MoveSY
IF SPZMove? AND NOT Flag?('4')
MoveSZ XYZSpace
ELSE
XYSpace
END
ELSE
' IX' SPX# ' IY' SPY# ' IZ' SPZ# IXYZSpace
END
DoR0 RF
IF NOT RetractToCP1? {Added this check and M99 - JHE}
' M99'
END
EOL
IF Drilling?
IF RetractToCP1?
SeqLab DoZL ' Z' ClearancePlane2# ZSpace DoR0 RF ' M99' EOL
IF NOT LastFeat?
SeqLab DoZL DoZCP1 ZSpace DoR0 RF EOL {Changed ' Z' ClearancePlane1# with DoZCP1 - JHE}
END
ELSE
{SeqLab DoZL ' Z' ClearancePlane2# ZSpace DoR0 RF ' M99' EOL} {Removed - JHE}
END
END
END
END
IF AutoCycle?
SeqLab ' CALL LBL ' Program# ' REP' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
Rapid {no output}
IF XMove? OR YMove? OR ZMove?
SeqLab FormatLine RF DoM EOL
END
ELSE
IF LineFeat?
Feed {no output}
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRateC '' DoM EOL {Added C to FeedRate - JHE}
DecelMove2
END
SeqLab FormatLine DecelFeed '' DoM EOL
ELSE
SeqLab FormatLine FeedRateC '' DoM EOL {Added C to FeedRate - JHE}
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeedC '' DoM EOL {Added C to ArcFeed - JHE}
DecelMove2
END
FormatArc DecelFeed '' DoM EOL
ELSE
FormatArc ArcFeedC '' DoM EOL {Added C to ArcFeed - JHE}
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
FeedEnt ''
ELSE
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
SetAbs
ToolPath
END
RETURN

MillingRepeat:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
SetAbs {Added this line - JHE}
SeqLab DoL StrtPos XYSpace DoR0 RF EOL {Added this line - JHE}
SetInc {Added this line - JHE}
SeqLab DoZL ' IZ' SPZ# ' W+0' IZSpace DoR0 {Added ' W+0' - JHE} {Incremental EntryMove}
IF FeedEntry?
Feed {no output}
FeedEnt ''
ELSE
RF
END
DoM EOL
SetAbs
SetFlag('1')
ToolPath
SetFlagF('1')
END
RETURN

G92Sub:
{SubWarning} {Removed warning output - JHE}
SetAbs
SeqLab DoL ' Z'ADD# SPZ# ABS# RepeatZ# XYSpace
IF FeedConnect?
FeedEnt ''
ELSE
RF
END
DoM
TrackZNO# ADD# SPZ# ABS# RepeatZ# EOL
StartRepeat
SetInc
MillingRepeat
SeqLab DoL ' IW+' MUL# Repeats# ABS# RepeatZ# XYSpace DoR0 RF DoM EOL
{Changed IZ to IW and RepeatZ# to MUL# Repeats# ABS# RepeatZ# - JHE}
{SeqLab DoL ' IZ+' ABS# RepeatZ# XYSpace DoR0 RF DoM EOL} {was this line - JHE}
{SeqLab DoL StrtPos XYSpace CRCOff DoR0 RF EOL} {Removed this line - JHE}
{TrackXNO# SPX# TrackYNO# SPY# EOL} {Removed this line - JHE}
{SeqLab DoL ' IZ' RepeatZ# XYSpace DoR0 RF DoM EOL} {Removed this line - JHE}
FinishSubG92
{ FinishSub1 }
SetAbs
StdRepeat
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc {Added C to FeedRate - JHE}
SeqLab DoL ' IX' SPX# ' IY' SPY# IXYSpace DoR0 FeedRateC '' DoM EOL
AbsOrInc
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# DoR0 RF DoM EOL
AbsOrInc
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
ELSE
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
ELSE
IF FeedEntry?
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
Rapid {no output}
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
FeedEnt ''
ELSE
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
FeedEnt ''
ELSE
RF
END
DoM EOL
END
IF FeedConnect?
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
Rapid {no output}
SeqLab DoZL ZCP2PlusIncC ZSpace DoR0 RF DoM EOL
END
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLab DoZL ZCP2
IF SameTool?
' W+0'
END
ZSpace DoR0 RF DoM EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt ''
ELSE
RF
END
END
END
{CoolOff} EOL
SeqLab DoL DoZCP1 RF EOL
ckCRCOff
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
SeqLab DoZL ZCP2
IF SameTool? {Added this check and W+0 - JHE}
' W+0'
END
ZSpace DoR0 RF EOL
GetCycle
IF RigidTap?
SeqLab ' CYCL DEF 17.0 RIGID TAP ' EOL
SeqLab ' CYCL DEF 17.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 17.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 17.3 DWELL 0' EOL
ELSE
IF Tap?
SeqLab ' CYCL DEF 2.0 TAPPING ' EOL
SeqLab ' CYCL DEF 2.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 2.3 DWELL 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SET UP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
Peck#
ELSE
CalcZFmSurf#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
END
IF CallMasterOp?
SeqLab ' CALL LBL ' CallMasterNum# ' REP' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlagF('1') {NOT std sep sub Zreps in effect}
SetFlag('4') {Drill Sub in effect}
NewMasterProg
SeqLab ' CALL LBL ' Program# ' REP' EOL
StartSub
SeqLab DoL StrtPos XYSpace DoR0 RF ' M99' EOL {Added ' M99' - JHE}
IF RetractToCP1?
{SeqLab DoZL ' Z' ClearancePlane2# ZSpace DoR0 RF ' M99' EOL} {Removed - JHE}
SeqLab DoZL DoZCP1 ZSpace DoR0 RF EOL {Changed ' Z' ClearancePlane1# with DoZCP1 - JHE}
ELSE
{SeqLab DoZL ' Z' ClearancePlane2# ZSpace DoR0 RF ' M99' EOL} {Removed - JHE}
END
ToolPath
SeqLab ' LBL 0' EOL
CloseSub
SetFlagF('4') {NOT Drill sub }
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
SetFlag('4') {Drill Sub in effect}
SeqLab DoL StrtPos XYSpace DoR0 RF ' M99' EOL {Added ' M99' - JHE}
IF RetractToCP1?
{SeqLab DoZL ' Z' ClearancePlane2# ZSpace DoR0 RF ' M99' EOL} {Removed - JHE}
SeqLab DoZL DoZCP1 ZSpace DoR0 RF EOL {Changed ' Z' ClearancePlane1# with DoZCP1 - JHE}
ELSE
{SeqLab DoZL ' Z' ClearancePlane2# ZSpace DoR0 RF ' M99' EOL} {Removed - JHE}
END
ToolPath
SetFlagF('4') {NOT Drill sub }
END
END
{SetDrillEndOpZ}
Rapid {no output}
SeqLab DoZL ZCP3 ZSpace DoR0 RF {CoolOff} EOL
SeqLab DoL DoZCP1 RF EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls('0')
SetMaxRPM('10000')
SaveProgNum2
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOff }
SetFlagF('3') { ArcFeat }
SetFlagF('4') { Drill subs }
Save# Num#('1') Num#('0') {number of full 360 deg rotations (an integer)}
Save# Num#('2') Num#('0') {number of rotations (360 deg = 1 rotation)}
Save# Num#('3') Num#('0') {the current A rotary location}
Save# Num#('4') Num#('0') {the current B rotary location}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts? AND WorkFixtureOffsets?
SeqLab ' ; *** WARNING *** ' EOL
SeqLab ' ; THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS. ' EOL
SeqLab ' ; PLEASE SELECT EQUALLY SPACED OFFSETS. ' EOL
SeqLab ' ; *** WARNING *** ' EOL
END
RETURN

InitOp:
'0 BEGIN PGM ' ProgramName$ ' INCH' EOL
IF ToolChangeAtHome?
SetHome
END
SeqLab ' BLK FORM 0.1 Z X' XStockMin# ' Y' YStockMin# ' Z' ZStockMin# EOL
SeqLab ' BLK FORM 0.2 X' XStockMax# ' Y' YStockMax# ' Z' ZStockMax# EOL
IF UseComments?
IF ProgramNameComment?
SeqLab ' ; PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
SeqLab ' ; ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLab ' ; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab ' ; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab ' ; OUTPUT IN ABSOLUTE INCHES' EOL
END
IF PartsComment?
SeqLab ' ; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLab ' ; FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SetAbs
Plane Rapid {no output}
EachTool
SetScale('1')
SeqLab ' TOOL DEF ' TLNum# ' ;'
RestoreScale
DoL TLLength#
' R' DIV# TLDia# Num#('2') { TLRadius# }
EOL
NextTool
RestoreScale
DoOpComments
DoPostScript
RETURN

FirstOp2:
IF NOT LastTool?
SeqLab ' TOOL CALL 0' EOL
SeqLab ' L Z0 W+19 R0 F MAX M05' EOL
SeqLab DoL Home XYSpace DoR0 RF ' M06' EOL
END
SeqLab CSAngleA CSAngleB ' F MAX' EOL
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL
{SeqLab DoL Home DoR0 RF DoM EOL}
CheckPass
SeqLab DoL StrtPos XYSpace CRCOff DoR0 RF SpinOn EOL
SeqLab DoL DoZCP1 ' W+0' DoR0 RF DoM EOL
RETURN

FirstOp3:
RETURN

NewToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END
RETURN

NewToolOp2:
SetAbs
Plane Rapid {no output}
RETURN

NewToolOp3: {Start new Operation}
SeqLab ' TOOL CALL 0' EOL
SeqLab ' L Z0 W+19 R0 F MAX M05' EOL
SeqLab DoL Home XYSpace DoR0 RF ' M06' EOL
DoOpComments
DoPostScript
IF AChange? OR BChange? {Added this check - JHE}
SeqLab CSAngleA CSAngleB ' F MAX' EOL
END
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL
RETURN

NewToolOp4:
{SeqLab DoL Home DoR0 RF DoM EOL}
CheckPass
SeqLab DoL StrtPos XYSpace CRCOff DoR0 RF SpinOn EOL
SeqLab DoL DoZCP1 ' W+0' DoR0 RF DoM EOL
RETURN

NewToolOp5:
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SetAbs
Plane Rapid {no output}
IF AChange? OR BChange? {Added this check - JHE}
SeqLab ' TOOL CALL 0' EOL
SeqLab ' L Z0 W+19 R0 F MAX M05' EOL
SeqLab DoL Home XYSpace DoR0 RF EOL
SeqLab CSAngleA CSAngleB ' F MAX' EOL
ELSE
SeqLab DoZL ZCP3 ZSpace DoR0 RF DoM EOL {Added this line - JHE}
END
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL {Moved this line up - JHE}
SeqLab DoL StrtPos XYSpace CRCOff RF SpinOn EOL
RETURN

End1:
DoEndOpPS
Rapid {no output}
SeqLab ' TOOL CALL 0' EOL
SeqLab ' L Z0 W+19 R0 F MAX M05' EOL {Added W+19 - JHE}
SeqLab DoL Home XYSpace DoR0 RF EOL
RETURN

End2:
SeqLab ' STOP M30' EOL
RETURN

End3:
Post
Close
Reopen
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLab ' ; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
SeqLab ' ; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
SeqLab ' ; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
SetScale('1') {restore scale for comments}
END

SeqLab ' END PGM ' Program2# ' INCH' EOL
ASCII('3') EOL
Close
Retag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level *************************}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END