{Change Comments ***********************************************************}

{1/27/92
Copied & modified: Okuma OSP 3000 LC10 L069.82
For: Berkeley Computers
Machine: Okuma LC10
Control: OSP 3000L
Made changes per supplied manual.
Only CannedCycles supported are RoughContour, RoughPatternShift and Non-Tapered Threading.
Deleted Drilling from CannedCycles.
Changed to Metric.
Changed all Seq to SeqLab, and added 'N?' to Form.
Added GearRange support, changed all literal 'M44' to GearRange.
Added Rapid and Feed following all 'G04' Dwell output where needed.
Modified RoughContour and RoughPatternShift CannedCycles to support AutoFinish.
Using Variables 1, 2 & 3 to assist in correct Retag of LineNumbers.
Added formula to output DiaDistanceToThread# which fails to add in ToolTip.
Using Variable 4 to store the value, and formual MULtiplies to SetScale.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####^##0;00'
#3 = '########;0'
#4 = '####^0'
#5 = '2#####^##0;00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(ZCutDepth#,2)
FORMAT(FeedIPR#,2)
FORMAT(Recall#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(XCutDepth#,5)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

AppMove:
ZCP OpToolID LatheOffset CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqLabC XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC OpToolID LatheOffset EOL
END
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST NOT ConstantSurfaceFeed?
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
SeqLabC SpeedC
IF LAST ProgStop?
SpinOn CoolOn
ELSE
IF NewGear?
SpinOn
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04F200' EOL
SeqLabC Feed Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04F' Dwell# EOL
IF RapidFeat?
Rapid
ELSE
Feed
END
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
IF XMove? OR ZMove?
SeqLabC FormatArc FeedRateC EOL
END
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('4500')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' METERS )' EOL
END
END
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab 'M01' EOL { Initial ProgStop }
SeqLabC Rapid AbsOrInc Preset Home 'S4500' EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn GearRange EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC LAST Home EOL

{Start new Operation}

SeqLab OpToolID '00'
IF LAST ProgStop?
'M00'
ELSE
ProgStop
END
EOL
DoOpComments
DoPostScript
SeqLabC Rapid Preset Home 'S4500' EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn
IF NewGear?
GearRange
END
EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF AutoFinish?
TagInc
Save# Num#('1') Tag#
TagInc
Save# Num#('2') Tag#
TagInc
Save# Num#('3') Tag#
END
SetPass2
SeqLabC LCycle
IF ApproachFace?
EOL
SeqLabC 'G82'
END
IF AutoFinish?
'Qł' Recall# Num#('2') EOL
'>' Recall# Num#('1') EOL
SeqLab
ELSE
EOL
END
IF RoughContour?
SeqLabC StepMove CutDepth XStkLeft ZStkLeft EOL
ELSE
IF RoughPatternShift?
SeqLabC Rapid
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
XStkLeft ZStkLeft EOL
END
END
SeqLabC StrtPos EOL
ToolPath
SeqLabC 'G80'
IF AutoFinish?
'Qł' Recall# Num#('3') EOL
'>' Recall# Num#('2') EOL
SeqLab
ELSE
EOL
END
SeqLabC Rapid XCSPC ZCSPC EOL
IF AutoFinish?
SeqLabC 'G87Qł' Recall# Num#('1')
'>' Recall# Num#('3') EOL
SeqLab
END
ELSE
IF Threading?
IF Taper?
'( This Post Processor does not support Tapered Threads )' EOL
ELSE
IF SingleEdgeCut? OR ConstantVolumeCut?
SeqLabC LCycle EOL
SetScale('1')
IF ToolTipProgram?
Save# Num#('4') ADD# ToolDiameter# DiaDistanceToThread#
ELSE
Save# Num#('4') DiaDistanceToThread#
END
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
SeqLabC CutDepth 'E' MUL# Recall# Num#('4') NumSc#('1') EOL
SeqLabC 'G33' XatFinZ FinZ ThrdLead EOL
SeqLabC 'G80' EOL
IF AutoFinish?
SeqLabC 'G33' XatFinZ FinZ ThrdLead EOL
END
ELSE
SeqLabC 'G33X' FirstMoveEPX# FinZ ThrdLead EOL
TrackXNO# FirstMoveEPX#
EachFeat
IF ThreadFeat? AND XMove?
SeqLabC MoveX FinZ EOL
END
NextFeat
IF AutoFinish?
SeqLabC XatFinZ FinZ EOL
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04F200' EOL
SeqLabC Rapid Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC Home EOL
SeqLabC UnTool '00' SpinOff CoolOff
IF ProgStop?
'M00'
END
EOL
SeqLabC EOP EOL
Post
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END