{Change Comments ***********************************************************}

{12/2/88,
General change to all Bandits.
Deleted CRCOnC & CRCOffsetC Commands from 6 places in ToolPath.
Added ZCP1C Command before OfstOff to assure Spindle is at same level as Preset before going Home.
Added Comments.
Changed FormatArc to unconditionaly move X & Y & I & J
JR}

{6/20/89
Modified: Bandit IIA Shizouka M006.55.
Change AbsValue in FirstOperation to AbsOrInc.
JR}

{4/13/90
Modified: Bandit IIA Shizouka M006.56
Changed Z to a negative value for Drilling Peck amount.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/29/91,
Modified: Bandit IIA Shizouka M006.58
For: Gibbs & Associates
Updated to new 4.0 Version per Fanuc 6M M001.80
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '##.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
FeedEnt EOL
Feed ZInC EOL
ELSE
Rapid ZInC EOL
END
RETURN

StartSub:
OpenSub
MarkSub
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
CallLabB EOL
RepLab RepCycs EOL
'N' EOL
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
Rapid ZCP3C EOL
END
RETURN

FinishSubG92: {part 2}
Feed
ShiftRC Preset EOL
EndSub EOL
CloseSub
UnshftRC Preset EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
CallLabB EOL
RepLab Parts EOL
'N' EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
Feed
ShiftPC Preset EOL
EndSub EOL
CloseSub
UnshftPC Preset EOL
END
RETURN

FormatArc:
IF XMove? AND YMove?
IF ArcCW?
CWArcC {no output}
ELSE
CCWArcC {no output}
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
ELSE
Feed MoveXYZC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF Drilling? AND RetractToCP1? AND NOT FirstFeat?
'G80' EOL
Rapid ZCP1 EOL
MoveSXYC EOL
'G89' EOL
Rapid ZCP2 EOL
ELSE
MoveSXYC EOL
IF AutoCycle?
CallLabB EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
Rapid MoveXYZC EOL
END
ELSE
IF LineFeat?
IF Decelerate?
IF RoomToDecel?
DecelMove1
FeedRateC EOL
Feed MoveXYZC EOL
DecelMove2
END
DecelFeed EOL
Feed MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
FeedRateC EOL
Feed MoveXYZC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
ArcFeedC EOL
FormatArc EOL
DecelMove2
END
DecelFeed EOL
FormatArc EOL
ELSE
ArcFeedC EOL
FormatArc EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}

{StartSub}
OpenSub
SetPass2 {position pattern}
EachFeat
MarkSub
NextFeat
SetPass1 {element cut moves}
DoSubComment

SetSRXYtoSP
IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc EOL {.69 removed RapidC}
ELSE
AbsOrInc EOL
Rapid ZCP2 EOL
END
EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}

{StartSub}
OpenSub
EachCycle
MarkSub
NextCycle
DoSubComment

NewProg
EachCycle
IF FeedConnect?
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE
Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
CallLabB EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
Rapid ZCP2 EOL {.69}
END {.69}
EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
Rapid ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE
Rapid ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
CallLabB EOL
NextCycle

{StartSub}
OpenSub
EachCycle
MarkSub
NextCycle
DoSubComment

SkipZ
ToolPath
FinishSub1
EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
Plane {no output}
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('3800')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
Plane {no output}
SpinOn EOL
AbsOrInc EOL
Home Preset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Rapid StrtPos EOL
OfstOnB EOL
Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP Rapid StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
ZCP1C EOL
OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SpinOff EOL
IF ToolChangeAtHome?
AbsOrInc EOL
Rapid Home EOL
END
IF LAST ProgStop?
'M00' EOL
END
AutoTool

{Start new Operation}

DoOpComments
DoPostScript
Plane {no output}
SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
AbsOrInc EOL
Feed Home Preset EOL
SpeedB Rapid StrtPos EOL
OfstOnB EOL
Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
OfstOff EOL
SpinOff EOL
Rapid Home EOL
'M00' EOL

{Start new Operation}

GetStartOfSameTool
SpinOn EOL
SpeedB Rapid StrtPos EOL
OfstOnB EOL
Feed ZCP1 Preset EOL
ELSE
IF NewToolOffset?
OfstOff EOL

{Start new Operation}

GetStartOfSameTool
SpinOn EOL
AbsOrInc EOL
Rapid StrtPos EOL
OfstOnB EOL
Feed ZCP1 Preset EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SpinOn EOL
AbsOrInc EOL
Rapid StrtPos EOL
Feed ZCP1 Preset EOL
END
END
END
END
END {common point for all operations}
IF Milling?
Rapid ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
Rapid ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
Rapid StrtPos EOL
END
Rapid ZCP2C EOL
GetCycle
FeedEnt EOL
ZDepth Dwell Peck Retract Cycle EOL
StrtPos EOL
ToolPath
'G80' EOL
Rapid ZCP3C EOL
IF Repeats?
FinishSubG92
END
Rapid ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
ZCP1C EOL
OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SpinOff EOL
IF FIRST ToolChangeAtHome?
AbsOrInc EOL
Rapid FirstHome EOL
END
IF LAST ProgStop?
'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
EOP EOL
Post
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum