{Change Comments ***********************************************************}

{5/20/93
Copied & modified: Fanuc 10M M008.81.2
For: Haas Automation
Combined OpToolID and ToolChng on one block at FirstOperation and NewTool.
Combined WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos and OfstOn on one block at FirstOperation,
NewTool and SameTool.
Added CkCRC sub to cancel CutterRadiusCompensation on LastFeature of ToolPath.
Added literal 'G74' for Left-Handed Tapping at Drilling.
Moved Canned Drill Cycle Block to Main Program when Repeats = TRUE at Drilling.
Main program will output the Canned Drill Cycle, and the SubPrograms will contain only the
positions from the second feature on.
DWB}

{8/2/93
Modified: Haas M573.81.2
For: Haas Automation
Changes made per visit with Harold Moon at Haas Automation.
Added ProgramName$ to SubID block at StartSub.
Added blank lines between subs.
Deleted RepLab OnePart at OpenMP.
Moved Rapid, Feed and Connect Commands to be output in front of AbsOrInc on same block.
Deleted colons from all Comments.
Deleted Spaces following '(, and preceeding )' from ProgramNameComment at FirstOperation.
Changed Seq to 'N' Tool# EOL at FirstOperation and NewTool, output on block by itself.
Changed Safe Start block from G17G80G40 to G0G90G54G40G80G17 at FirstOperation and NewTool.
Changed StrtPos block from WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos OfstOn to
Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn at FirstOperation and NewTool.
Added PlaneC to StrtPos block at NewTool.
Moved OfstOn to beginning of CoolOn block at FirstOperation and NewTool.
Changed WFOStuff PlaneC AbsOrInc Rapid to Rapid AbsOrInc WFOStuff PlaneC at SameTool StrtPos block.
Added IF RetractToCP1 boolean at SameTool.
This is to force output of ZCP1 or ZCP2 for Drilling.
Changed RapidC ZCP3C to Rapid ZCP3 at Drilling.
Moved 'G80' to Rapid ZCP3 at Drilling.
Added literal 'M19', Spindle Orient, at OfstOff block at end of Prog.
Added MasterOp/CallMasterOp PostScript Command support for Drilling.
Routines have been added to call previously created subroutines.
Added MasterOpF and CallMasterOpF at PSInit.
Added PostScript Comments regarding MasterOp and CallMasterOp Commands.
Added support of MasterOp and CallMasterOp Commands at Drilling.
Added FORMAT for Recall# to output called sub.
DWB}

{
Format: Haas C573.00
Updated to C Style .00 format per C001.00.01
TH}

{
Format: Haas C573.00.01
12/22/94
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Haas C573.00.02
1/10/95
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
TH}

{
Format: Haas C573.00.03
1/13/95
Formatted TrackZNO# to #4
}

{ Added ClearCSOffset to SubCSMP TH}

{8/23/95 - Updated to .10 format TH}

