{12/2/88
General change to all Bandits.
Deleted: CRCOnC & CRCOffsetC commands from 6 places in ToolPath.
Added Comments.
Changed FormatArc to unconditionaly move X & Y & I & J
Jim Radcliffe}

{1/12/89
Modified Bandit IIIM-Shiz M009.54
Added RapidC to 'IF NOT FeedConnect'}

{2/7/89
Modified Bandit IIIM-Shiz M009.55 for Magness
Changed '/Z' to 'Z' in G82 Bore cycle
Jim Radcliffe}

{6/20/89
Modified; Bandit IIIM Shizouka M009.56.
Change "AbsValue" in first operation to "AbsOrInc".
Jim Radcliffe}

{3/23/90
Updated: Bandit IIIM Shizouka M009.57
For: Kipe Molds
Fixed FormatArc sub
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/9/90, Updated: Bandit IIIM Shizouka M009.59 to .74 format & corrected arcs per M225, JR}

{4/03/91
Modified: Bandit IIIM Shizouka M009.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '##.##;0.'
#5 = '####.####;0.'
#6 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,4)
FORMAT(ToolDiameter#,5) {.72}
FORMAT(Program#,6) {.72}
FORMAT(Operation#,6) {.72}
FORMAT(Tool#,6) {.72}
FORMAT(Parts#,6) {.72}

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
FeedEnt EOL
Feed ZIn EOL
ELSE
RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub MarkSub
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
CallLabB EOL
RepLab RepCycs EOL
'N' EOL
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
RapidC ZCP3C EOL
END
RETURN

FinishSubG92: {part 2}
Feed ShiftRC Preset EOL
EndSub EOL
CloseSub
Feed UnshftRC Preset EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
CallLabB EOL
RepLab Parts EOL
'N' EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
ShiftPC Preset EOL
EndSub EOL
CloseSub UnshftPC Preset EOL
END
RETURN

FormatArc:
IF XMove? AND YMove?
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE
MoveXC MoveY MoveZ { YZ plane }
END
END
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
ELSE
FeedC MoveXYC
END
RETURN

StdLine: {enables CRC on first call, .70}
CRCOnC EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
FeedRateC EOL
FeedC MoveXYZC EOL
DecelMove2
END
DecelFeed EOL
FeedC MoveXYZC EOL
ELSE
FeedRateC EOL
FeedC MoveXYZC EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
MoveSXYC EOL
IF AutoCycle?
CallLabB EOL
'N' EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
CRCOffC EOL
RapidC MoveXYZC EOL
ELSE
RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
CRCOffC EOL
FeedRateC EOL
FeedC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
FeedRateC EOL
FeedC MoveXYZC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
ArcFeedC EOL
FormatArc EOL
DecelMove2
END
DecelFeed EOL
FormatArc EOL
ELSE
ArcFeedC EOL
FormatArc EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
IncValue EOL
StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
CRCOnC EOL
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
AbsOrInc EOL
Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
SetPass1 {for correct Z's}
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
Feed IncValue StrtPosC EOL
AbsOrInc
ELSE
Feed
END
ELSE
Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
Rapid IncValue StrtPosC EOL
IF FeedEntry?
AbsOrInc ZCP2PlusInc EOL
Feed ZInPlusInc FeedEnt EOL
ELSE
AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
Rapid ZCP2PlusInc EOL
Feed ZInPlusInc FeedEnt EOL
ELSE
Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
Feed ZInPlusInc FeedEnt EOL
ELSE
Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
CallLabB EOL
'N' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
Rapid ZCP2 EOL {.69}
END {.69}
EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
FeedEnt EOL
FeedC ZInPlusInc EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE
RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
CallLabB EOL
'N' EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SpinOn EOL
AbsOrInc EOL
IF ToolChangeAtHome?
Home Preset EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Rapid StrtPos EOL
OfstOnB3 EOL
Plane Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
Rapid StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SpinOff EOL
IF ToolChangeAtHome?
AbsOrInc EOL
Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
ToolChng EOL

{Start new Operation}

DoOpComments
DoPostScript
Plane SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
AbsOrInc EOL
IF ToolChangeAtHome?
Feed Home Preset EOL
END
CheckPass
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
OfstOff EOL
SpinOff EOL
'M00' EOL

{Start new Operation}

GetStartOfSameTool
PlaneC SpinOn EOL
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
OfstOff EOL

{Start new Operation}

GetStartOfSameTool
PlaneC EOL
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
ELSE
{Start new Operation}

GetStartOfSameTool
PlaneC EOL
Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
RapidC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
RapidC ZCP3C EOL
CRCOffC EOL
ELSE
IF Drilling?
Rapid ZCP2C EOL
IF Repeats?
CallLabB EOL
RepLab RepCycs EOL
'N' EOL
OpenSub MarkSub AbsOrInc EOL
DoSubComment
Rapid StrtPos EOL
END
GetCycle
FromCP ZDepth Dwell Peck Retract Cycle EOL
FeedEnt EOL
StrtPos EOL
ToolPath
'G80' EOL
IF Repeats?
ZCP2 EOL
Feed ShiftRC Preset EOL
EndSub EOL
CloseSub Feed UnshftRC Preset EOL
AbsValue EOL
END
Rapid ZCP3 EOL
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
AbsOrInc EOL
Rapid FirstHome EOL
END
SpinOff EOL
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
EOP EOL
Post
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum