{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{added separate sub call code and warning for not separate, 7/5/88 WFG}
{separate sub calls turned off in this post- 'UseSeparateSubCalls' commented out}
{ncPost3ż24 or better}
{added IF ToolChangeAtHome?, & SetHome 9/26/88 WFG}
{added PostScript commands 3/11/89 WFG}
{added PostScript command comments 5/9/89, WFG, use ncPost 3.10Ś9 or better}
{removed run time comments, 5/9/89, WFG}
{added "must be all capital letters when typed in" to Postscript Command comment, 5/17/89, JR}
{added metric, 6/5/89, WFG}
{suppressed first cycle StrtPos for sep subs,7/17/89 WFG}
{last tool now goes to FirstHome when finished, 7/26/89, WFG}
{changed to Sep Sub standard}
{.65, corrected Sep sub problem if 1st cut <> Z step, 9/14/89 WFG, requires ncPost 3.19Ś5}

{10/19/89
Copied & modified: Fanuc 6M M001.65
For: Dewey Electronics
Machine: Toshiba
Control: Tosnuc 500MX
Modified per cust requests.
Comment out PostScript & SepSubs
Jim Radcliffe}

{6/5/90 Updated: Tosnuc 500MX Tshba M258.62 to .72.1 format, JR}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{9/13/90
Copied & modified: Tosnuc 500MX Tshba M258.73
For: Dewey Electronics
Machine: Toshiba
Control: Tosnuc 500MX
Added code when indexing the 5th axis to cancel the tool offset, retract to clearance plane 1,
index, output the work fixture offset, and output the tool offset.
Made XY unconditional in arc features.
Deleted the booleans to output CRCOffsetC because ResetCRCNum now works.
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
DWB}

{9/24/90
Copied & modified: Tosnuc 500MX Tshba M258.76.1
For: Dewey Electronics
Machine: Toshiba
Control: Tosnuc 500MX
Set Allow R Format Arcs to False in Form.
Midified format for Dwell# in Prog.
DWB}

{2/1/91
Copied & modified: Tosnuc 500MXII Tshba M259.76.2
For: Tool Sales & Service
Machine: Toshiba BMC4 Horizontal & VMC6 Vertical
Control: Tosnuc 500MXII
Deleted OpToolID from NewTool, pretool info good enough.
Changed G73 to G87 in MachSpec Drill Cycle.
Added 'G89' in Drilling.
Added LastFeatExtend to turn off CRC if not an AutoCycle operation.
Added unconditional ZCP3 after G80 in Drilling.
Deleted the 'E98' go home sub & its calls, using standard Home stuff.
Modified FormatArc sub and added HelixPitch#.
Jim Radcliffe}

{7/3/91
Copied & modified: Tosnuc 500MXII [TSS] M395.76.1
For: Tool Sales & Service
Machine: Toshiba BMC-63 Horizontal
Control: Tosnuc 600M
Update to .80 format.
Put ToolChng on line after OpToolID.
Program Stops are at the beginning of operations.
Format Dwell to use decimal point & suppress trailing zeros.
Output M11 unclamp before an index & M10 clamp after.
The indexing axis is a 4th axis B, the 5th axis may be an A using same format as B.
Indexing must be done with Z full up, added sub Rotate for indexing stuff and called from main.
Changed format 2 & 3 for index to have 3 decimal places.
Delete OfstOff between tools not needed.
Delete Home stuff between tools, not needed, going to literal machine postion at end.
PreTool during all tools except the last one.
No subroutines, output per M015.
Changed M19 to SpinOff, SpinOff in MachSpec is M19, same effect.
Jim Radcliffe}

{7/5/91
Copied & modified: Tosnuc 600M BMC-63
For: Tool Sales & Service
Machine: Toshiba BMC-40 (Horizontal)
Control: Tosnuc 600M
Modified G73 move to machine coordinate values.
Jim Radcliffe}

{9/14/93
Modified: Tosnuc 600M BMC-40 M440.80
For: Tool Sales & Service
Updated to Version 4.1 per LongHand M001.81.3 Format.
Changed all colons in Comments to dashes for DNC purposes.
Changed M11 to M69 and M10 to M68 for FifthDegree# at Rotate Sub.
Added Axis Tracking for Helical Arcs at FormatArc.
Added CkThreadHob sub to output G40 on NextToLastFeat.
Modified CRCOff to support 4.2 exit move, deleted LastFeatExtend.
**NOTE: Actually copied the M442.81.2 Prog, after the change comments.
The only differences between M4440.80 and M442.80 were G73 Z positions and minor fixes
The changes shown here were already in M442.81.2 so it was easier to
use the M442.81.2 prog and just change the G73 Z positions and minor fixes!
Jim Radcliffe}

{9/14/93
Modified: Tosnuc 600M BMC-40 M440.81.2
For: Tool Sales & Service
Moved the program stop, M0, to the beginning of the operation specified in ncCAM.
Jim Radcliffe}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Incremented number to .87, MPK}