{
12/15/95
Added CSAngleA CSAngleB to MP1ToollAllPXcp
Fixed OfstOff to output absvalue after incvalue
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{02Sep98
Original: Haas B573.12
Created: Haas [PR] Bxxx.12
For: Precision Resources
Changes made per: Paul Ruby
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Moved ToolComment$ line from DoOpComments to FirstOp1 and NewToolOp3
Deleted spaces ' in ToolComment$. Changed ' (' to '(' and ' )' to ')
Deleted N Tool# lines in FirstOp1 and NewToolOp3
Added Boolean at NewToolOp5 to prevent redundandant output of WFO when only G54 is used.
Deleted redundant SafetyLine on NewToolOp3
Added Block Delete before CoolOn in FirstOp3, FirstOp3a, NewToolOp5, NewToolOp5a, SameToolOp3
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '*#####.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Recall#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(ADD#,5)

FORMAT(CS#,5)
FORMAT(CSOffsetA#,7)
FORMAT(CSOffsetB#,7)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
'G' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'G' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
IF WFOCS?
'A0.'
ELSE
'A' CSOffsetA#
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
IF WFOCS?
'B0.'
ELSE
'B' CSOffsetB#
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' A' CSOffsetA# ' B' CSOffsetB# ' )' EOL
RETURN

PSInit:
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL
SubID
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove?
CRCOnC
IF NOT EmptyLine?
ResetCRCNum
END
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL ELSE
IF FIFO?
SeqC FeedC AbsOrInc ZCP2 FeedEntC EOL
ELSE
SeqC RapidC AbsOrInc ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC Connect AbsOrInc StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' MasterOp(1), MOP(1) -' EOL
' IF Repeats? AND Drilling? = TRUE, will place Drill Points in next available Subroutine' EOL
' Minimum = MasterOp(1); Maximum = MasterOp(25)' EOL
' CallMasterOp(1), CMOP(1) -' EOL
' IF Repeats? AND Drilling? = TRUE, will call Subroutine created during MasterOp(1) operation' EOL
' CallMasterOp(1) operations MUST follow MasterOp(1) operations for output to be correct' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('6')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to non-WFO output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('6') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to non-WFO output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
SeqC FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF Repeats?
NewProg
StdSub
END
IF CallMasterOp?
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

DoWFONum:
IF WFOCS?
IF ChangeCS?
CSWFO
ELSE
'G' NewWFO#
END
END
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
END
ClearCSOffset
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
END
ClearCSOffset
END
RETURN

InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
' ' EOL
IF ToolComment?
'(' ToolComment$ ')' EOL
END
SeqC OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqC Rapid AbsOrInc DoWFONum CRCOff 'G80' Plane EOL
RETURN

FirstOp3:
CheckPass
SeqC Rapid AbsOrInc
DoWFONum
StrtPos CSAngleA CSAngleB Speed SpinOn EOL
SeqC OfstOn '/' CoolOn EOL
RETURN

FirstOp3a:
CheckPass
SeqC Rapid AbsOrInc
IF GreaterThan? NumOfCS# Num#('1')
DoWFONum
END
Speed SpinOn EOL
SeqC OfstOn '/' CoolOn EOL
RETURN

NewToolOp1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid AbsOrInc Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
' ' EOL
IF ToolComment?
'(' ToolComment$ ')' EOL
END
SeqC OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
RETURN

NewToolOp5:
CheckPass
SeqC Rapid AbsOrInc
IF GreaterThan? NumOfCS# Num#('1')
DoWFONum
END
PlaneC StrtPos CSAngleA CSAngleB Speed SpinOn EOL
SeqC OfstOn '/' CoolOn EOL
RETURN

NewToolOp5a:
CheckPass
SeqC Rapid AbsOrInc
IF GreaterThan? NumOfCS# Num#('1')
DoWFONum
END
PlaneC Speed SpinOn EOL
SeqC OfstOn '/' CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC Rapid AbsOrInc
IF ChangeCS?
DoWFONum
END
PlaneC StrtPos CSAngleA CSAngleB SpeedC SpinOn EOL
SeqC OfstOn '/' CoolOn EOL
ELSE
SeqC Rapid AbsOrInc
IF ChangeCS?
DoWFONum
END
PlaneC StrtPos CSAngleA CSAngleB SpeedC EOL
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn EOL
ELSE
IF Drilling?
IF RetractToCP1?
SeqC ZCP1 EOL
ELSE
SeqC ZCP2 EOL
END
END
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC '/' CoolOn EOL
END
END
RETURN

End1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff 'M19' EOL { Spindle Orient }
SeqC AbsValue EOL
ELSE
SeqC OfstOff 'M19' EOL { Spindle Orient }
END
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid AbsOrInc FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3a
OpenMP
SeqC StrtPos CSAngleA CSAngleB EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5a
OpenMP
SeqC StrtPos CSAngleA CSAngleB EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END