{12/2/88
General change to all Bandits.
Deleted: CRCOnC & CRCOffsetC commands from 6 places in ToolPath.
Added ZCP1C command before OfstOff to assure spindle is at same
level as preset before going home. Added Comments.
Changed FormatArc to unconditionaly move X & Y & I & J
Jim Radcliffe}

{6/20/89
Modified; Bandit IIM Shizouka M004.55.
Change "AbsValue" in first operation to "AbsOrInc".
Jim Radcliffe}

{8/2/89
Copied & modified; Bandit IIM Shizouka M004.56
For; Geo Stevenson Machine Co., Inc.
Two axis machine only, no Z axis capability or tool change.
Delete all Z and tool change stuff.
Jim Radcliffe}

{8/23/89
Changed M5 for spindle off to M6 per Geo Stevenson Amendment
Tom Fischer}

{12/13/89
Modified: Bandit IIM (No Z) M225.61
For: Geo Stevenson Machine Co., Inc.
Add 'M00' to every operation after StartPos.
Move the AbsOrInc to after the tool change at end of prog.
No SepSubs, PostScript commented out.
Jim Radcliffe}

{5/7/90
Moved SpinOff and AbsOrInc commands to before IF ToolChangeAtHome? at end of last operation,
to be consistant with IF NewTool?.
Replaced ArcI# and ArcJ# with ArcIJ.
Added Plane to FirstOperation to allow the ArcIJ address labels to be output.
DWB}

{6/5/90, Added round to .0005 formatting in form and prog, DWB}
{6/19/90, Modified arc move to output as linear when movement is on one axis only, DWB}
{7/1/90, Removed .0005 format rounding from form and prog, DWB}
{7/1/90, Modified all 4 place decimals to 3 place in form and prog, DWB}
{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/03/91
Modified: Bandit IIM (No Z) M225.62
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

#1 = '0.00'
#2 = '###.###;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ArcI#,2)
FORMAT(ArcJ#,2)

DoPostScript:
{EachPS
PostScript EOL
NextPS}
RETURN

DoEndOpPS:
{EachEOPS
EndOpPS EOL
NextPS}
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

OpenMP:
IF EquallySpacedOffsets?
CallLabB EOL
RepLab Parts EOL
'N' EOL
OpenSub MarkSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
ShiftPC Preset EOL
EndSub EOL
CloseSub UnshftPC Preset EOL
END
RETURN

FormatArc:
IF XMove? AND YMove?
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXY
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
ELSE
FeedC MoveXYC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
MoveSXYC EOL
ELSE
IF RapidFeat?
RapidC MoveXYC EOL
ELSE
IF LineFeat?
IF Decelerate?
IF RoomToDecel?
DecelMove1
FeedC MoveXYC FeedRateC EOL
DecelMove2
END
FeedC MoveXYC DecelFeed EOL
ELSE
FeedC MoveXYC FeedRateC EOL
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeedC EOL
DecelMove2
END
FormatArc DecelFeed EOL
ELSE
FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

InitProg
ReverseXZArcs
{IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END}
EachOp
IF FirstOperation?
EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
Plane SpinOn EOL
AbsOrInc EOL
Home Preset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
Rapid StrtPos EOL
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
Rapid StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoEndOpPS
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SpinOff EOL
AbsOrInc EOL
IF ToolChangeAtHome?
Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
ToolChng EOL
DoOpComments
PlaneC SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
AbsOrInc EOL
Feed Home Preset EOL
Rapid StrtPos EOL
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
Rapid StrtPos EOL
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
DoEndOpPS
DoOpComments
PlaneC EOL
Rapid StrtPos EOL
DoPostScript
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
IF Milling?
IF Repeats?
CallLabB EOL
RepLab RepCycs EOL
'N' EOL
OpenSub MarkSub AbsOrInc EOL
DoSubComment
Rapid StrtPos EOL
END
FeedRateC EOL
ToolPath
IF Repeats?
Feed ShiftRC Preset EOL
EndSub EOL
CloseSub Feed UnshftRC Preset EOL
AbsValue EOL
END
ELSE
IF Drilling?
IF Repeats?
CallLabB EOL
RepLab RepCycs EOL
'N' EOL
OpenSub MarkSub AbsOrInc EOL
DoSubComment
Rapid StrtPos EOL
END
GetCycle
FeedEnt EOL
FromCP ZDepth Dwell Peck Retract Cycle EOL
StrtPos EOL
ToolPath
'G80' EOL
IF Repeats?
Feed ShiftRC Preset EOL
EndSub EOL
CloseSub Feed UnshftRC Preset EOL
AbsValue EOL
END
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoEndOpPS
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SpinOff EOL
AbsOrInc EOL
IF ToolChangeAtHome?
Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
EOP EOL
Post
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum