{
MILL=T
LATHE=T
ADV_MILL=F
SUBS=T
ROTARY_MILL=T
MILLTURN_POLAR-SEG=T
MILLTURN_Y-AXIS=F
METRIC=T
}

{Change Comments ***********************************************************}

{8/29/95, L155.82.1m, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format, DWB}

{13.05.95, German translated post
Spaces added between commands
T.Damerow}

{01Mar99
Original: Siemens 810T CNC 110A Lxxx.85m ( Dealer Custom Post- No valid post number )
Created: Siemens 810T 110A Lxxx.85m
For: Mothes, Solingen (Germany).
Changes made per: Thomas Pickhardt
Develop: Catalyst 5.03/ComPost2 1.7b15
Added Post Header Comment at the top of Prog.
Added Formatting for Recall#, FeedContour# and FeedIPR# in Prog Numeric Format Definitions.
Added Custom Feedrate output supported by SaveFeed and GetFeedRateC Subs.
FeedRate is now output on the G96/G95 line in FirstOperation and NewTool
and is suppressed in Approach and ToolPath.
GetFeedRateC is called in FeedRateNoCan, ApproachSP, ToolPath and in Canned Cycles.
Changed ApproachSP. XSPC and ZOpCPC are now output on the same line.
Changed FeedRateC to FeedRate in ToolPath at ThreadFeat.
Changed 'F' to 'K' for Threading feedRate in ToolPath.
Added a Boolean in FirstOperation and NewTool, to output G92 MaxRPM, when CSS is TRUE.
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0'
#3 = '######00;00'
#4 = '######.##;0'
#5 = '0000'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(StockXRadius#,2)
FORMAT(StockZ#,2)
FORMAT(CutDepth#,2)
FORMAT(FeedIPR#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(Retract#,2)
FORMAT(Peck#,2)
FORMAT(Recall#,2)
FORMAT(FeedContour#,2)
FORMAT(FeedIPR#,2)
FORMAT(ToolOffset#,3)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(RapidF#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( UNTERPROGRAMM NUMMER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

SaveFeed:
IF ConstantSurfaceFeed?
Save# Num#('50') FeedIPR# EOL
ELSE
Save# Num#('50') FeedContour# EOL
END
RETURN

GetFeedRateC: { suppress FeedRate output }
IF NOT EmptyLine?
IF ConstantSurfaceFeed?
IF NOT Equal? Recall# Num#('50') FeedIPR#
Save# Num#('50') FeedIPR#
' F' FeedIPR#
END
ELSE
IF NOT Equal? Recall# Num#('50') FeedContour#
Save# Num#('50') FeedContour#
' F' FeedContour#
END
END
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
GetFeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC StockOff ZOpCPC GetFeedRateC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC StockOff XOpCDC GetFeedRateC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan RapidC XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC OpToolID ' D' ToolOffset# EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF LAST ProgStop?
SeqC CSSOn ' G96' Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC CSSOn ' G96' Speed EOL
END
END
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
ELSE
SeqC CSSOn ' G96' Speed EOL
SeqC Preset MaxRPM EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
' G95' Speed
ELSE
IF LAST ProgStop?
' G95' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
' G95' Speed
END
END
END
END
IF LAST ProgStop?
SeqC {SpeedC} SpinOn EOL
SeqC CoolOn EOL
ELSE
SeqC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
InverseSpinOn
ELSE
IF Dwell?
SeqC ' G4 X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC GetFeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc GetFeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC ' K' FeedIPR# EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR 'MPF' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAMM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' UM ' Time$ ' )' EOL
END
IF MovesComment?
'( AUSGABE IN ' MoveType$ ' MM )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqC ' G57 Z300.0' EOL
SeqC ' R04=0' EOL
IF ConstantSurfaceFeed?
SeqC ' G92' MaxRPM EOL
END
SeqC ' G0 D' ToolOffset# OpToolID
IF ConstantSurfaceFeed?
CSSOn ' G96'
ELSE
CSSOff ' G95'
END
FeedRate Speed SpinOn EOL
SaveFeed
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript

IF EQUAL? CWSpindle? LAST CWSpindle?
SeqC ' G97' EOL
END
SeqC Rapid' D20'Home EOL
IF ConstantSurfaceFeed?
SeqC ' G92' MaxRPM EOL
END
SeqC ' G0 D' ToolOffset# OpToolID
IF ConstantSurfaceFeed?
CSSOn ' G96'
ELSE
SeqC CSSOff ' G95'
END
FeedRate Speed SpinOn EOL
SaveFeed
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC
END
SeqC LAST OpExitZCPC
SeqC LAST OpExitXCPC
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass1
NewProg
SeqC GetFeedRateC EOL
SeqC
FORMAT(Program#,6)
' R20=' Program#
' R21=' CycleStartXDia#
' R22=' CycleStartZ#
' R24=' StockXRadius#
' R25=' StockZ#
' R26=' CutDepth#
IF CutterRadiusCompensation?
IF CRCLeft?
' R27=41'
ELSE
' R27=42'
END
ELSE
' R27=40'
END
' R28=' FeedIPR#
IF ApproachOD?
' R29=11'
ELSE
IF ApproachID?
' R29=13'
ELSE {OD ApproachFace}
' R29=12' {R29=14 is for ID ApproachFace}
END
END
EOL
SetPass2
SeqC ' L95 P1' EOL
OpenSub
'%SPF' Program# EOL
DoSubComment
SeqC StepMove StrtPos EOL
ToolPath
SeqC ' M17' EOL
CloseSub
IF AutoFinish?
SeqC ' R24=0 R25=0'
IF ApproachID?
' R29=22'
ELSE
' R29=21'
END
EOL
SeqC ' L95 P1' EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqC
' R20=' FeedIPR#
' R21=' FinishXDia#
' R22=' CycleStartZ#
IF AutoFinish?
' R23=2'
ELSE
' R23=1'
END
IF ApproachID?
' R24=' ThreadXInc#
ELSE
' R24=-' ThreadXInc#
END
' R25=' StockXRadius#
' R26=.05' {Thread in amount}
' R27=.05' {Thread out amount}
EOL
SeqC
' R28=' CalcNumCuts
IF SingleEdgeCut?
' R29=30'
ELSE
' R29=0'
END
' R31=' FinishXDia#
' R32=' FinishZ#
' L97 P1'
EOL
ELSE
IF Drilling?
IF PeckFullRetract?
SeqC GetFeedRateC EOL
SeqC
' R11=1'
' R22=' CycleStartZ#
' R24=' Retract# {Peck decrease amount}
' R25=' Peck#
' R26=' FinishZ#
' R27=' Dwell# {Dwell at start}
' R28=' Dwell# EOL {Dwell at end}
SeqC ' L98 P1' EOL
EOL
END
IF PeckChipBreaker?
SeqC GetFeedRateC EOL
SeqC
' R11=0'
' R22=' CycleStartZ#
' R24=' Retract# {Peck decrease amount}
' R25=' Peck#
' R26=' FinishZ#
' R27=' Dwell# {Dwell at start}
' R28=' Dwell# EOL {Dwell at end}
SeqC ' L98 P1' EOL
EOL
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqC ' G33'
IF Taper?
' X' MUL# Num#('2') FinishXRadius#
END
' Z' FinishZ# EOL
SeqC Rapid XSP EOL
SeqC FeedC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC CoolOff EOL
SeqC Rapid Home SpinOff EOL
IF ProgStop?
SeqC ' M0' EOL
END
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( DATEI LAENGE: ' FileBytes# ' ZEICHEN )' EOL
END
IF FileFeetComment?
'( DATEI LAENGE: ' FileFeet# ' FUSS )' EOL
END
IF FileMetersComment?
'( DATEI LAENGE: ' FileMeters# ' METER )' EOL
END
Close
END