{Change Comments ***********************************************************}

{5/1/96
Copied & modified: Fanuc 6T Mazak L217.82.1
For: Abbey Etna Machine Co.

Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format

Changes made per Docs. provided by John Wielinski at Abbey Etna.
(added gear range and replaced G99 with G01 and G98 with G00)

MPS}

{12/24/97
Updated: Fanuc 6T Mazak [AE] L454.85
Created: Fanuc 6T Mazak [AE] L454.85.1
For: Gibbs & Associates/Abbey Etna Machine Co./General Hone Corporation
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Updated for Catalyst v3.35C per Fanuc 10T MS [-] L001.85.02e Format.
DWB}

{1/12/98
Modified: Fanuc 6T Mazak [AE] L454.85.1
Created: Fanuc 6T Mazak [GH] L688.85
For: General Hone Corporation
Machine: Mazak
Control: Fanuc 6T
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Changes made per Dave Kauffman of General Hone Corporation, phone calls, G200B5701.VNC,
L454.85 Test.VNC, L688.85 Test, L688.85 V Tool & Gear, L688.85 Tool & Gear.
Changed SeqLab to 'N' Operation# '00' at FirstOperation and NewTool.
Added 'N' Operation# '00' EOL at SameTool.
Changed Spindle Forward from M03 to M04 in Compost2 Spindle and Coolant Dialog.
Changed Spindle Reverse from M04 to M03 in Compost2 Spindle and Coolant Dialog.
Deleted BarFeed routine.
Deleted GetOpToolID sub.
Deleted GetLOfstOff sub.
Deleted BarFeeder sub.
Deleted Flag(1).
Deleted all IF Drilling? AND Tool#(10) Boolean routines.
Deleted TailStock w/ PartsCatcher routine.
Deleted TailStockOn sub.
Deleted TailStockOff sub.
Deleted all Tool#(13) Boolean routines.
Changed GearRange values in INT# Resource and in Prog.
M37 = S0 to S425, M38 = S426 to S970, M39 = S971 to S2200.
Made other changes per customer requests.
DWB}

{2/11/98
Modified: Fanuc 6T Mazak [GH] L688.85
Created: Fanuc 6T Mazak [GH] L688.85.1
For: General Hone Corporation
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Changes made per Dave Kauffman of General Hone Corporation, phone calls.
Customer requested that all Line Numbers be based on Operation#.
Added SetOpLines sub.
Outputs 'Åš' Operation# '00' EOL
Added call to SetOpLines at FirstOperation, NewTool and SameTool.
Changed 'N' Operation# '00' to SeqLab at FirstOperation and NewTool.
Changed 'N' Operation# '00' to SeqLab ' ' at and SameTool.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###.###;0.'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(ZDepth#,2)
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Added Subroutines *********************************************************}

GetGearRange:
IF ConstantSurfaceFeed?
IF GTEqual? SpeedSFPM# Num#('971')
'M39'
ELSE
IF GTEqual? SpeedSFPM# Num#('426')
'M38'
ELSE
'M37'
END
END
ELSE
GearRange
END
RETURN

CSSOnToCSSOn:
IF GTEqual? SpeedSFPM# Num#('971')
IF LessThan? LAST SpeedSFPM# Num#('971')
SetFlag('2')
END
ELSE
IF GTEqual? SpeedSFPM# Num#('426')
IF GTEqual? LAST SpeedSFPM# Num#('971')
SetFlag('2')
ELSE
IF LessThan? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
END
ELSE
IF GTEqual? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
END
END
RETURN

CSSOffToCSSOn:
IF GTEqual? SpeedSFPM# Num#('971')
IF LessThan? LAST SpeedRPM# Num#('971')
SetFlag('2')
END
ELSE
IF GTEqual? SpeedSFPM# Num#('426')
IF GTEqual? LAST SpeedRPM# Num#('971')
SetFlag('2')
ELSE
IF LessThan? LAST SpeedRPM# Num#('426')
SetFlag('2')
END
END
ELSE
IF GTEqual? LAST SpeedRPM# Num#('426')
SetFlag('2')
END
END
END
RETURN

CSSOnToCSSOff:
IF GTEqual? SpeedRPM# Num#('971')
IF LessThan? LAST SpeedSFPM# Num#('971')
SetFlag('2')
END
ELSE
IF GTEqual? SpeedRPM# Num#('426')
IF GTEqual? LAST SpeedSFPM# Num#('971')
SetFlag('2')
ELSE
IF LessThan? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
END
ELSE
IF GTEqual? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
END
END
RETURN

ckNewGear:
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
CSSOnToCSSOn
ELSE
CSSOffToCSSOn
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOnToCSSOff
ELSE
IF NewGear?
SetFlag('2')
END
END
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

SetOpLines:
'Åš' Operation# '00' EOL
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidC RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
SetFlagF('2') { NewGear }
ckNewGear
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF Flag?('2') { NewGear }
SeqLabC SpinOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF Flag?('2') { NewGear }
SeqLabC GetGearRange EOL
END
IF ConstantSurfaceFeed?
CSSOn
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF Flag?('2') { NewGear }
'G96' Speed
ELSE
IF LAST ProgStop?
Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
ELSE
SeqLabC Preset MaxRPM EOL
'G96' Speed
END
ELSE
CSSOff
IF Flag?('2') { NewGear }
'G97' Speed
ELSE
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC {SpeedC}
IF Flag?('2') { NewGear }
SpinOn
END
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
SetFlagF('2') { NewGear }
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Rapid
END
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC
IF Taper?
XTapAtZ
END
ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Threading?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('2200')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('2') { NewGear }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SetLineStrtChr('/')
SeqLabC 'G28U0.' EOL
SeqLabC Preset 'X47.5' EOL
SeqLabC Rapid 'X38.' EOL
SetLineStrtChr('')
SetOpLines
SeqLab Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC Rapid OpToolID LatheOffset EOL
IF ConstantSurfaceFeed?
SeqLabC GetGearRange EOL
SeqLabC CSSOn 'G96'
ELSE
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97'
END
Speed SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome CoolOff EOL
SeqLabC LOfstOff '00' EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SetOpLines
SeqLab Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC Rapid OpToolID LatheOffset EOL
IF ConstantSurfaceFeed?
SeqLabC GetGearRange EOL
SeqLabC CSSOn 'G96'
ELSE
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97'
END
Speed SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
SetOpLines
SeqLab ' ' EOL
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC 'G92X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
SeqLabC XatFinZ EOL
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead 'A' InFeedAngle# EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth FeedRate EOL
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ FinZ XTapAtZ
ELSE
FinZ
END
ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR Threading?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC FirstHome CoolOff EOL
SeqLabC OpToolID '00' EOL
IF ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
SeqLabC SpinOff EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END