{Change Comments ***********************************************************}

{8/11/89, Updated processor JR}
{8/31/89, Added PostScript, JR}
{12/1/89, Updated: Fanuc 11M M007.61, JR}

{2/7/90, Updated to Version 3.2 per Fanuc 6M M001.70 Format, DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{9/28/90, Updated: Fanuc 11M M007.71 to .76.1 format, JR}

{10/23/90
Copied & modified: Fanuc 11M M007.76.1
For: Chndler Evans (Colt Ind.)
Machine: Matsuura/Beaver Mill
Change G70 to G20 at prog start-up.
Add AbsOrInc command to WFO line.
Add line at beginning of 1st tool: /G91G28X0.Y0.Z0.M19
Change tool change position to: /G91G28X0.Y0.M19
Jim Radcliffe}

{11/11/91
Modified: Fanuc 11M Matsuura M353.81
For: Chandler Evans
Removed wrongly placed 'END' in IF SameTool? Section after the IF NewToolOffset?
Kim Michelman}

{
Format: Fanuc 11M Matsuura C353.00
1/25/95
Updated to C Style post per C001.05
TH}

{ Added ClearCSOffset to SubCSMP TH}

{8/23/95 - Updated to .10 format TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{5/9/97
Updated: Fanuc 11M Matsuura C353.12
Created: Fanuc 11M Matsuura C353.15
For: Gibbs & Associates/AM Precision
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Pete Jackson and EMail dated 5/7/97
Updated for Catalyst v3.33C per Fanuc 6M (PW) C001.15 Format
DWB}

{12/23/97,
Initial : Fanuc 11M Matsuura C353.15
Created: Fanuc 15M Mat [LM] CW83.15
Customer: Liberty Machine

Changes to "Form":

1. Under Arcs, changed I-J Max Arc Radius to 0.000.
2. Under Tool Offsets, changed Tool Length Offset Cancel from G28 to G30.

Changes to "Prog":

1. Changes to FirstOp1, 2, & 3 to match the customer output.
2. Changes to NewToolOp1, 2, 3, 4, & 5 to match the customer output.
3. Some changes to SameToolOp3 and added check so A or B be output only when moved.
4. Changes to End1 to match the customer output.
5. Changed FORMAT #2 & #3 to 3 decimal points.
6. Changed CSOffsetA# & CSOffsetB# Format to 3.
JHE}

{1/6/98,
Initial : Fanuc 15M Mat [LM] CW83.15
Created: Fanuc 15M Mat [LM] CW83.15.1
Customer: Liberty Machine

Changes to "Prog":

1. Added Var 1 & 2 to output the rotaries as Incremental values.
2. Added Var 3 & 4 to move the rotaries, at tape END, to the start position.
3. Added FORMAT to SUB#.
JHE}

{1/8/98,
Initial : Fanuc 15M Mat [LM] CW83.15.1
Created: Tosnuc 888M Tosh [LM] CW90.15
Customer: Liberty Machine

Changes to "Form":

1. Under General Info, changed Format Code to 10543 & Prog ID Lable to $.
2. Under Origin & Values, changed First Work Fixture Offset to H901 & Last to H999.
3. Under Subs, Changed Call Sub to G72, Return from Sub to M2, & Sub Call Lable to $.
4. Under Tool Offsets, changed Tool Length Offset Cancel to G44.

Changes to "Prog":

1. Changes to FirstOp1 & 2 to match the customer output.
2. Changes to NewToolOp1, 2, 3, & 4 to match the customer output.
3. Changes to SameToolOp1 & 3 to match the customer output.
4. Changes to End1 & 3 to match the customer output.
5. Changed Fixture Offset Code to G57H and Min Number to be 901.
6. Added 'G57' before SetWFO call.
7. Changed NumOfCS# from 6 to 99 (Fixture Offsets).
8. Added RepLab RepCycs in 5 SubCall lines.
10. Added EOR EOL after all SubEnd calls.
11. Replaced SubID, ProgID1, and all CallLab with '$' Program#.
12. Changed rotary Clamp/Unclamp codes from M21/M22.
JHE}

{1/15/98,
Initial : Tosnuc 888M Tosh [LM] CW90.15
Created: Tosnuc 888M Tosh [LM] CW90.15.1
Customer: Liberty Machine

Changes to "Form":

1. Under Arcs, un-checked Allow R-format Arcs.

Changes to "Prog":

1. Added Plane to first block & PlaneC to restart blocks.
JHE}


{Prog Numeric Format Definitions ****************************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3) {Changed from 2 - JHE}
FORMAT(CSOffsetB#,3) {Changed from 2 - JHE}
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(CSSubID#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(SUB#,3) {Added - JHE}

{Prog Subroutines ***********************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

CSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

CSWFO:
'G57H' ADD# CSPartNum# Num#('900') {Changed 'G' and '53' - JHE 1/8}
RETURN

WFO:
'G57H' ADD# PartNum# Num#('900') {Changed 'G' and '53' - JHE 1/8}
RETURN

WFOStuff:
IF Flag?('2')
IF NOT SameTool?
IF WFOCS?
CSWFO
ELSE
WFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
END
END
SetFlagF('2')
RETURN

CSG52:
IF FirstOperation? OR NewTool? OR ChangeCS?
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
END
ClearCSOffset
RETURN

G52Stuff:
IF AAxisAvail? OR BAxisAvail?
IF NOT WFOCS?
IF MultipleParts?
IF WorkFixtureOffsets?
CSG52
END
ELSE
CSG52
END
END
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoCSComment:
IF AAxisAvail? OR BAxisAvail?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
RETURN

DoCSWFOComment:
IF AAxisAvail? OR BAxisAvail?
IF FirstOperation? OR NewTool? OR ChangeCS?
'( ' CSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
END
ClearCSOffset
END
RETURN

CSComments:
IF WFOCS?
IF MultipleParts?
IF OneToolAllParts? AND ExitClearancePlane?
ClearCSOffset { Necessary for correct StrtPos in Main }
END
ELSE
DoCSComment
DoCSWFOComment
END
ELSE
DoCSComment
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
CSComments
RETURN

CSAngleA:
IF AAxisAvail?
{'A' CSOffsetA#} {Abs Output, removed - JHE}
'A' SUB# CSOffsetA# Recall# Num#('1') {Inc Output, added - JHE}
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
{'B' CSOffsetB#} {Abs Output, removed - JHE}
'B' SUB# CSOffsetB# Recall# Num#('2') {Inc Output, added - JHE}
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'$' Program# EOL {Changed from SubID - JHE 1/8}
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall '$' Program# RepLab RepCycs EOL {Replaced CallLab - JHE 1/8}
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

DoCSG52Ops:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC 'G57' SetWFO EOL {Added 'G57' - JHE 1/8}
END
SeqC SubCall '$' Program# RepLab OnePart EOL {Replaced CallLab - JHE 1/8}
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSG52Ops
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSG52Ops
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
StartSub
END
ELSE
SeqC SubCall '$' Program# RepLab Parts EOL {Replaced CallLab - JHE 1/8}
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSComment
DoCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC CSWFO EOL
END
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
END
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall '$' Program# RepLab RepCycs EOL {Added RepLab RepCycs - JHE 1/8}
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall '$' Program# RepLab RepCycs EOL {Added RepLab RepCycs - JHE 1/8}
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall '$' Program# RepLab RepCycs EOL {Added RepLab RepCycs - JHE 1/8}
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# RepLab RepCycs EOL {Added RepLab RepCycs - JHE 1/8}
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall '$' Program# RepLab RepCycs EOL {Added RepLab RepCycs - JHE 1/8}
StartSub
ToolPath
SeqC EndSub EOL
EOR EOL {Added this line - JHE 1/8}
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
Save# Num#('1') CSOffsetA# {Rotary Abs Location - JHE}
Save# Num#('2') CSOffsetB# {Rotary Abs Location - JHE}
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('99') {Changed Num from 6 - JHE 1/8}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('99') {Changed Num from 6 - JHE 1/8}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN

InitOp:
EOR EOL
'$' Program# {Changed fron ProgID1 - JHE 1/8}
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
'N' Tool# Rapid Plane CRCOff 'G44G80' AbsOrInc EOL {Added Plane - JHE 1/15}
SeqC WFOStuff EOL {Added this line - JHE 1/8}
SeqC '/G27' EOL {Added this line - JHE 1/8}
SeqC OpToolID EOL
SeqC ToolChng EOL
SeqC ProgStop EOL {Added this line - JHE}
DoOpComments
DoPostScript
RETURN

FirstOp2:
G52Stuff
{SeqC Speed SpinOn EOL} {Moved to motion block - JHE}
CheckPass
SeqC Rapid AbsOrInc StrtPos Speed SpinOn EOL {Removed WFOStuff - JHE 1/8}
Save# Num#('3') CSOffsetA# {Rotary Location @ Start - JHE}
Save# Num#('4') CSOffsetB# {Rotary Location @ Start - JHE}
RETURN

FirstOp3:
SeqC OfstOn CoolOn EOL
{SeqC CoolOn EOL} {Moved to motion block - JHE}
RETURN

NewToolOp1:
SeqC RapidC ZCP1C CoolOff EOL {Added RapidC ZCP1C - JHE}
{IF AbsoluteMoves?} {Removed this check - JHE 1/8}
SeqC '/G26' EOL {Added this line - JHE 1/8}
SeqC 'G73Z19.' SpinOff EOL {Added this line - JHE 1/8}
RETURN

NewToolOp2:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
{ELSE
SeqC ProgStop EOL} {Moved to NewToolOp3 - JHE}
END
RETURN

NewToolOp3: {Start new Operation}
'N' Tool# Rapid PlaneC CRCOff 'G44G80' AbsOrInc EOL {Added PlaneC - JHE 1/15}
SeqC WFOStuff EOL {Added this line - JHE 1/8}
SeqC '/G27' EOL {Added this line - JHE 1/8}
SeqC OpToolID EOL
SeqC ToolChng EOL
SeqC ProgStop EOL {Added this line - JHE}
DoOpComments
DoPostScript
RETURN

NewToolOp4:
G52Stuff
{SeqC Speed SpinOn EOL} {Moved to motion block - JHE}
CheckPass
IF AChange? OR BChange?
SeqC 'M11' EOL {Unclamp Rotary - JHE}
SeqC Rapid IncValue CSAngleA CSAngleB EOL {Moved B before X & Y - JHE}
SeqC 'M10' EOL {Clamp Rotary - JHE}
END
SeqC Rapid AbsOrInc StrtPos Speed SpinOn EOL {WFOStuff - JHE 1/8}
RETURN

NewToolOp5:
SeqC OfstOn CoolOn EOL
{SeqC CoolOn EOL} {Moved to motion block - JHE}
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
{IF AbsoluteMoves?} {Removed this check - JHE 1/8}
SeqC 'G73Z19.' SpinOff EOL {Added 'G73Z19.' - JHE 1/8}
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
{IF AbsoluteMoves?} {Removed this check - JHE 1/8}
SeqC 'G73Z19.' EOL {Added this line - JHE 1/8}
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC WFOStuff EOL
G52Stuff
IF LAST ProgStop?
IF AChange? OR BChange?
SeqC 'M11' EOL {Unclamp Rotary - JHE}
SeqC Rapid IncValue CSAngleA CSAngleB EOL {Moved B before X & Y - JHE}
SeqC 'M10' EOL {Clamp Rotary - JHE}
END
SeqC Rapid PlaneC AbsOrInc StrtPos Speed SpinOn EOL {Added PlaneC - JHE 1/15}
SeqC OfstOn CoolOn EOL
{SeqC CoolOn EOL} {Moved to motion block - JHE}
ELSE
IF AChange? OR BChange?
SeqC 'M11' EOL {Unclamp Rotary - JHE}
SeqC RapidC IncValue CSAngleA CSAngleB EOL {Moved B before X & Y - JHE}
SeqC 'M10' EOL {Clamp Rotary - JHE}
END
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL {Added PlaneC - JHE 1/15}
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC RapidC ZCP1C CoolOff EOL {Added RapidC ZCP1C - JHE}
SeqC '/G26' EOL {Added this line - JHE 1/8}
SeqC 'G73Z19.' SpinOff EOL {Added 'G73Z19.' - JHE 1/8}
RETURN

End2:
DoEndOpPS
{Move Rotary to First Location - JHE}
{'*** ' Recall# Num#('1') ' recall 1' EOL Use for Testing - JHE
'*** ' Recall# Num#('2') ' recall 2' EOL
'*** ' Recall# Num#('3') ' recall 3' EOL
'*** ' Recall# Num#('4') ' recall 4' EOL}
IF NOT Equal? Recall# Num#('2') Recall# Num#('4') {OR NOT Equal? Recall# Num#('1') Recall# Num#('3')}
SeqC 'M11' EOL
IF AAxisAvail?
SeqC RapidC IncValue 'A' SUB# Recall# Num#('3') Recall# Num#('1') EOL
END
IF BAxisAvail?
SeqC RapidC IncValue 'B' SUB# Recall# Num#('4') Recall# Num#('2') EOL
END
SeqC 'M10' EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC 'G44' AbsValue EOL {Changed to 'G44' - JHE 1/8}
SeqC 'M60' EOL {Added this line (pallet change) - JHE 1/8}
SeqC EOP EOL
EOR EOL {Moved this line up - JHE 1/8}
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ***********************************}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END