{Change Comments ***********************************************************}

{5/1/96
Copied & modified: Fanuc 6T Mazak L217.82.1
For: Abbey Etna Machine Co.

Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format

Changes made per Docs. provided by John Wielinski at Abbey Etna.
(added gear range and replaced G99 with G01 and G98 with G00)

MPS}

{2/4/97
Initial: Fanuc 6T Mazak [AE] L454.85
Created: Fanuc 6T Mazak M4 Lxxx.85
ForUser: Precision Industries
Control: Fanuc 6T
Machine: Mazak M4
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: New processor per marked up readout and conversation with Scott Tetlow
Modified Bar Pulling, following conditions must be met to get output:
1. Virtual file must contain a CutOff operation
Flag#1
2. Virtual file must contain a Drilling FIFO operation that is not a SameTool operation.
first one found sets: Flag#2 ; Var#1 = Tool#
Then if Flag#2 and Tool# = Var#1
set Flag#3 for discrimination of operations output.
Set up for 2 turrets.
Turret Positions 01 thru 08 are Front Turret and allways PosSide
Turret Positions 21 thru 26 are Rear Turret and can be either PosSide or NegSide
Using OptCyc1 PostScript to output rear turret NegSide.
Deleted Programmable tailstock
Changed ProgID1 to ':' Program#
Updated to .85 format per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe}

{8/28/97
Initial: Fanuc 6T Mazak M4 L561.85
Created: Fanuc 6T Mazak [LAM] L621.85
ForUser: CIM Solutions / LA Martin
Control: Fanuc 6T
Machine: Mazak M4
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: New processor per conversation with Steve Sauve
Updated per Fanuc 10T MS [-] L001.85.01.02
Modified tool start up and end blocks.
Changed to R format arcs up to 360 degrees.
Changed to standard GearRange command:
M37 - 0 -> 400
M38 - 401 -> 800
M39 - 801 -> 2200
Jim Radcliffe}

{9/24/97
Initial: Fanuc 6T Mazak [LAM] L621.85
Created: Fanuc 6T Mazak [LAM] L621.85.1
Develop: ComPost2 1.1b2, Virtual Gibbs 4.21
Comment: Modified per marked up readout.
Suppressed output of G98/G99 if program is not a bar feed program.
Changed StrtPos in RoughContour to output X and Z on separate lines.
Added 'G27X0.Z0.' to offset cancel lines at end of tools.
Changed ThrdLead from E to F.
Doubled value of output for InFeedAngle.
Moved CheckOp call to after DoPostScript call to allow seting negside on current op.
UnTool both turrets at end of program. Added flags 4 and 5 to control output.
Jim Radcliffe}

{11/19/97
Initial: Fanuc 6T Mazak [LAM] L621.85.1
Created: Fanuc 6T Mazak [LAM] L621.85.2
Develop: ComPost2 1.1b3, Virtual 4.21.14
Comment: Added RapidF# to RoughContour to force FeedRateC output in ToolPath per Steve Sauve.
Jim Radcliffe}

{26Jan98
Original: Fanuc 6T Mazak [LAM] L621.85.2
Created: Fanuc 6T Mazak [LAM] L621.85.3
For: LA Martin
Changes made per: Steve / Neil
Changed G71, G72 and G76 cycles to output 18T/20T, 2-line canned cycles
Commented out Booleans in ApproachSP per customers request.
Added Formatting for SpringPasses#, LastCutXRadius#, Add# and Div# in Prog Numeric Format Definitions
Added Formatting for SPX# ans SPZ# at Prog Numeric Format Definitions
Adjusted Threading Canned Cycle per customers requirements.
Deleted IF CannedCycle? Boolean in Toolpath at IF LastFeat?
Added logic in Toolpath which prevents the last feature of a canned cycle from being ouput,
and now outputs SeqLab on the penultimate line of a LineFeat
Added FeedRate to Canned Cycle Approach moves at IF RoughContour?
Added IF NOT SameTool? Boolean to DoOpComments to suppress Tool comments
Charles Winston}

{2Feb98
Original: Fanuc 6T Mazak [LAM] L621.85.3
Created: Fanuc 6T Mazak [LAM] L621.85.4
For: LA Martin
Changes made per: Steve / Neil
Reverted to single-line canned cycles per customers request
Charles Winston}

{3Feb98
Original: Fanuc 6T Mazak [LAM] L621.85.4
Created: Fanuc 6T Mazak [LAM] L621.85.5
For: LA Martin
Changes made per: Steve / Neil
Changed G71, G72 and G76 Canned Cycles per MAZAK manual supplied by the Customer.
Charles Winston}

