{Change Comments ***********************************************************}

{11/9/89
Copied & modified: Okuma OSP 3000 LB20 L067.56
For: Mike Kenney Tool
Machine: Okuma LB20
Control: Okuma OSP 3000
Changed Seq to SeqLab & added ReTag.
Added Special 1st block for DNC.
Changed literal ' M42' to GearRange, 'M41' for 0 to 1000 RPM.
Madified RoughContour CannedCycle start blocks & added AutoFinish.
Needed for CannedCycle changes.
Modified Threading CannedCycle.
Output FeedRate on non-Threading Operation start blocks only.
Modified Drilling CannedCycles for Pecking & Tapping.
Added special last blocks for customer file info and DNC.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{9/26/91
Modified: Okuma 3000 LB20 [MK] L134.62
For: Mike Kenney Tool
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
CannedCycles supported are RoughContour, RoughPattern, Threading, Tapping and both types of Pecks.
DWB}

{5/24/93
Modified: Okuma 3000 LB20 [MK] L134.82
For: Mike Kenney Tool
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
Changed to Decimal Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^#0'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPX#,2)
FORMAT(Peck#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

CheckFeed:
IF NOT Threading?
FeedRate
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
DoPostScript
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
DoPostScript
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
DoPostScript
FaceApproachSP
END
END
RETURN

CheckGear:
IF NewGear?
SpinOn
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqLabC LOfstOff '00' SpinOff EOL
SeqLabC OpToolID LatheOffset GearRange EOL
ELSE
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
ELSE
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC CheckGear EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPathPrim:
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF NOT CannedCycle?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 F200' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
END
END
ToolPathPrim
END
ELSE
ToolPathPrim
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

DNCAscii: { 25 Total }
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
DNCAscii '$' ProgID1 '.MIN' EOR DNCAscii EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
Plane
SeqLab
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset SpinOn CoolOn GearRange CheckFeed EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC
IF LAST ConstantSurfaceFeed?
CSSOff ' G97' CalcRPM2
END
IF NewGear?
SpinOff
END
EOL
SeqLabC NewHome
IF LAST ProgStop?
' M0'
ELSE
ProgStop
END
EOL

{Start new Operation}

DoOpComments
SeqLab
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset SpinOn CoolOn GearRange CheckFeed EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC CheckFeed EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn ' G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
ToolPath
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle ' Nł' Tag# CutDepth XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab ' G82' EOL
ELSE
SeqLab ' G81' EOL
END
SeqLabC StrtPos EOL
ToolPath
SeqLabC ' G80' EOL
SeqLabC Rapid XCSPC ZCSPC EOL
IF AutoFinish?
SeqLabC ' G87' ' Nł' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle EOL
IF ApproachFace?
SeqLabC ' G82' EOL
SeqLabC Rapid ZminusW XStkLeft ZStkLeft EOL
ELSE
SeqLabC ' G81' EOL
SeqLabC Rapid XminusU XStkLeft ZStkLeft EOL
END
SeqLabC StrtPos EOL
ToolPath
SeqLabC ' G80' EOL
SeqLabC Rapid XCSPC ZCSPC EOL
IF AutoFinish?
SeqLabC RapidC XSPC ZSPC EOL
ToolPath
SeqLabC RapidC XCSPC ZCSPC EOL
END
END
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading? {does not support tapered threads}
IF Chamfer?
SeqLabC ' M23' EOL
END
IF ConstantVolumeCut?
SeqLabC LCycle XatFinZ FinZ ToolAngle CutDepth ThrdHeight ThrdLead EOL
SeqLabC Rapid XCSPC EOL
SeqLabC ZCSPC EOL
IF AutoFinish?
SeqLabC ' G33' XatFinZ FinZ ThrdLead EOL
SeqLabC Rapid XCSPC EOL
SeqLabC ZCSPC EOL
END
ELSE
SeqLabC ' G33 X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
IF AutoFinish?
SeqLabC XatFinZ EOL
END
SeqLabC Rapid XCSPC EOL
SeqLabC ZCSPC EOL
END
IF Chamfer?
SeqLabC ' M22' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ' X0000' ZDepth FeedRate EOL
SeqLabC Rapid ZSP EOL
ELSE
IF Peck?
SeqLabC LCycle ' X0000' ZDepth Peck
IF PeckFullRetract?
' L' Peck#
END
Dwell FeedRate EOL
SeqLabC Rapid ZSP EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
END
SeqLabC StockOff StrtPosC EOL
ToolPath
END
END
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC SpinOff EOL
SeqLabC ' G4 F200' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqLabC FirstHome
IF ProgStop?
' M0'
ELSE
ProgStop
END
EOL
SeqLabC EOP EOL
Post
'( MACHINE CYCLE TIME = )' EOL
'( PART TO PART TIME = )' EOL
'( PARTS PER HOUR = )' EOL
EOR DNCAscii EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END