{5Nov98
Original: Tosnuc 600M BMC-40 M440.87
Created: Tosnuc 600M [BC] NMT29.87
For: Black Clawson
Changes made per: Joe Knowles
Added Post Header Comment at the top of Prog.
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
NEW Post FIRST DRAFT:
Added ToolList in Program Header
Changed G81 to G86 and G83 to G87 in MachSpec
Deleted G17 thru G19 in MachSpec and added DoPlane and DoPlaneC Subs
Added ' G63 M03' when tapping to Syncronisetap head/RPM
Added Spaces to all Address lables
Added Blank Lines between Operations
Moved CoolOff from NewTool and SameTool to Opguts, at DrillStuff and ExitMove2
Other changes too numerous to list per conversation and Sample output from Joe Knowles
Charles Winston}

{11Feb99
Original: Tosnuc 600M [BC] NMT29.87
Created: Tosnuc 600M [BC] NMT29.87.1
For: Black Clawson
Changes made per: Joe Knowles
Develop: Catalyst 5.03/ComPost2 1.7b15
Set Allow R Format Arcs to TRUE in Form.
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '##.###;0.'
#7 = '#;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(HelixPitch#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TLDia#,4)
FORMAT(TLNum#,5)
FORMAT(Tag#,5)
FORMAT(Recall#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)


{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' - ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF FirstOperation? OR NewTool?
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' - ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
END
RestoreScale
END
RETURN

Rotate:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' M11' EOL
SeqC ' B' FourthDegree# EOL
SeqC ' M10' EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' M11' EOL
SeqC ' B' FourthDegree# EOL
SeqC ' M10' EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' M69' EOL
SeqC ' A' FifthDegree# EOL
SeqC ' M68' EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' M69' EOL
SeqC ' A' FifthDegree# EOL
SeqC ' M68' EOL
FifthCCWF
END
RETURN

PSInit:
NewWFOF
RotateF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

GetConnect:
IF FeedConnect?
FeedC
ELSE
RapidC
END
RETURN

ExitMove:
IF NOT FeedConnect?
SeqC
IF FIFO? { .81 }
FeedC
ELSE
IF NOT AutoCycle?
RapidC
END
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
EOL
END
RETURN

ExitMove2:
IF FIFO?
FeedC ZCP3C FeedEntC CoolOff
ELSE
RapidC ZCP3C CoolOff
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY
ELSE
IF XZPlane?
MoveX MoveZ
ELSE
MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
IF XYPlane? AND ZMove?
' K' HelixPitch#
ELSE
IF XZPlane? AND YMove?
' J' HelixPitch#
ELSE
IF YZPlane? AND XMove?
' I' HelixPitch#
END
END
END
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF AutoCycle?
SetInc
ELSE
SetAbsOrInc
END
RETURN

CkThreadHob:
SetAbs
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF NEXT NOT XMove? AND NEXT NOT YMove?
CRCOffC
END
TrackXNO# SPX#
TrackYNO# SPY#
TrackZNO# SPZ#
SetInc
RETURN

CkCRC:
IF LastFeat?
CRCOffC
ELSE
IF AutoCycle? AND NEXT LastFeat?
CkThreadHob
ELSE
CRCOnC
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CkCRC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath:
ResetCRCNum { Do not move, customer wants offset on all G41/G42 blocks. }
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('6') SUB# EPX# CurOriginPosX#
Save# Num#('7') SUB# EPY# CurOriginPosY#
SetInc
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
IF NOT SameTool?
IF WorkFixtureOffsets?
SeqC ' G57 H' Recall# Num#('9') EOL
END
END
ELSE
SeqC ' G57 H' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF MultipleParts? AND WorkFixtureOffsets?
SeqC ' G57 H' Recall# Num#('9') EOL
ELSE
IF NeedWFO1?
SeqC ' G57 H' NewWFO# EOL
END
END
END
END
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
IF FIFO?
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
EachRep
IF NOT FirstCycle?
SeqC GetConnect StrtPosC EOL
END
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
IF ZshiftOnly?
EntryMove
END
ELSE
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
DoCycleComment
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
SetAbs
Save# Num#('4') SPX#
Save# Num#('5') SPY#
SetInc
AutoCycCutSub1
DoCycleComment
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('4') Recall# Num#('6')
TrackYNO# ADD# Recall# Num#('5') Recall# Num#('7')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF FirstCycle?
DoCycleComment
EntryMove
ELSE
IF NOT FeedConnect?
ExitMove
END
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
DoCycleComment
IF NOT FeedConnect?
EntryMove
END
END
ToolPath
NextRep
AutoCycCutSub2
ReSetPass2 {restore for positioning moves}
NEXTFeat
RETURN

DrillStuff:
SeqC DrillCP EOL
GetCycle
IF Tap?
SeqC ' G63 M03' EOL
END
SeqC FromCP
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

BlankLine:
' ' EOL
RETURN

GetStartOfSameTool:
BlankLine
DoPartCycleComment
DoOpComments
DoPostScript
BlankLine
Rotate
WFOStuff
CheckPass
RETURN

GetPreTool:
IF NOT LastTool?
PreTool
END
RETURN

DoPlane:
IF XYPlane?
' G17'
Save# Num#('10') Num#('17')
ELSE
IF XZPlane?
' G18'
Save# Num#('10') Num#('18')
ELSE
' G19'
Save# Num#('10') Num#('19')
END
END
RETURN

DoPlaneC:
IF XYPlane?
IF NOT Equal? Recall# Num#('10') Num#('17')
' G17'
Save# Num#('10') Num#('17')
END
ELSE
IF XZPlane?
IF NOT Equal? Recall# Num#('10') Num#('18')
' G18'
Save# Num#('10') Num#('18')
END
ELSE
IF NOT Equal? Recall# Num#('10') Num#('19')
' G19'
Save# Num#('10') Num#('19')
END
END
END
RETURN

ToolList:
BlankLine
EachTool
'( Tool ' TLNum# ' ' TLDia# ' ' TLToolType$ ' ' TLToolComment$ ' )' EOL
NextTool
BlankLine
RETURN

MasterSub:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE
Save# Num#('10') Num#('17') { establishes the G17 Plane }
IF ToolChangeAtHome?
SetHome
END
Plane { No output }
WFOStuff
SeqC OpToolID EOL
Seq ToolChng EOL
BlankLine
DoPartCycleComment
DoOpComments
DoPostScript
BlankLine
Rotate
IF ProgStop?
SeqC ' M0' EOL
END
CheckPass
SeqC AbsOrInc Rapid StrtPos GetPreTool EOL
SeqC OfstOn
IF NOT Tap?
SpinOn
END
Speed EOL
SeqC CoolOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts?
IF WorkFixtureOffsets?
SeqC ' G57 H' Recall# Num#('8') EOL
END
END
DoEndOpPS
Rotate
IF ProgStop?
SeqC ' M0' EOL
BlankLine
END

{Start new Operation}

Seq ToolChng EOL
BlankLine
DoPartCycleComment
DoOpComments
DoPostScript
BlankLine
Rotate
CheckPass
SeqC AbsOrInc DoPlaneC Rapid StrtPos GetPreTool EOL
SeqC OfstOn
IF NOT Tap?
SpinOn
END
Speed EOL
SeqC CoolOn EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF ProgStop?
SeqC CoolOff EOL
SeqC OfstOff EOL
SeqC ' G73' ' Z27.559' EOL
Rotate

{Start new Operation}

GetStartOfSameTool
SeqC ' M0' EOL
SeqC AbsOrInc DoPlaneC Rapid StrtPos SpeedC
IF NOT Tap?
SpinOn
END
EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff EOL
SeqC ' G73' ' Z27.559' EOL
Rotate

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc DoPlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
IF Rotate?
SeqC OfstOff EOL
SeqC ' G73' ' Z27.559' EOL
Rotate

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc DoPlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

{GetStartOfSameTool}
BlankLine
DoPartCycleComment
DoOpComments
DoPostScript
BlankLine
IF Rotate?
SeqC OfstOff EOL
SeqC ' G73' ' Z27.559' EOL
Rotate
WFOStuff
CheckPass
SeqC AbsOrInc DoPlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
WFOStuff
CheckPass
SeqC AbsOrInc DoPlaneC Rapid StrtPos SpeedC EOL
END
END
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZshiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff CoolOff EOL
SeqC ZCP3 EOL
END
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts?
IF WorkFixtureOffsets?
SeqC ' G57 H' Recall# Num#('8') EOL
END
END
SeqC ' G73' ' Z27.559' EOL
DoEndOpPS
Rotate
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop ASCII('13') EOL
END
RETURN

MPLoop:
TagInit
IF AllToolsOnePart?
Save# Num#('9') Recall# Num#('8') { NewWFO# }
EachPart
TagInc
EachOp
MasterSub
NextOp
EndPartSub
Save# Num#('9') ADD# Recall# Num#('9') Num#('1') { NewWFO# }
NextPart
ELSE { OneToolAllParts }
Save# Num#('2') Recall# Num#('1')
IF LTEqual? Recall# Num#('1') Recall# Num#('3')
EachOp
IF Equal? Operation# Recall# Num#('2')
Save# Num#('2') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('1') Recall# Num#('3')
Save# Num#('2') Operation#
ELSE
IF NotEqual? Recall# Num#('1') SUB# Recall# Num#('2') Num#('1')
Save# Num#('2') SUB# Operation# Num#('1')
END
END
END
END
NextOp
EachPart
TagInc
EachOp
IF GTEqual? Operation# Recall# Num#('1')
IF LTEqual? Operation# Recall# Num#('2')
IF Equal? Operation# Recall# Num#('1')
IF FirstPart?
Save# Num#('9') Recall# Num#('8') { NewWFO# }
ELSE
Save# Num#('9') ADD# Recall# Num#('9') Num#('1') { NewWFO# }

{Finish off last Operation}

IF FullUp?
SeqC CoolOff EOL
SeqC OfstOff EOL
SeqC ' G73' ' Z27.559' EOL
END
{DoEndOpPS}

{Start new Operation}

{GetStartOfSameTool}
DoPartCycleComment
DoOpComments
DoPostScript
IF Rotate? AND NOT FullUp?
SeqC OfstOff EOL
SeqC ' G73' ' Z27.559' EOL
END
Rotate
WFOStuff
CheckPass
SeqC AbsOrInc DoPlaneC Rapid StrtPos SpeedC EOL
IF FullUp?
SeqC OfstOn CoolOn EOL
ELSE
IF Rotate?
SeqC OfstOn EOL
END
END
END
END
MasterSub
END
END
NextOp
NextPart
Save# Num#('1') ADD# Recall# Num#('2') Num#('1')
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('4500')
SetMaxFeed('500')
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + A move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
END
EOR EOL
'$' Program# EOL
IF UseComments?
'(PRINT NUMBER )' EOL
'(REV - )' EOL
BlankLine
IF ProgramNameComment?
'( PROGRAM - ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT - ' FormatName$ ' )' EOL
END
IF TimeComment?
'( PROGRAMED ' Date$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED - ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
ToolList
IF MultipleParts?
Save# Num#('1') Num#('1')
Save# Num#('8') NewWFO#
EachOp
IF LastOp?
Save# Num#('3') Operation#
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
ELSE
IF WorkFixtureOffsets?
SeqC ' G57 H' Recall# Num#('8') EOL
END
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
SeqC ' G53' EOL
SeqC ' X39.25' ' Y33.' EOL
SeqC EOP EOL
'(SET UP TIME= )' EOL
'(OPER SHOP PREP MACHINE TIME= )' EOL
EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END