{Change Comments ***********************************************************}

{3/30/92
Copied & modified: Tosnuc 600M VMC-45 M442.81
For: Pride Machine Inc
Machine: Toshiba VMC-45 ( Vertical )
Control: Tosnuc 600M
Made changes per conversations with Mark Babich at Pride, manual and sample program.
Added Subroutine handling per Tosnuc 500MXII [TSS] M395.81.
Added 4-Axis handling per Yasnac MX3 4A Mat A001.80.03.
Added PostScript Rotation Repeats.
Flag(1) is used to route Post Processor to RotateSub Sub.
Var(1) Stores value of FourthDegree#
Var(2) Calculates and stores value of each index.
Var(3) Keeps track of Loop Value.
DWB}

{12/22/92
Modified: Tosnuc 600M Toshiba 45 A003.80
For: Pride Machine Inc
Moved ProgramNameComment to a line by itself.
Deleted EOR between subs.
Moved EOR at end of program to be after Post2.
Changed 'G73XXX' to 'G73' in GoHome sub.
JR}

{2/25/93
Modified: Tosnuc 600M Toshiba 45 A003.81
For: Pride Machine Inc
Made changes per conversations with Willis Berndt at Pride and sample program.
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
Corrected bugs and simplified logic regarding Rotary Axis Repeats.
DWB}

{6/25/93, v.81.4
For: general
By: [cwh]
Added the SetOpArcSegAcc to the EachOp/NextOp loop to set the arc segmentation
accuracy value to the value entered in ncCAM.
}

{11/3/93
Modified: Tosnuc 600M Tosh 45 A003.81.4
For: Pride
Added Tracking of 3rd axis position for Helical Interpolation
Jim Radcliffe}

{3/20/97, changed to 3 axis post per Fanuc 6M M001.14, MPK}

{17Jun97
Original: Tosnuc 600M Tosh 45 MY49.14.1
Created: Tosnuc 600M Tosh 45 MY49.14.2
For: Pride Industries
Changes made per: Carl Mackey
Customer requested a reduction in the number of Subs output with Drilling Canned Cycles kept in the main prog.
Changed StartToolSub and EndToolSub
Drill Cycles now bypass the SubCall
Added DrillStuff sub
Updated Drill Canned Cycles per LongHand M001.12
Added Booleans in SameToolOp2 and SameToolOp3 to call StartToolSub and EndToolSub
to catch SameTool used for Milling and then Drilling (or vice versa) in contiguous operations.
Added Boolean in End1 to close sub in LastOp
Charles Winston}

{1/8/98
Initial: Tosnuc 600M Tosh 45 MY49.14.2
Created: Tosnuc 600M Tosh 45 MY49.14.3
ForUser: Pride Industries
Develop: ComPost2 1.1b3, Virtual 4.21.21
Comment: Modified CRCOff handling per Carl Mackey.
Deleted LastFeatExtend. Call CRCOff on last toolpath feature.
Jim Radcliffe}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.##;0.'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(HelixPitch#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
'G57H' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
'G57' WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoToolComments:
IF UseComments?
SetScale('1')
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
RestoreScale
END
RETURN

GoHome:
SeqC 'G73' EOL { Program in Machine Coordinate System }
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'M11' EOL
SeqC 'A' FourthDegree# EOL
SeqC 'M10' EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'M11' EOL
SeqC 'A' FourthDegree# EOL
SeqC 'M10' EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'M11' EOL
SeqC 'B' FifthDegree# EOL
SeqC 'M10' EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'M11' EOL
SeqC 'B' FifthDegree# EOL
SeqC 'M10' EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL
SubID EOL
DoSubComment
RETURN

StartToolSub:
IF NOT Drilling?
NewProg
SeqC SubCall '$' Program# EOL
StartSub
END
RETURN

EndToolSub:
IF LAST NOT Drilling?
SeqC EndSub EOL
CloseSub
END
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall '$' Program# RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC 'G57' SetWFO EOL
SeqC SubCall '$' Program# RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqC SubCall '$' Program# RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC 'G57' WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY
ELSE
IF XZPlane?
MoveX MoveZ
ELSE { YZPlane }
MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
IF XYPlane? AND ZMove?
'K' HelixPitch#
TrackZNo# EPZ#
ELSE
IF XZPlane? AND YMove?
'J' HelixPitch#
TrackYNo# EPY#
ELSE
IF YZPlane? AND XMove?
'I' HelixPitch#
TrackXNo# EPX#
END
END
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ArcFeat?
IF NOT ZMove?
CRCOnC
END
END
END
RETURN

ckCRCNum:
IF NOT ArcFeat?
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FormatArc ArcFeedC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FormatArc DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FormatArc ArcFeedC ckCRCNum EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall '$' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall '$' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

DrillStuff:
SeqC DrillCP EOL
GetCycle
SeqC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
FromCP StrtPos ZDepth Dwell Peck Retract RLevel FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
EachRep
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
SetDrillEndOpZ
SeqC Rapid DrillOff ZCP3 EOL
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('4500')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
EOR EOL
ProgID1 EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Seq Plane DrillOff CRCOff EOL
DoPostScript
GoHome
DoToolComments
SeqC OpToolID EOL
SeqC ToolChng EOL
IF NOT LastTool?
SeqC PreTool EOL
END
RETURN

FirstOp2:
SeqC WFOStuff EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN

FirstOp3:
SeqC OfstOn CoolOn EOL
StartToolSub
DoOpComments
RETURN

NewToolOp1:
EndToolSub
SeqC AbsOrInc Rapid LAST ZCP3 CoolOff EOL
SeqC OfstOff SpinOff EOL
RETURN

NewToolOp2:
DoEndOpPS
GoHome
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqC PlaneC EOL
DoToolComments
Seq OpToolID EOL
SeqC ToolChng EOL
DoPostScript
SeqC PreTool EOL
RETURN

NewToolOp4:
SeqC WFOStuff EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN

NewToolOp5:
SeqC OfstOn CoolOn EOL
StartToolSub
DoOpComments
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC OfstOff SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
IF Milling? AND LAST Drilling?
EndToolSub
ELSE
IF Drilling? AND LAST Milling?
EndToolSub
END
END
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC WFOStuff EOL
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
IF Milling? AND LAST Drilling?
StartToolSub
ELSE
IF Drilling? AND LAST Milling?
StartToolSub
END
END
RETURN

End1:
IF NOT Drilling?
SeqC EndSub EOL
CloseSub
END
SeqC AbsOrInc Rapid ZCP3 CoolOff EOL
SeqC OfstOff SpinOff EOL
RETURN

End2:
DoEndOpPS
GoHome
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END