{Change Comments ***********************************************************}

{5/11/90
Copied & modified: Dynapath Sys 10M M078.55
For: MICA
Machine: Republic Lagun Model 310
Control: Dynapath 20M
Updated to Version 3.2 per Fanuc 6M M001.72 Format
DWB}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/16/91
Copied & modified: Dynapath 20M Convrs M312.73
For: Gibbs & Associates
Machine:
Control: Dynapath 10M
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Made major modifications per conversation with Dale Bachman at Dynapath Systems, Inc.
This processor is totally conversational.
Added Flag('1') to check if CRCOn (C1) has been output.
CutterRadiusCompensation rules:
CRCOn (C1) must only be activated when Feed (1) or CWArc/CCWArc (2) are active.
Control requires CRCOff (C0) DummyMove on line preceeding CRCOn (C1).
Added logic to output SPX# SPY# CRCOff (C0) in TurnOnCRC Sub.
Rapid (0) must NOT be output while CRCOn (C1) is active.
When RapidFeat, CutterRadiusCompensation and Flag('1') are TRUE:
Added logic to output FeedC (1) MoveXYZC RapidFC (F199.1) in ToolPath.
RapidFC set to output F199.1 in Mach Spec.
Control requires CRCOff (C0) DummyMove when cancelling CRCOn (C1).
Added logic to output MoveXY CRCOff (C0) in TurnOffCRC Sub.
DWB}

{8/28/91
Changed: Dynapath 20M Convrs M312.80
For: General Dynamics/Space Sys. Div.
Changed to FIRST TOOL NOT IN SPINDLE.
Added ToolChng ToolOfst prior to SpinOn block at FirstOperation and NewTool.
Added PreTool to SpinOn block at FirstOperation and NewTool.
Added ToolOfst to ToolChng block at NewTool.
Added following after ToolChng block at FirstOperation and NewTool:
IF NOT CoolOff?
SeqLab '(T) CHECK COOLENT' Get$ EOL
SeqLab '(9)' CoolOn Get$ EOL
SeqLab '(9)' 'M0' Get$ EOL
SeqLab '(T) CHECK COOLENT' Get$ EOL
SeqLab '(9)' SpinOn Get$ EOL
END
KM}

{1/5/94
Modified: Dynapath 20M Convrs M312.80.1
For: Gibbs & Associates/Rayco B
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost4.21.19
Updated to Version 4.2 per Fanuc 6M M001.81.2c Format.
Added IF FIFO? for Milling.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added RestoreScale Sub per 4-Axis Post Processor.
NOTE: Did not add CRCOffC per version 4.2.
Processor already cancels CRC after LastFeat at end of ToolPath.
Added WorkFixtureOffsets for MultipleParts at OpenMP and CloseMP subs.
DWB}

{3/10/95
Modified: Dynapath 20M Convrs M312.81.2
Compared to: Dynapath 20M Conv[RB] M617.81.3
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Changes made per Pete Jackson per Custom Machine.
Added Format#7 '00' at Prog Numeric Format Definitions.
Changed NewWFO# from Format#5 to Format#7 at Prog Numeric Format Definitions.
Added ToolOffset# to Format#7 at Prog Numeric Format Definitions.
Added Flag(2) for SubPrograms M30 per M617.81.3.
Changed ToolChng ToolOfst to ToolChng OpToolID ToolOffset# at FirstOperation and NewTool.
Added condition to test for PreTool when needed at FirstOperation.
Changed ToolOfst to ToolOffset# at PreTool block at FirstOperation and NewTool.
PreTool ToolOfst was causing post to output like T02T01.
This in incorrect based on conversation with Dynapath, should be T0201.
Added condition to output CoolOn only IF NOT CoolOff? = TRUE.
When Coolant is not selected, block output contains Event (9) with no instruction.
DWB}

{7/31/95
Initial: Dynapath 20M Convrs M312.81.3
Created: Dynapath 20M Tree M000.81.3
ForUser: Braden Eng / Pneumat
Control: Dynapath 20M Conversational
Machine: Tree 1060
Develop: ComPost 4.21.32, Catalyst68K v2.19.11C
Comment: New processor per marked up readout.
First Tool In Spindle
Changed M6 to M20 in 1st op.
I guess M20 just tells the control which tool is in the spindle.
Deleted PreTool and ToolOffset# commands.
Deleted '(T) CHECK COOLENT' and '(9)' 'M0' lines for turning on the coolant.
Added Rigid Tapping.
Jim Radcliffe}

{5/9/96, upgraded to .85 version, added RapidF Format, MPK}

{6/2/98,
Initial : Dynapath 20M Tree [PN] M851.85
Created: Dynapath 20M Tree [PN] M851.89
Customer: Pharmaceutical Machine, Brian Walters 612/425-2995

Changes to "Prog":

1. Under OpenMP sub, moved TagUp TagInc to be the first line.
2. Under CloseMP sub, added 2 lines.
3. Added TagInit.
4. Updated ZonlyRepAutoCycle sub per .89 version.
JHE}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0.'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(RapidF#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(DIV#,6) {FeedTapIPR}
FORMAT(NewWFO#,7) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$:
IF NOT EmptyLine?
'$'
END
RETURN

DoSubComment:
NewProg
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Program# Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
{No Rotate stuff for this post}
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab '(1)' ZIn
IF AutoCycle?
'/'
END
FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZIn
IF AutoCycle?
'/'
END
Get$ EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) Z CLEARANCE WILL' Get$ EOL
SeqLab '(T) CHANGE WITH EACH' Get$ EOL
SeqLab '(T) CYCLE OF SUB!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLab '(0)' ShiftRC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftRC Preset Get$ EOL
RETURN

