{Change Comments ***********************************************************}

{11/17/89
Copied & modified: Okuma OSP 3000 LC10 L069.56
For: Mike Kenney Tool
Made minor changes per marked up readout.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/23/91
Modified: Okuma 3000 LC10 [MK] L135.62
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All Canned Cycles are supported except RoughSimple.
This Post Processor does not support Threading Taper output when ConstantVolumeCut = FALSE.
Added Math to remove any Taper value compensation from Canned Threading Cycle.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '####^###0'
#3 = '########;0'
#4 = '###^#0'
#5 = '#^######;0.'
#6 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(DistanceToThread#,2)
FORMAT(DiaDistanceToThread#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

CheckFeed:
IF NOT Threading?
IF SameTool?
IF LAST NOT StraightConnect?
FeedRate
END
ELSE
FeedRate
END
END
RETURN

CheckSameToolFeed:
IF SameTool?
IF NOT Threading?
FeedRate
END
END
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

Approach: { NOT FOR TAILSTOCK, .69.8 }
StockOff
IF NOT SameTool?
SeqC
IF ApproachOD?
XCP
ELSE
IF ApproachID?
XOpCD
ELSE {ApproachFace}
StockOnNoCan XSP StockOff
END
END
ZCP EOL
END
IF ApproachOD?
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
SeqC Feed StockOnNoCan XSPC CheckSameToolFeed EOL
ELSE
IF ApproachID?
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqC Feed StockOnNoCan XSPC CheckSameToolFeed EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
SeqC Feed StockOnNoCan ZSPC CheckSameToolFeed EOL
END
END
RETURN

CheckSpinOn:
IF LAST ProgStop?
SpinOn
END
RETURN

CheckCoolant:
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqC SpeedC CheckSpinOn CheckCoolant EOL
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn ' G96' Speed CheckSpinOn CheckCoolant EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff ' G97' Speed CheckSpinOn CheckCoolant EOL
ELSE
SeqC SpeedC CheckSpinOn CheckCoolant EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPathPrim:
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF NOT CannedCycle?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC ' G4 F200' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC ' G4 F' Dwell# EOL
END
END
END
ToolPathPrim
END
ELSE
ToolPathPrim
END
NEXTFeat
RETURN

CheckRapid1:
IF LAST NOT ApproachID?
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
END
RETURN

CheckRapid2:
IF CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'%' ProgID1 '%' EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsOrInc EOL
IF ConstantSurfaceFeed?
SeqC Preset MaxRPM EOL
END
SeqC Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset SpinOn CoolOn ' M44' CheckFeed EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid1
IF LAST ApproachOD?
SeqC XCPC EOL
END
SeqC ZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqC CSSOff ' G97' CalcRPM2 EOL
END
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq
IF ConstantSurfaceFeed?
SeqC Preset MaxRPM EOL
END
SeqC Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset SpinOn CoolOn ' M44' CheckFeed EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqC XOpECDC EOL
ELSE {around}
SeqC ZCPC EOL
SeqC XCPC EOL
END
ELSE
IF LAST ApproachOD?
SeqC XCPC EOL {around}
END
IF ApproachID?
IF LAST NOT ApproachID?
SeqC ZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC ZOpECPC EOL
ELSE
SeqC ZCPC EOL
END
END
END
CheckOffset
Approach
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqC CSSOn ' G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass2
SeqC LCycle EOL
IF ApproachFace?
SeqC ' G82' EOL
END
SeqC StepMove CutDepth XStkLeft ZStkLeft EOL
SeqC StrtPos EOL
ToolPath
SeqC ' G80' EOL
IF AutoFinish?
SeqC StepMove XSPC ZSPC EOL
ToolPath
END
SeqC RapidC XCSPC ZCSPC EOL
ELSE
IF RoughPatternShift?
SetPass2
SeqC LCycle EOL
IF ApproachFace?
SeqC ' G82' EOL
END
SeqC Rapid
IF ApproachFace?
ZminusW
ELSE
XminusU
END
XStkLeft ZStkLeft EOL
SeqC StrtPos EOL
ToolPath
SeqC ' G80' EOL
IF AutoFinish?
SeqC Rapid XSPC ZSPC EOL
ToolPath
END
SeqC Rapid XCSPC ZCSPC EOL
END
END
ELSE
IF Threading?
IF Chamfer?
SeqC ' M23' EOL
END
IF ConstantVolumeCut?
SeqC LCycle EOL
SeqC CutDepth ' E' DiaDistanceToThread# EOL
SeqC ' G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqC ' G80' EOL
SeqC Rapid XCSPC EOL
SeqC ZCSPC EOL
IF AutoFinish?
SeqC ' G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqC Rapid XCSPC EOL
SeqC ZCSPC EOL
END
ELSE { Does not support Tapered output }
SeqC ' G33'

{ FORMULA removes any Taper# value compensation from FirstMoveEPX# }

IF ApproachOD?
' X' ADD# FirstMoveEPX# MUL# Taper# NumSc#('-2')
ELSE
IF ApproachID?
' X' ADD# FirstMoveEPX# MUL# Taper# NumSc#('2')
END
END

FinZ ThrdLead EOL
SimpleRough
SeqC XatFinZ EOL
IF AutoFinish?
SeqC XatFinZ EOL
END
SeqC Rapid XCSPC EOL
SeqC ZCSPC EOL
END
IF Chamfer?
SeqC ' M22' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth FeedRate EOL
SeqLabC SpinOff EOL
SeqLabC ' G4 F200' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck?
SeqC ' G83' EOL
SeqC ' G82' EOL
SeqC Peck ' E0.' EOL
SeqC Feed ZDepth FeedRate EOL
SeqC ' G80'
SeqC Rapid ZSP EOL
IF AutoFinish?
SeqC Feed ZDepth EOL
IF Dwell?
SeqC ' G4 F' Dwell# EOL
END
SeqC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC ' G4 F200' EOL
SeqC Speed SpinOn EOL
END
IF ApproachID? {.71.2}
CheckRapid2
SeqC XOpECDC EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF NOT ApproachID? {.71.2}
CheckRapid2
END
IF ApproachOD?
SeqC XCPC EOL
END
SeqC ZCPC EOL
DoEndOpPS
SeqC CoolOff EOL
IF ConstantSurfaceFeed?
SeqC CSSOff ' G97 S' CalcEPRPM# EOL
END
IF ProgStop?
SeqC ' M0' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END