{04/17/98, Changed to Metric, CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.###;0'
#3 = '#######0'
#4 = '###.###;0'
#5 = '#.######;0'
#6 = '###0'
#7 = '#'
#8 = '00'
#9 = '0^0'
#10 = '###.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(ADD#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Tag#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(SpringPasses#,8)
FORMAT(Add#,8)
FORMAT(Div#,9)
FORMAT(LastCutXRadius#,10)

{Command Subroutines *******************************************************}

DoInch:
'G20'
RETURN

DoFeedType:
IF Flag?('2')
IF Flag?('3')
'G98' { IPM for bar pull operation to feed with spindle off }
ELSE
'G99' { IPR }
END
END
RETURN

DoSpeedC:
IF Flag?('3')
{ skip speed and gear range }
ELSE
IF ConstantSurfaceFeed?
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
Speed GearRange
END
RETURN

DoSpin:
IF Flag?('3')
SpinOff
ELSE
SpinOn
END
RETURN

CheckOp:
IF OptCyc1? AND ToolOver?('20')
NegSideLathe
ReverseXZArcs
ELSE
PosSideLathe
StandardXZArcs
END
IF Equal? Recall# Num#('1') Tool#
SetFlag('3') { This is the Bar Pull Operation! }
ELSE
SetFlagF('3')
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF NOT SameTool?
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
{ SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL }
TrackZNO# CycleStartZ#
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
{ SeqLabC FeedNoCan XSPC FeedRateNoCan EOL }
TrackXNO# CycleStartX#
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
SeqLabC
IF NewToolOffset?
OpToolID '00'
END
IF NewGear?
SpinOff
END
EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
END
DoOpComments
DoPostScript
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
Preset MaxRPM
END
ELSE
Preset MaxRPM
END
END
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewGear?
GearRange
END
EOL
SeqLabC
IF NewToolOffset?
OpToolID LatheOffset
END
IF LAST ProgStop?
SpinOn
ELSE
IF NewGear?
SpinOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
IF Flag?('3')
SeqLabC 'M00' EOL { Open Chuck/Collet }
END
END
ELSE
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF NOT LastFeat? AND NEXT LastFeat? AND CannedCycle?
SeqLab
END
IF LineFeat?
IF LastFeat? AND CannedCycle?
ELSE
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC
IF Taper?
XTapAtZ
END
ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
OptCyc1F
SetAbs
SetMaxRPM('2200')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { cut off operation in Virtual file }
SetFlagF('2') { bar feed operation in Virtual file }
SetFlagF('3') { current operation bar feed operation }
SetFlagF('4') { untooled Front Turret }
SetFlagF('5') { untooled Rear Turret }
Save# Num#('1') Num#('0')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: separate commands with a space or carriage return' EOL
' OptCcyc1 -' EOL
' Use to set rear turret to output negative X values.' EOL
' Modal. Effects all following operaions with tool' EOL
' numbers 21 and over.' EOL
END

{ Look for Cut Off operation }
EachOp
IF CutOff?
SetFlag('1')
END
NextOp

{ Look for Bar Pull operation if we have a Cut Off operation }
IF Flag?('1')
EachOp
IF NOT SameTool?
IF Flag?('2')
{ we allready have a bar pull operation }
ELSE
IF Drilling? AND FIFO?
Save# Num#('1') Tool#
SetFlag('2')
END
END
END
NextOp
END

EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
':' Program#
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
DoOpComments
DoPostScript
CheckOp
SeqLab 'G28U0.W0.' EOL
SeqLabC Preset Home MaxRPM CoolOn EOL
SeqLabC DoSpeedC EOL
SeqLabC Rapid DoFeedType OpToolID LatheOffset DoSpin EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC CoolOff EOL
DoEndOpPS
SeqLabC RapidC 'G27X0.Z0.' LOfstOff '00' SpinOff EOL
SeqLabC 'G28U0.W0.' EOL
' ' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
' ' EOL
ELSE
IF OptionalStops?
SeqLabC ProgStop EOL
' ' EOL
END
END

{Start new Operation}

DoOpComments
DoPostScript
CheckOp
SeqLab 'G28U0.W0.' EOL
SeqLabC Preset Home MaxRPM CoolOn EOL
SeqLabC DoSpeedC EOL
SeqLabC Rapid DoFeedType OpToolID LatheOffset DoSpin EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# FeedRate EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# FeedRate EOL
END
RapidF# { RapidF# Forces FeedRate }
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
' ' EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
IF SingleEdgeCut? OR ConstantVolumeCut?
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead 'A' ADD# InFeedAngle# InFeedAngle# EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
ELSE
SeqLabC 'G92X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
SeqLabC XatFinZ EOL
IF AutoFinish?
SeqLabC XatFinZ EOL
END
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth FeedRate EOL
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32' XatFinZ
IF Taper?
XTapAtZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04U2.' EOL
SeqLabC Speed SpinOn EOL
END
IF Flag?('3')
SeqLabC 'M00' EOL { Close Chuck/Collet }
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC CoolOff EOL
DoEndOpPS
SeqLabC RapidC 'G27X0.Z0.' OpToolID '00' SpinOff EOL
' ' EOL
EachOp
IF FirstOperation?
SeqLabC OpToolID '00' EOL
IF ToolOver?('20')
SetFlag('5')
ELSE
SetFlag('4')
END
ELSE
IF NewTool?
IF ToolOver?('20') AND NOT Flag?('5')
SeqLabC OpToolID '00' EOL
SetFlag('5')
END
IF NOT ToolOver?('20') AND NOT Flag?('4')
SeqLabC OpToolID '00' EOL
SetFlag('4')
END
END
END
NextOp
' ' EOL
SeqLabC 'G28U0.W0.' EOL
IF Flag?('2') { CutOff and Bar Pull Program }
SeqLabC 'M99' EOL { Tape Rewind }
SeqLabC 'M02' EOL
ELSE
SeqLabC EOP EOL
END
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END