OpenMP:
TagUp TagInc {Moved to here - JHE}
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab '(9)' SetWFO Get$ EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
IncWFO
NextWFO
ELSE
{TagUp TagInc} {Moved up - JHE}
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
'<' Tag# EOL {Added this line - JHE}
TagDown {Added this line - JHE}
CloseSub
SeqLab '(9)' WFO1 Get$ EOL
ELSE
SeqLab '(0)' ShiftPC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
END
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
MoveXYZC
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc GetPlane CheckMove
IF AutoCycle?
ArcI '/' ArcJ '/'
ELSE
ArcIJ
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

TurnOnCRC:
IF CutterRadiusCompensation? AND NOT Flag?('3')
SetFlag('3')
SeqLab '(1)'
IF AutoCycle?
'X' SPX# '/Y' SPY# '/'
ELSE
'X' SPX# 'Y' SPY#
END
CRCOff Get$ EOL
END
RETURN

TurnOffCRC:
IF CutterRadiusCompensation? AND Flag?('3')
SeqLab '(1)'
IF AutoCycle?
MoveX '/' MoveY '/'
ELSE
MoveXY
END
CRCOff Get$ EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
TurnOnCRC
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove CRCOnC DecelFeed Get$ EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
SeqLab '(0)' DoDrillAbsOrInc
IF NOT AbsValue?
IF SPXMove?
MoveSX '/'
END
IF SPYMove?
MoveSY '/'
END
IF SPZMove?
MoveSZ '/'
END
ELSE
MoveSXYZC
END
Get$ EOL {.80.01}
END
END
ELSE
IF RapidFeat?
IF CutterRadiusCompensation? AND Flag?('3')
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove RapidFC Get$ EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(0)' DoAbsOrInc GetPlane CheckMove Get$ EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab '(1)' DoAbsOrInc CheckMove FeedRateC Get$ EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat?
TurnOffCRC
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
Get$ EOL
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) DO NOT USE' Get$ EOL
SeqLab '(T) NEWWFO() WITH' Get$ EOL
SeqLab '(T) NCPOST MULTIPLE' Get$ EOL
SeqLab '(T) PARTS!' Get$ EOL
SeqLab '(T) ' Get$ EOL
ELSE
'E' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
SeqLab '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
SeqLab '(1)' StrtPos Get$ EOL
ELSE
SeqLab '(0)' StrtPos Get$ EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLab Rapid ZCP2 EOL {.69}
END
END {.69}
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
TagDown
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect? {.71.2, added Connect}
SeqLab '(1)' StrtPos Get$ EOL
ELSE
SeqLab '(0)' StrtPos Get$ EOL
END
END
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

CheckRapid:
IF NOT AutoCycle?
IF Repeats?
IF FeedConnect?
Rapid
END
ELSE
Rapid
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit {Added this line - JHE}
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetAbs
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { SubPrograms require 2nd M30 at end }
IF MultipleParts?
SetFlag('2')
END
SetFlagF('3') { CutterRadiusCompensation }
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
SetFlagF('3') { Flag to set-up CutterRadiusCompensation }
Plane { no output }
IF FirstOperation?
'(' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
SeqLab '(T) ' ProgramComment$ Get$ EOL
END
IF FormatNameComment?
SeqLab '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqLab '(T) FIRST TOOL IN SPINDLE' Get$ EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLab '(9)' 'M20' OpToolID Get$ EOL
SeqLab '(9)' SpinOn WFOStuff Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
SeqLab '(9)' ProgStop Get$ EOL
END
END

{Start new Operation}

SeqLab '(9)' ToolChng OpToolID Get$ EOL
DoOpComments
DoPostScript
SeqLab '(9)' SpinOn WFOStuff Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' SpinOff Get$ EOL
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' SpinOn WFOStuff OpToolID Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab '(9)' CoolOff Get$ EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' WFOStuff OpToolID Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' WFOStuff Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
END
END
END
END {common point for all operations}
IF Repeats? OR AutoCycle?
SetFlag('2') { SubPrograms require 2nd M30 at end }
END
IF Milling?
SeqLab '(0)' ZCP2 Get$ EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP3 CheckRapid Get$ EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLab '(0)' StrtPos Get$ EOL
END
IF NOT RetractToCP1?
SeqLab '(0)' ZCP2 Get$ EOL
END
GetCycle
SeqLab '(0)' StrtPos RLevel ZDepth Dwell Peck
IF PeckChipBreaker?
'/Q' Retract#
END
IF Tap? AND OptCyc1?
'F' DIV# Num#('1') FeedTapIPR#('1') 'G8'
ELSE
FeedEnt Cycle
END
Get$ EOL
IF CallMasterOp?
SeqLab '(7)'
'FÅ‚' CallMasterNum#
'L²' CallMasterNum# Get$ EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
SetFlag('2') { SubPrograms require 2nd M30 at end }
TagUp
NewMasterTag
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
StartSub
ToolPath
'<' Tag# EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab '(0)' ZCP3 Rapid Get$ EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' ToolChng Get$ EOL
IF ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
IF Flag?('2') { SubPrograms exist }
SetFlagF('2')
SeqLab '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
END
'END' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END