{Change Comments ***********************************************************}

{7/5/91
Copied & modified: Tosnuc 600M BMC-63 M441.76.1
For: Tool Sales & Service
Machine: Toshiba VMC-45 ( Vertical )
Control: Tosnuc 600M
Modified 'G73' move to Machine Coordinate Values.
JR}

{3/19/92
Modified: Tosnuc 600M VMC-45 M442.80
For: Gibbs & Associates
Updated to Version 4.1 per LongHand2 M001.81 Format.
DWB}

{1/20/93
Modified: Tosnuc 600M VMC-45 M442.81
For: Winegar Inc.
Changed StrtPos to StrtPosC at DrillStuff sub.
Deleted G17, G18 and G19 from Mach Specs Commands 2 Dialog Plane Select fields.
Added AbsOrInc and OfstOff to Plane block at FirstOperation.
Deleted OpToolID and ToolChng at FirstOperation.
Moved Speed SpinOn to be output on block by itself at FirstOperation.
Added GoHome sub to output literal 'G73Z19.685'.
Called from CheckRotate, EndPartSub and MPLoop subs, and NewTool and SameTool.
Added Flag(1) to output literal 'G73Y17.7165Z19.685' at end of output for LastOp.
Added CoolOff to DrillOff block at IF Drilling.
KLM}

{1/21/93
Modified: Tosnuc 600M VMC-45 M543.81.1
For: Winegar Inc.
Made additional changes per request -
Changed literal 'Z19.685' to 'Z19.0' at GoHome sub.
Added literal 'G53' [cancel WFO] after DrillOff block at IF Drilling.
Changed M2 to M30 in Mach Specs Commands 4 Dialog End Program field.
Added ToolChng at end of prog.
KLM}

{3/4/94
Modified: Tosnuc 600M VMC45 WB M543.81.2
For: Winegar Inc.
Versions: ncCad 4.32.03/ncCAM 4.32.03/ncPost 4.32.03/Compost 4.21.20
Updated to Version 4.2 per LongHand M001.81.3a Format.
Changed TrackZNO# ZDepth# to TrackZNO# FIRST SPZ# at DrillStuff.
SPZ# is affected by SetScale, whereas ZDepth# is not.
Changed logic of MPLoop sub to handle IF NewTool? and LastOp? situations.
Commented out DoEndOpPS at MPLoop for OneToolAllParts, it does not work correctly.
Added call to WFOStuff at all operations.
Using Var(8) and Var(9) for control of MultiplePart WorkFixtureOffsets.
Added CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added Move to ZInC for Non-AutoCycle FeedConnect Repeats with ZMoves at ExitMove sub.
Moved DoCycleComment call to before StrtPos move in related subs.
Added BadMPWFOReport sub.
Moved SeqC and EOL outside of IF ELSE condition at ExitMove sub.
Moved SeqC AbsOrInc and EOL outside of IF ELSE condition at AutoCycCutSub2.
Deleted ReSetPass2 at end of ZonlyRepAutoCycle sub.
Already executed at end of call to AutoCycCutSub2 sub.

Changes made per Aaron Storvick of Winegar Inc.
Added GetCoolOff sub to output CoolOff on ExitMoves.
Added ckCoolOff sub to call GetCoolOff sub at end of AutoCycle Operation
ckCoolOff sub is called at AutoCycCutSub2 sub.
Deleted literal 'Y17.7165' at GoHome sub.
Deleted Flag(1) test at GoHome Sub.
Flag(1) allowed literal 'Y17.7165' to be output.
Deleted Flag(1) and FlagF(1) setting at end of prog.
Changed FORMAT for zero values from ';0.' to ';0' in both Mach Spec and Prog.
Added RotateF, FourthCWF, FourthCCWF, FifthCWF and FifthCCWF at setup and initializations.
Clears any previous process setting.
DWB}

