{Change Comments ***********************************************************}

{8/2/95,
Updated for Catalyst v2.20 per Fanuc 6M M001.85.01 Format.
This is a Tagging Post.
DWB}

{11/2/95,
Modified: Dynapath 20M M074.85.01
Added CallMasterNum# to FORMAT#5 at Prog Numeric Format Definitions.
Added OptCyc1F at PSInit sub.
Modified CRC handling.
SetUp for Virtual RapidFeat and LineFeat, not Gibbs System DogBone!
Added Flag(3)
Various necessary minor changes, too numerous to list due to time constraints.
DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{12/15/97
made longhand per Fanuc 6M Longhand M001.12.9, MPK}
}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'
#7 = '00'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Recall#,5)
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(RapidF#,6)
FORMAT(Dwell#,6) {.72}
FORMAT(NewWFO#,7) {.72}
FORMAT(RapidF#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$: { For conversational output }
IF NOT EmptyLine?
'$'
END
RETURN

TurnCRCOn:
IF CutterRadiusCompensation? AND NOT Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
SetFlag('2')
SetFlag('3') { CRCOff }
SeqC FeedC EOL
SeqC CRCOff MoveSX MoveSY EOL
END
END
RETURN

TurnCRCOff:
IF CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
SetFlagF('3') { CRCOff }
SeqC FeedC EOL
SeqC IncValue EOL
SeqC CRCOff MoveXY EOL
IF NOT AutoCycle?
SeqC AbsValue EOL
END
END
RETURN

WFONum:
'E' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
SeqC '(T) ' Get$ EOL
SeqC '(T) *** WARNING ***' Get$ EOL
SeqC '(T) DO NOT USE' Get$ EOL
SeqC '(T) NEWWFO() WITH' Get$ EOL
SeqC '(T) NCPOST MULTIPLE' Get$ EOL
SeqC '(T) PARTS!' Get$ EOL
SeqC '(T) ' Get$ EOL
ELSE
'E' NewWFO#
END
ELSE
IF Flag?('1')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
SetWFO
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('1')
RETURN

ResetWFO:
IF WorkFixtureOffsets?
SeqC WFO1 EOL
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
Seq '(T) PART NO. ' Tag# Get$ EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
Seq '(T) CYCLE START ' Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqC '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqC '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqC '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqC '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqC '(T) ' ToolComment$ Get$ EOL
END
RestoreScale
END
RETURN

BadMPWFOReport:
SetStatusOff
' ' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
'Ä„ NOTE: Even though you have elected to Ä„' EOL
'Ä„ process this file using Multiple Ä„' EOL
'Ä„ Parts with Work Fixtures, there exist Ä„' EOL
'Ä„ non-zero values in the invisible, Ä„' EOL
'Ä„ Equally SpacedÉ fields, as follows: Ä„' EOL
'Ä„ Ä„' EOL
'*****************************************' EOL
IF NotEqual? PartShiftX# Num#('0')
' X axis shift = ' PartShiftX# EOL
END
IF NotEqual? PartShiftY# Num#('0')
' Y axis shift = ' PartShiftY# EOL
END
IF NotEqual? PartShiftZ# Num#('0')
' Z axis shift = ' PartShiftZ# EOL
END
'*****************************************' EOL
'Ä„ Ä„' EOL
'Ä„ Please reset these values to zero as Ä„' EOL
'Ä„ they affect the coordinate values Ä„' EOL
'Ä„ output, starting with Part# 2. Ä„' EOL
'Ä„ Thank You. Ä„' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
' ' EOL
SetStatusOn
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC '(0)' 'A' FourthDegree# Get$ EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC '(0)' 'A' FourthDegree# Get$ EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC '(0)' 'B' FifthDegree# Get$ EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC '(0)' 'B' FifthDegree# Get$ EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

ExitMove:
IF NOT FeedConnect?
IF FIFO?
FeedC PRIME ZCP2C FeedEntC
ELSE
RapidC PRIME ZCP2C
END
END
RETURN

ExitMove2:
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC ArcIJ
RETURN

ckCRC:
IF CutterRadiusCompensation? AND Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
IF NOT Flag?('3') { CRCOff }
SetFlag('3')
FeedC EOL
SeqC
END
CRCOnC
END
END
RETURN

FormatLine:
ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ Not supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqC MoveSXYZC EOL {.80.01}
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF CutterRadiusCompensation? AND Flag?('2')
SeqC FormatLine RapidFC EOL
ELSE
SeqC ckCRC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC EOL
DecelMove2
END
SeqC FormatLine DecelFeed EOL
ELSE
SeqC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF LastFeat? { Exit Length Feature }
TurnCRCOff {.70}
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SeqC AbsOrInc
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC EOL
END
IF ZShiftOnly?
EntryMove
ELSE
IF NOT NoZMoves?
EntryMove
END
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
SeqC ExitMove EOL
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
DoCycleComment
IF NOT FirstCycle?
IF FIFO?
Rapid
END
SeqC RapidC StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
EACHFeat
IF NOT FirstFeat?
DoCycleComment
END
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
SeqC CRCOffC
LoadFeat Num#('0') Num#('0') PRIME ClearancePlane2#
IF ZMove?
ExitMove
END
EOL
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF FeedConnect?
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
AbsOrInc
ELSE
SeqC AbsOrInc ExitMove EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue RapidC MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC RapidC ZCP2 EOL
END
END
EntryMove
SeqC IncValue EOL
END
ToolPath
NextRep
AutoCycCutSub2
NEXTFeat
RETURN

DrillStuff:
SeqC DrillCP EOL
GetCycle
SeqC Cycle StrtPos ZDepth RLevel Dwell Peck
IF PeckChipBreaker?
'Q' Retract#
END
FeedEnt EOL
TrackZNO# FIRST SPZ#
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
Save# Num#('1') Num#('0') { MultipleParts Current Tool FirstOp# }
Save# Num#('2') Num#('0') { MultipleParts ToolOp# Counter }
Save# Num#('3') Num#('0') { LongHand PeckCycle }
SetFlagF('1') { WFOStuff }
SetFlagF('2') { TurnCRCOff }
SetFlagF('3') { CRCOff }
IF PSComment? AND UseComments?
SeqC '(T) PostScript:' Get$ EOL
SeqC '(T) Literals: put between single or double quotes.' Get$ EOL
SeqC '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqC '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqC '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqC '(T) EndOP -' Get$ EOL
SeqC '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqC '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqC '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqC '(T) at the end of the operation.' Get$ EOL
SeqC '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqC '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqC '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqC '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqC '(T) generates a + A move of the value you specify' Get$ EOL
SeqC '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqC '(T) generates a - A move of the value you specify' Get$ EOL
SeqC '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqC '(T) generates a + B move of the value you specify' Get$ EOL
SeqC '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqC '(T) generates a - B move of the value you specify' Get$ EOL
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
SetPass1
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC CRCOffC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END

{ For LongDrillStuff

LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqC RapidC ZCP3C EOL
END}

{ For DrillStuff }
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
END
END
RETURN

InitOp:
'(' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqC '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
SeqC '(T) ' ProgramComment$ Get$ EOL
END
IF FormatNameComment?
SeqC '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqC '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqC '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqC '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqC '(T) FIRST TOOL NOT IN SPINDLE' Get$ EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
DoOpComments
DoPostScript
SeqC Rapid Speed WFOStuff EOL
SeqC Plane EOL
SeqC 'G70' EOL
SeqC AbsValue EOL
SeqC ToolOfst ToolChng EOL
SeqC SpinOn EOL
RETURN

FirstOp2:
CheckPass
SeqC StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
RETURN

FirstOp3:
RETURN

NewToolOp1:
SeqC CoolOff EOL
RETURN

NewToolOp2:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF OptionalStops?
SeqC ProgStop EOL
END
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
SeqC Rapid Speed WFOStuff EOL
SeqC PlaneC EOL
SeqC AbsValue EOL
SeqC ToolOfst ToolChng EOL
SeqC SpinOn EOL
RETURN

NewToolOp4:
CheckPass
SeqC StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
RETURN

NewToolOp5:
RETURN

SameToolOp1:
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
END
RETURN

SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
SeqC SpeedC WFOStuff EOL
SeqC PlaneC EOL
SeqC AbsValue EOL
RETURN

SameToolOp3: {Start new Operation}
IF SameTool?
IF LAST ProgStop?
SeqC ToolOfst EOL
SeqC SpinOn EOL
SeqC Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
ELSE
IF NewToolOffset?
SeqC ToolOfst EOL
SeqC Rapid StrtPos EOL
SeqC ZCP1 EOL
ELSE
SeqC Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
RETURN

End1:
SeqC CoolOff EOL
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsValue EOL
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
'END' EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation? OR EquallySpacedOffsets?
SetFlag('1') { WFOStuff }
END
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
SetFlag('1') { WFOStuff }
IF FirstOperation?
IF FirstPart?
FirstOp1
FirstOp2
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
SetFlag('1') { WFOStuff }
IF FirstOperation?
IF FirstPart?
FirstOp1
FirstOp2
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

NoMPs: {no multiple parts}
SetFlag('1') { WFOStuff }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
End1
IF MultipleParts? AND OneToolAllParts?
ResetWFO
END
End2
RETURN

DoNewPart:

{Finish off last Part}

IF FullUp?
SeqC CoolOff EOL
IF AbsoluteMoves?
IncValue
END
SeqC OfstOff EOL
END
{DoEndOpPS}

{Start new Part}

SetFlag('1') { WFOStuff }
SameToolOp2
SeqC PlaneC Rapid StrtPos EOL
IF FullUp?
SeqC OfstOn EOL
SeqC CoolOn EOL
END
RETURN

MPLoop:
Save# Num#('2') Recall# Num#('1')
IF WorkFixtureOffsets?
NewWFO
EachWFO
ELSE
EachPart
END
IF AllToolsOnePart?
EachOp
MasterSub
NextOp
EndPartSub
ELSE { OneToolAllParts }
EachOp
IF Equal? Operation# Recall# Num#('2') { Tool First Op }
IF FirstOperation? OR NewTool?
IF NOT FirstPart?
DoNewPart
END
END
MasterSub
IF LastOp?
IF LastPart?
Save# Num#('1') Num#('0')
END
Save# Num#('2') Recall# Num#('1')
ELSE
IF NEXT SameTool?
Save# Num#('2') NEXT Operation#
ELSE
IF LastPart?
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
Save# Num#('2') Recall# Num#('1')
END
END
END
END
NextOp
END
IF WorkFixtureOffsets?
IncWFO
NextWFO
ELSE
NextPart
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}
InitOp

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
END
IF AllToolsOnePart?
MPLoop
ResetWFO
ELSE
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
END
NextOp
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3