{Change Comments ***********************************************************}

{6/25/93
Copied & modified: Fanuc 6T Mazak L217.82.1
For: IDESSYS

This Post Processor was created by Michel JEAN FRANCOIS at IDESSYS and during transfer
to ABELSYS, the source code was lost. The Form was decompiled, restored and fully tested
as best as possible. The following comments were reported by Daniel Ball of Gibbs & Associates.

Changed FORMAT #2 from '###.####;0' to '####.###;0'.
Changed FORMAT #4 from '###.###;0' to '####.###;0'.
Added FORMAT #7 '0000' for Program#.
Added CycleStartXDia# and CycleStartZ# to FORMAT #2.
Deleted RapidF# at Prog Numeric Format Definitions.
Added MUL# to FORMAT #4.
Changed to Metric.
Deleted all occurances of RapidF/RapidFC.
Deleted CoolOn at AppMove.
Deleted literal 'G01' at Approach sub.
Added CheckGear sub.
Outputs SpinOn IF NewGear? = TRUE.
Added SpeedCheck sub.
Compares values of MaxRPM# and SpeedRPM# and outputs either literal 'S' values or Speed Command.
Added SpeedCheckCSS sub.
Compares values of MaxRPM# and CalcRPM1# and outputs either literal 'S' values or CalcRPM1 Command.
Added SpeedCheckCSS2 sub.
Compares values of MaxRPM# and CalcRPM2# and outputs either literal 'S' values or CalcRPM2 Command.
Added SpeedCheckEP sub.
Compares values of MaxRPM# and CalcEpRPM# and outputs either literal 'S' values or CalcEpRPM#
Command.
Added check for NewGear at CheckOffset and NewTool.
Added FirstFeed sub to force FeedRate on FirstFeat of non-Canned Cycle Operation.
Changed SetMaxRPM from 10000 to 2200 at setup and initializations
Added SetMinRpm('30') at setup and initializations
Added blank line to be output FIRST at FirstOperation
Changed EOR to ':' Program# at FirstOperation.
Changed INCHES to MM at MovesComment at FirstOperation.
Deleted literal 'G20' at FirstOperation.
Added literal 'G28U0.' at FirstOperation and NewTool.
Added literal 'G28W0.' at FirstOperation and NewTool.
Moved 'G00' GetOpToolID LatheOffset prior to Preset Home block at FirstOperation and NewTool.
Added GearRange at FirstOperation and NewTool.
Added CoolOn at FirstOperation and NewTool.
Deleted special handling of BarFeeder Station.
IF Drilling AND Equal? Tool# Num#('10') output is rerouted to handle BarFeeder.
Deleted special handling of Retract Programmable TailStock with Parts Catcher Attachment.
IF Equal? Tool# Num#('13') was used.
Changed literal 'G28U0W0' to 'G28U100.W3.' at NewTool and end of Prog.
Changed StrtPos to 'X' CycleStartXDia# 'Z' CycleStartZ# at CannedCycle RoughContour and
RoughPatternShift.
Added literal 'M53' at CannedCycle Threading block.
Added literal 'M54' at CannedCycle Threading Chamfer cancel.
Added GearRange at CannedCycle Tapping.
Changed EOP to literal 'M30' at end of Prog.
DWB}

{6/25/93
Modified: Fanuc 6T Mazak L217.82.10m
For: Gibbs & Associates/ABELSYS/Brusselle Marine Industries
Changes made per Beno"t DE Hertogh at Abelsys.
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
Made major clean-up changes for smoothness and to reduce confusion.
Changed FORMAT #4 from '####.###;0' to '0000' for Program#.
Changed FORMAT #7 from '0000' to '#' for RapidF#.
Deleted ZDepth#, MUL# and CalcEPRPM# at Prog Numeric Format Definitions.
Added RapidF# to FORMAT #7.
DWB}