{4/21/94
Modified: Tosnuc 600M VMC45 WB M543.81.3
For: Winegar Inc.
Versions: ncCad 4.32.03/ncCAM 4.32.03/ncPost 4.32.03/Compost 4.21.20
Changes made per Aaron Storvick of Winegar Inc.
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Converted to SubProgram support per Fanuc 6M M001.81.2d.
Subroutines are called with G72 $Program# L Repeats#.
Subroutines start with EOR EOB followed by $Program#.
Subroutines end with M2.
Moved DoOpComments prior to SafeStart block at FirstOperation.
Customer requested single AutoCycle to be output as part of Main Program in AbsOrInc values.
Added Var(0) to count number of PointFeatures.
Added Flag(1) to indicate single AutoCycle situation.
Added Var(1) to store WorkGroup SetPass2 XPos.
Added Var(2) to store WorkGroup SetPass2 YPos.
Added ADD# to FORMAT#4 at Prog Numeric Format Definitions.
Added GetMoveXYZC sub to calculate Absolute AutoCycle EndPoint.
Called from FormatArc, StdLine and ToolPath subs.
Added ckCoolOff sub to output CoolOff at ExitMove.
Called from DoOneAutoCycle sub.
Added DoOneAutoCycle sub to take care of Prog flow.
Added condition to check Flag(1) at Milling sub.
Added ckOneAutoCycle sub to check for single AutoCycle.
DWB}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '##.###;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,4)
FORMAT(HelixPitch#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

GoHome:
'G73Z19.' { Program in Machine Coordinate System }
RETURN

GetCoolOff:
IF LastOp?
CoolOff
ELSE
IF NEXT NewTool?
CoolOff
ELSE
IF ProgStop?
CoolOff
ELSE
IF NOT CoolOff? AND NEXT CoolOff?
CoolOff
END
END
END
END
RETURN

CheckRotate:
IF Rotate?
IF SameTool? AND NOT FirstOperation? AND LAST NOT ProgStop? AND NOT NewToolOffset?
SeqC GoHome EOL
END
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'M11' EOL
SeqC 'B' FourthDegree# EOL
SeqC 'M10' EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'M11' EOL
SeqC 'B' FourthDegree# EOL
SeqC 'M10' EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'M11' EOL
SeqC 'A' FifthDegree# EOL
SeqC 'M10' EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'M11' EOL
SeqC 'A' FifthDegree# EOL
SeqC 'M10' EOL
FifthCCWF {reset flag}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
EOR EOL
'$' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall '$' Program# RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall '$' Program# RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqC SubCall '$' Program# RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

GetMoveXYZC:
IF AbsoluteMoves? AND Flag?('1') { DoOneAutoCycle }
IF XMove?
'X' ADD# Recall# Num#('1') TrackXNO# EPX#
END
IF YMove?
'Y' ADD# Recall# Num#('2') TrackYNO# EPY#
END
IF NOT ArcFeat?
MoveZC
END
ELSE
IF ArcFeat?
MoveX MoveY
ELSE
MoveXYZC
END
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
GetMoveXYZC
ELSE
IF XZPlane?
MoveX MoveZ
ELSE { YZPlane }
MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
IF XYPlane? AND ZMove?
'K' HelixPitch#
ELSE
IF XZPlane? AND YMove?
'J' HelixPitch#
ELSE
IF YZPlane? AND XMove?
'I' HelixPitch#
END
END
END
RETURN

CkCRC: { 4.2 }
IF LastFeat?
CRCOffC
ELSE
CRCOnC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CkCRC FeedC GetMoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CkCRC FeedC GetMoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CkCRC FeedC GetMoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall '$' Program# 'L1' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC GetMoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC GetMoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC GetMoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC GetMoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF LastFeat? AND NOT AutoCycle?
CRCOffC
IF NOT EmptyLine?
SeqC FeedC LastFeatExtend EOL
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'G57H' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqC 'G57H' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

ckCoolOff:
IF NOT Repeats?
ReSetPass2 {restore for positioning moves}
SetStatusOff
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF NOT ZMove?
IF LastFeat?
GetCoolOff
END
END
SetStatusOn
ReSetPass1 {restore for element cut moves}
END
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

ckCoolOff:
ReSetPass2 {restore for positioning moves}
SetStatusOff
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF NOT ZMove?
GetCoolOff
END
SetStatusOn
ReSetPass1 {restore for element cut moves}
RETURN

DoOneAutoCycle: {One PointFeat in WorkGroup}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
EntryMove
ToolPath
SeqC
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
ckCoolOff EOL
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
IF Flag?('1') { One PointFeat in WorkGroup }
DoOneAutoCycle
ELSE
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall '$' Program# 'L1' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall '$' Program# 'L1' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

ckOneAutoCycle:
IF NOT Repeats?
Save# Num#('0') Num#('0')
EachFeat
Save# Num#('0') ADD# Recall# Num#('0') Num#('1')
NextFeat
IF Equal? Recall# Num#('0') Num#('1')
SetFlag('1')
IF AbsoluteMoves?
SetStatusOff
SetACSPCompF
Save# Num#('1') SPX#
Save# Num#('2') SPY#
SetACSPComp
SetStatusOn
END
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ckOneAutoCycle
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckRotate
WFOStuff
CheckPass
PlaneC { No Output }
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('4500')
SetMaxFeed('500')
RotateF {Clears any previous process setting}
FourthCWF {Clears any previous process setting}
FourthCCWF {Clears any previous process setting}
FifthCWF {Clears any previous process setting}
FifthCCWF {Clears any previous process setting}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + A move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
'$' Program# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane { No Output }
DoOpComments
Seq AbsOrInc DrillOff CRCOff OfstOff EOL
SeqC 'G53' EOL { cancel WFO }
DoPostScript
CheckRotate
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos
IF NOT LastTool?
PreTool
END
EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC OfstOff EOL
CloseMP
END
DoEndOpPS
SeqC GoHome SpinOff EOL
CheckRotate
SeqC
IF LAST ProgStop?
'M0'
ELSE
IF OptionalStops?
ProgStop
ELSE
' '
END
END
ASCII('13') EOL

{Start new Operation}

Plane { No Output }
Seq ToolChng EOL
DoOpComments
DoPostScript
CheckRotate
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos PreTool EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC OfstOff EOL
SeqC GoHome SpinOff EOL
CheckRotate

{Start new Operation}

GetStartOfSameTool
SeqC 'M0' EOL
SeqC SpeedC SpinOn EOL
SeqC AbsOrInc Rapid StrtPos EOL
SeqC OfstOn CoolOn EOL
ELSE
IF NewToolOffset?
SeqC OfstOff EOL
SeqC GoHome EOL
CheckRotate

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C
IF Flag?('1')
SetFlagF('1')
IF NOT EmptyLine?
GetCoolOff
END
ELSE
GetCoolOff
END
EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC GetCoolOff EOL
ELSE
SeqC RapidC CRCOffC ZCP3C GetCoolOff EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
SeqC FromCP StrtPosC ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff OfstOff EOL
IF Repeats?
FinishSubG92
END
SeqC 'G53' EOL { cancel WFO }
SeqC RapidC ZCP3C GetCoolOff EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC OfstOff EOL
CloseMP
END
DoEndOpPS
SeqC GoHome SpinOff EOL
CheckRotate
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END