{10/30/95
Fanuc 6T Mazak [Mat] Lxxx.82m (from: Fanuc 6T Mazak [BEL] L288.82.1m)
Added special G92 canned Thread Cycle fix for a Matsuura customer.
Changes made to ToolPath and CannedCycle section for Threading
WS}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.###;0'
#3 = '#######0'
#4 = '0000'
#5 = '#.######;0'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(Dwell#,2) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Program#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(Recall#,6)
FORMAT(RapidF#,7)

{Special Matsuura Routines ****************************************************}

G92CannedThread:
IF RapidFeat?
IF Flag?('7') {Positions tool to X cutting depth }
IF Flag?('6') {Positions tool to X cutting depth using G92 line}
SeqLabC 'G92X' FirstMoveEPX# FinZ XTapAtZ ThrdLead 'M53' EOL
SetFlagF('6')
ELSE { Positions tool to X cutting depth }
SeqLabC RapidC MoveXC EOL
END
SetFlagF('7')
ELSE
IF Flag?('8') { Tool moves to safe clearance X height on this pass}
SetFlagF('8') {No Output}
ELSE { Tool moves to the start Z point on this pass}
SetFlag('7') {No Output}
SetFlag('8')
END
END
ELSE {Thead Feature}
{Do Nothing - Tool moves to the Required Z depth on this pass}
END
RETURN

{End Special Matsuura Routines *************************************************}

{Added Subroutines *********************************************************}

GetOpToolID:
IF ToolOver?('12') AND NOT ToolOver?('13')
'T11'
ELSE
OpToolID
END
RETURN

GetLOfstOff:
IF LAST ToolOver?('12') AND LAST NOT ToolOver?('13')
'T11'
ELSE
LOfstOff
END
RETURN

DoSpeed:
IF GreaterThan? MaxRPM# Num#('960')
IF LTEqual? Recall# Num#('1') Num#('960')
'S960'
ELSE
'S' Recall# Num#('1')
END
ELSE
IF GreaterThan? MaxRPM# Num#('420')
IF LTEqual? Recall# Num#('1') Num#('420')
'S420'
ELSE
'S' Recall# Num#('1')
END
ELSE { MaxRPM# ² 420 }
IF LTEqual? Recall# Num#('1') Num#('30')
'S30'
ELSE
'S' Recall# Num#('1')
END
END
END
RETURN

GetSpeed:
Save# Num#('1') SpeedRPM#
DoSpeed
RETURN

GetCalcRPM1:
Save# Num#('1') CalcRPM1#
DoSpeed
RETURN

GetCalcRPM2:
Save# Num#('1') CalcRPM2#
DoSpeed
RETURN

GetCalcEpRPM:
Save# Num#('1') CalcEpRPM#
DoSpeed
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqLabC GetLOfstOff '00' SpinOff EOL
SeqLabC GetOpToolID LatheOffset GearRange EOL
ELSE
SeqLabC GetLOfstOff '00' EOL
SeqLabC GetOpToolID LatheOffset EOL
END
ELSE
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
END
IF ConstantSurfaceFeed?
IF NewGear?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
ELSE
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC GetSpeed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' GetSpeed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC GetSpeed
END
END
END
IF LAST ProgStop?
SpinOn EOL { Output Buffer. }
SeqLabC CoolOn EOL
ELSE
IF NewGear?
SpinOn EOL { Output Buffer. }
ELSE
{SpeedC} EOL { Output Buffer. }
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
SetFlag('6') { Output G92 line for 1st line of Canned Thread Cycle }
SetFlag('7') { Used to output every 4th line of Canned Thread Cycle }
SetFlag('8') { Used to output every 4th line of Canned Thread Cycle }
EACHFeat
IF Flag?('5') {G92 Canned Thread Cycle}
G92CannedThread
ELSE
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC GetSpeed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC
IF Taper?
XTapAtZ
END
ThrdLead EOL
Rapid
END
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('2200')
SetMaxFeed('500')
SetMinRpm('30')

SetFlagF('5') { G92 Canned Thread Flag }
SetFlagF('6') { Used to output G92 line for Canned Thread Cycle }
SetFlagF('7') { Used to output every 4th line of Canned Thread Cycle }
SetFlagF('8') { Used to output every 4th line of Canned Thread Cycle }

IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
' ' EOL
':' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MM )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab 'G28U0.' EOL
SeqLabC 'G28W0.' EOL
SeqLabC 'G00' GetOpToolID LatheOffset GearRange EOL
SeqLabC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
CoolOn EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
GetCalcRPM1
ELSE
GetSpeed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' GetCalcRPM2 EOL
END
SeqLabC 'G28U100.W3.' EOL
SeqLabC 'G00' GetLOfstOff '00' EOL
IF NewGear?
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
SeqLab 'G28U0.' EOL
SeqLabC 'G28W0.' EOL
DoPostScript
Plane
SeqLabC 'G00' GetOpToolID LatheOffset GearRange EOL
SeqLabC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
CoolOn EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
GetCalcRPM1
ELSE
GetSpeed
END
SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' CycleStartZ# EOL
ELSE
SeqLab StepMove 'X' CycleStartXDia# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid 'X' CycleStartXDia# 'Z' CycleStartZ# EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SetFlag('5') {Sets G92CannedThread Flag}
ToolPath
IF AutoFinish?
SeqLabC XatFinZ EOL
END
SetFlagF('5') {Cancels G92CannedThread Flag}
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth
IF SingleEdgeCut?
'A60'
ELSE
'A0'
END
ThrdLead 'M53' EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead 'M53' EOL
END
END
IF Chamfer?
SeqLabC 'M54' EOL
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC GetSpeed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth FeedRate EOL
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
END
SeqLabC StockOff StrtPosC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC GetSpeed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF Drilling? AND ToolOver?('9') AND NOT ToolOver?('10') { BarFeeder Station }
ELSE
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' GetCalcEpRPM EOL
END
END
SeqLabC SpinOff EOL
SeqLabC 'G28U100.W3.' GetOpToolID '00' CoolOff EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END